Prolog - 递归追加到返回 false 的列表

Question

标题说明了一切，但我们又来了。尝试以递归方式附加到 Prolog 中的列表，虽然我之前已经通过“临时缓冲区”（通过 nb_setval/nb_getval）使其工作，但我想学习如何以稍微更合适的方式递归地附加到列表。

我知道 Prolog 可以在所有绑定中工作，一旦绑定了某些东西就很难操作它，所以一开始我就坐在那里，但我明白为什么这不起作用：

recursiveAppend([], _).
recursiveAppend([H|T], Output):-
    append(H, [], Output),
    recursiveAppend(T, Output).

这让我更改了代码并转到以下内容：

recursiveAppend([], _).
recursiveAppend([H|T], Output):-
    append(H, Output, NewOutput),
    recursiveAppend(T, NewOutput).

我曾希望这能奏效，因为这对我自己很有意义，显然对其他人也很有意义，同时也搜索了其他 StackOverflow 问题。不幸的是，在 SWI-Prolog 中调用这个谓词只会返回 false。

?- recursiveAppend([1, 2, 3, 4, 5], L1). false

在这种情况下，预期/期望的结果是：

?- recursiveAppend([1, 2, 3, 4, 5], L1). L1 = [1, 2, 3, 4, 5].

为了清楚起见，如果“充实”，程序的运行时应该如下所示：

recursiveAppend([H|T], Output):-
    % H is 1, Output is []
    append(H, Output, NewOutput),
    % NewOutput is [1]
    recursiveAppend(T, NewOutput).

recursiveAppend([H|T], Output):-
    % H is 2, Output is [1]
    append(H, Output, NewOutput),
    % NewOutput is [1, 2]
    recursiveAppend(T, NewOutput).

recursiveAppend([H|T], Output):-
    % H is 3, Output is [1, 2]
    append(H, Output, NewOutput),
    % NewOutput is [1, 2, 3]
    recursiveAppend(T, NewOutput).

recursiveAppend([H|T], Output):-
    % H is 4, Output is [1, 2, 3]
    append(H, Output, NewOutput),
    % NewOutput is [1, 2, 3, 4]
    recursiveAppend(T, NewOutput).

recursiveAppend([H|T], Output):-
    % H is 5, Output is [1, 2, 3, 4]
    append(H, Output, NewOutput),
    % NewOutput is [1, 2, 3, 4, 5]
    recursiveAppend(T, NewOutput).

recursiveAppend([], _). % First argument (list) is empty, and the second argument (list) has been populated (with [1, 2, 3, 4, 5]), program done.

感谢任何和所有帮助，即使这个问题可能已经被问过一百万次了！

Answer 1

“递归追加”在 Prolog 中通常没有意义。该问题应包含有关您要解决的问题的信息。目前不是这样。它是关于你如何尝试解决你的问题。那个“如何”是“递归追加”，但这几乎肯定不是你应该如何真正解决这个问题。如果我们知道问题是什么，而不是你认为你想如何解决它，我们可以提供更好的帮助。

以https://stackoverflow.com/a/64092447/4391743的问题和解决方案为例：

?- recursiveAppend([1, 2, 3], Ys).
Ys = [1, 2, 3].

?- recursiveAppend(Xs, [1, 2, 3]).
Xs = [1, 2, 3] ;
% nontermination after first answer

?- recursiveAppend([1, 2, X], [A, B, 3]).
X = 3,
A = 1,
B = 2.

?- recursiveAppend([1, 2 | Rest], [A, B, 3, 4]).
Rest = [3, 4],
A = 1,
B = 2 ;
% nontermination after first answer

如果这是您想要的，那么您似乎想要的是“列表副本”谓词。这里有一个更短、更快、更完整的：

list_copy([], []).
list_copy([X | Xs], [X | Ys]) :-
    list_copy(Xs, Ys).

这没有上述谓词所具有的非终止问题：

?- list_copy([1, 2, 3], Ys).
Ys = [1, 2, 3].

?- list_copy(Xs, [1, 2, 3]).
Xs = [1, 2, 3].

?- list_copy([1, 2, X], [A, B, 3]).
X = 3,
A = 1,
B = 2.

?- list_copy([1, 2 | Rest], [A, B, 3, 4]).
Rest = [3, 4],
A = 1,
B = 2.

如果一个参数是一个列表，另一个是一个变量，则会建立一个新的列表结构并绑定到这个变量。

但是...为什么你需要一个新的列表结构呢？在纯 Prolog 中，您无法判断两个术语是否相同（即共享相同的内存位置）或“只是”在结构上相等。您通常也不关心（或不应该）。 （在非纯 Prolog 中有关于共享和显式复制的知识的用途，但同样我们不知道您要做什么。）

因此，如果我们无法判断“副本”是否确实是副本或只是“一个相等的术语”，那么我们根本不需要复制。我们可以通过统一得到与上面完全相同的行为：

?- [1, 2, 3] = Ys.
Ys = [1, 2, 3].

?- Xs = [1, 2, 3].
Xs = [1, 2, 3].

?- [1, 2, X] = [A, B, 3].
X = 3,
A = 1,
B = 2.

?- [1, 2 | Rest] = [A, B, 3, 4].
Rest = [3, 4],
A = 1,
B = 2.

不需要复制，当然也不需要“递归追加”来实现统一，Prolog 知道如何为您进行统一。

如果这不是您想要的，请告诉我们实际问题是什么。 “递归追加”几乎肯定不是它。

Answer 2

Prolog 是一种不同的编程范式。它要求您“忘记”您对编程的所有了解并以开放的心态学习。不要在使用“普通”变量并重新影响不同值时尝试学习 Prolog，Prolog 变量只有一个值或没有。它们可能仅在回溯时采用不同的值，并尝试为程序中的所有变量找到另一组满足所有给定谓词的值。

建议您阅读“立即学习 Prolog”之类的书籍。大量来自州立大学的教程可在互联网上免费获得。

根据您最近对调用 recursiveAppend 的示例进行的编辑，下面是符合示例的代码。

recursiveAppend(X, Y) :- recursiveAppend(X, [], Y).

    recursiveAppend([], X, X).
    recursiveAppend([H|T], Current, Output):-
        append(Current, [H], NewTemp),
        recursiveAppend(T, NewTemp, Output).

您之前的代码返回 false，因为 append 需要列表作为参数。所以附加一个整数（输入列表的项目）总是会失败。我创建了一个版本 recursiveAppend/3 来在第二个参数中累积当前列表。在列表的末尾，当前列表成为最终输出。您能否通过更多示例进一步测试它并告诉我们它是否按要求工作。