如何使用 fortran 子例程（或函数）填充矩阵并将矩阵传递回主程序？

Question

我正在处理 Fortran 90 作业，在学习如何使用子例程和函数时遇到了很多问题，我希望有人能帮助我。如果不是很明显，我对 FORTRAN 非常陌生，并且对 C 和 Java 等语言更加熟悉。

无论如何，这就是我必须做的事情：用户选择他们想要做的事情：加、减、乘或转置两个矩阵。我为此使用了一个选择案例，效果很好。但是，我显然不想重复相同的代码以四次填充两个矩阵，因此我试图将其设为单独的函数。理想情况下，我想做这样的事情：

integer matrix1(11,11), matrix2(11,11)
integer rows1,cols1,rows2,cols2,i,j
case (1)  
    matrix1 = fillmatrix(rows1,cols1)
    matrix2 = fillmatrix(rows2,cols2)
.
.
.


function fillmatrix(rows,columns)
  integer input
  read *,rows,columns
  do i = 1, rows
    do j = 1, columns
       fillmatrix(i,j) = read *,input
    end do
  end do
end

有没有办法做这样的事情？我有没有说清楚，因为有时我很难说出我的意思。

或者这可能吗？

matrix1 = fillmatrix(rows1)cols1)


function fillmatrix(rows,columns)
   integer input,matrix(11,11)
       //fill matrix
   return matrix
end

Answer 1

在 C 或 Java 中，只有函数，但 Fortran 既有函数又有子例程。在这种情况下，将其写为subroutine 而不是function 可能更容易，所以你的调用看起来像

integer matrix1(11,11), matrix2(11,11)
integer rows1,cols1,rows2,cols2,i,j
...
case (1)  
    call fillmatrix(matrix1)
    call fillmatrix(matrix2)
...

子程序的样子

subroutine fillmatrix(m)
    implicit none
    integer, intent(out) :: m(:,:)

    integer :: i, j
    do j = 1,size(m,2)
        do i = 1,size(m,1)
            read *, m(i,j)
        end do
    end do
end subroutine fillmatrix

请注意，我没有直接指定数组边界——而是在子例程中找出它们。这意味着这个子例程需要一个显式接口 - 获得它的最简单方法是将它放在 contains 块或 module 中。

Answer 2

如果你想使用function，你需要在调用它之前知道矩阵的大小。这是一个小例子：

module readMatrix
  implicit none
contains
  function fillmatrix(cols,rows)
    implicit none
    ! Argument/return value
    integer,intent(in)  :: rows,cols
    integer             :: fillmatrix(rows,cols)
    ! Loop counters
    integer             :: i,j

    do j = 1, rows
      do i = 1, cols
        write(*,*) 'Enter matrix element ',i,j
        read *,fillmatrix(i,j)
      enddo ! j
    enddo ! i
  end function
end module

program test
  use readMatrix
  implicit none
  integer,allocatable :: matrix(:,:)
  integer             :: row,col, stat

  write(*,*) 'Enter number of rows'
  read *,row
  write(*,*) 'Enter number of cols'
  read *,col
  allocate( matrix(col,row), stat=stat )
  if (stat/=0) stop 'Cannot allocate memory'

  matrix = fillmatrix(col,row)

  write(*,*) matrix
  deallocate(matrix)
end program

这类似，使用subroutine 和静态数组（如问题中所示）：

module readMatrix
  implicit none
contains
  subroutine fillmatrix(cols,rows,matrix)
    implicit none
    ! Argument/return value
    integer,intent(out) :: rows,cols
    integer,intent(out) :: matrix(:,:)
    ! Loop counters
    integer             :: i,j

    write(*,*) 'Enter number of rows, up to a maximum of ',size(matrix,2)
    read *,rows
    write(*,*) 'Enter number of cols, up to a maximum of ',size(matrix,1)
    read *,cols

    if ( rows > size(matrix,2) .or. cols > size(matrix,1) ) &
      stop 'Invalid dimension specified'

    do j = 1, rows
      do i = 1, cols
        write(*,*) 'Enter matrix element ',i,j
        read *,matrix(i,j)
      enddo ! j
    enddo ! i
  end subroutine
end module

program test
  use readMatrix
  implicit none
  integer,parameter   :: maxCol=10,maxRow=10
  integer             :: matrix(maxCol,maxRow)
  integer             :: row,col

  call fillmatrix(col,row,matrix)

  write(*,*) matrix(1:col,1:row)

end program

您甚至可以将 allocatable 数组传递给子例程并在那里分配它，但那是另一回事...