计算列 - 从过滤器过滤日期范围的 MAX答案

【问题标题】：Calculated Column - Filtering MAX on date range from filter计算列 - 从过滤器过滤日期范围的 MAX
【发布时间】：2019-02-26 21:09:32
【问题描述】：

考虑以下表格 - 一个是打印机，另一个是来自仪表读数的页数：

Printers
+------------+---------+--------+
| Printer ID |  Make   | Model  |
+------------+---------+--------+
|          1 | Xerox   | ABC123 |
|          2 | Brother | DEF456 |
|          3 | Xerox   | ABC123 |
+------------+---------+--------+


Meter Read
+-------+------------+-----------+------------+
| Index | Printer ID | Poll Date | Mono Pages |
+-------+------------+-----------+------------+
|     1 |          1 | 1/1/2019  |       1000 |
|     2 |          2 | 1/1/2019  |        800 |
|     3 |          3 | 1/1/2019  |      33000 |
|     4 |          1 | 1/2/2019  |       1100 |
|     5 |          2 | 1/2/2019  |        850 |
|     6 |          3 | 1/2/2019  |      34000 |
|     7 |          1 | 1/3/2019  |       1200 |
|     8 |          2 | 1/3/2019  |        900 |
|     9 |          3 | 1/3/2019  |      35000 |
|    10 |          1 | 1/4/2019  |       1400 |
|    11 |          2 | 1/4/2019  |        950 |
|    12 |          3 | 1/4/2019  |      36000 |
|    13 |          1 | 1/5/2019  |       1800 |
|    14 |          2 | 1/5/2019  |       1000 |
|    15 |          3 | 1/5/2019  |      36500 |
|    16 |          1 | 1/6/2019  |       2000 |
|    17 |          2 | 1/6/2019  |       1050 |
|    18 |          3 | 1/6/2019  |      37500 |
|    19 |          1 | 1/7/2019  |       2100 |
|    20 |          2 | 1/7/2019  |       1100 |
|    21 |          3 | 1/7/2019  |      39000 |
|    22 |          1 | 1/8/2019  |       2200 |
|    23 |          2 | 1/8/2019  |       1150 |
|    24 |          3 | 1/8/2019  |      40000 |
+-------+------------+-----------+------------+

在我的 Power BI 报告中，我有一个日期表：

Dates = CALENDAR(DATE(2019, 1, 1), DATE(2019, 1, 31))

我用作切片机。目标是在切片器的日期范围内最终获得 Mono Pages 的增量。我可以通过 Meter Read 表上一个相当复杂的计算列来获取每次抄表之间的差异：

PagesSinceLastPoll = 
IF(
    ISBLANK(
        LOOKUPVALUE(
            'Meter Read'[Mono Pages],
            'Meter Read'[Index], CALCULATE(
                MAX(
                    'Meter Read'[Index]
                ), FILTER(
                    'Meter Read',
                    'Meter Read'[Index] < EARLIER('Meter Read'[Index])
                        && 'Meter Read'[Printer ID] = EARLIER('Meter Read'[Printer ID] )
                )
            )
        )
    ),
    BLANK(),
    'Meter Read'[Mono Pages] - 
    LOOKUPVALUE(
        'Meter Read'[Mono Pages],
        'Meter Read'[Index], CALCULATE(
            MAX(
                'Meter Read'[Index]
            ), FILTER(
                'Meter Read',
                'Meter Read'[Index] < EARLIER('Meter Read'[Index])
                    && 'Meter Read'[Printer ID] = EARLIER('Meter Read'[Printer ID] )
            )
        )
    )
)

但是超过 10,000 行以上的性能非常糟糕。我想在过滤的日期范围内获取设备的最大值和最小值，然后减去，但我很难获得正确的值。到目前为止，我的 DAX 一直从 ENTIRE 表中获取最大值，而不是根据切片器中的日期过滤的表。到目前为止，我尝试过的所有内容都在以下方面有所变化：

MaxInRange =
CALCULATE (
    MAX ( 'Meter Read'[Mono Pages] ),
    FILTER ( 'Meter Read', 'Meter Read'[Printer ID] = Printers[Printer ID] )
)

总结一下：如果我有一个从 2019 年 1 月 2 日开始到 2019 年 1 月 5 日结束的切片机，那么打印机 ID 1 的最大值应该是 1800，而不是 2200。

想法？

【问题讨论】：

您的Dates 表与Meter Read 表之间是否存在关系？
是 - 一对多，从 Dates[Date] 到 'Meter Read'[Poll Date] 两列都是日期数据类型

标签： powerbi dax powerbi-desktop

【解决方案1】：

计算的列可以像这样更有效地完成：

PagesSinceLastPoll = 
VAR PrevRow =
    TOPN(1,
        FILTER('Meter Read',
            'Meter Read'[PrinterID] = EARLIER('Meter Read'[PrinterID]) &&
            'Meter Read'[PollDate] < EARLIER('Meter Read'[PollDate])
        ),
        'Meter Read'[PollDate]
    )
RETURN 'Meter Read'[MonoPages] - SELECTCOLUMNS(PrevRow, "Pages", 'Meter Read'[MonoPages])

使用它，两个日期之间的页数可以将这些日期的该列相加。

如果您想跳过它并直接进入小节，请尝试以下操作：

PagesInPeriod = 
VAR StartDate = FIRSTDATE(Dates[Date])
VAR EndDate = LASTDATE(Dates[Date])
RETURN
SUMX(
    VALUES('Meter Read'[PrinterID]),
    CALCULATE(
        MAX('Meter Read'[MonoPages]),
        Dates[Date] = EndDate
    )
    -
    CALCULATE(
        MAX('Meter Read'[MonoPages]),
        Dates[Date] < StartDate
    )
)

请注意，如果您使用Dates[Date] = StartDate，那么您将离开。您想计算第一个包含日期之前的最大页数。

这两种方法应该给出相同的结果：

【讨论】：

该列在这种情况下更为理想，因为我正在汇总来自数百台设备的数据。如果我正在查看一个特定设备的信息，那么该度量是完美的，但是在查看多个设备时正在做一些......有趣的事情（例如，表格的 Total 行）。我最终使用了您提供的更有效的计算列，但我很好奇是否有人能提出“按日期过滤的范围内的 MAX - MIN”解决方案。
啊，对。我需要分别获取 ID 值的最大值。请查看我的编辑。

【解决方案2】：

Alexis 的措施是处理这个问题的正确方法（谢谢！），但我做了一个非常小的编辑。由于可能未在结束日期读取读数，因此我们需要查看该日期或之前的日期，否则它将结束日期的最大值视为零。那么最终的代码就变成了：

PagesInPeriod = 
VAR StartDate = FIRSTDATE(Dates[Date])
VAR EndDate = LASTDATE(Dates[Date])
RETURN
SUMX(
    VALUES('Meter Read'[PrinterID]),
    CALCULATE(
        MAX('Meter Read'[MonoPages]),
        Dates[Date] <= EndDate
    )
    -
    CALCULATE(
        MAX('Meter Read'[MonoPages]),
        Dates[Date] < StartDate
    )
)

【讨论】：