Perl 脚本不会多次打印 <STDIN>

Question

我有这个 Perl 脚本：

#!/usr/bin/perl
use strict;
use warnings;

print <STDIN>, "\n";
print <STDIN>, "\n";
print <STDIN>, "\n";
print <STDIN>, "\n";
print <STDIN>, "\n";

我将“Hello”传递给脚本的标准输入：

echo "Hello" | perl test.pl

我希望它打印“Hello”五次，但它只打印“Hello”后跟五个换行符。谁能解释为什么这不能按预期工作？

Answer 1

print <STDIN>, "\n";

<STDIN>（即readline(STDIN)）“在列表上下文中读取，直到到达文件末尾并返回行列表。”

因此，在您的程序中，第一个 print 会打印 all 从 STDIN 读取的行。

根据定义，不再有来自STDIN 的行，因为<STDIN> 在列表上下文中读取了所有要读取的内容。

如果你想从STDIN读取连续的五行并打印出来，你需要：

print scalar <STDIN>;
print scalar <STDIN>;
print scalar <STDIN>;
print scalar <STDIN>;
print scalar <STDIN>;

根据定义，一行以换行符结束。如果你不删除它，就没有必要再粘上另一个了。

我更直观的是，<STDIN> 表示的值一旦通过管道传输到脚本中就会保存在内存中的某个位置

您的程序不包含存储从STDIN 读取的输入的指令。它所做的只是阅读STDIN 上的所有内容，打印所有内容，然后丢弃。

如果您想存储从STDIN 读取的所有内容，则必须明确这样做。这就是计算机程序的工作方式：它们完全按照被告知的方式运行。想象一下，如果计算机程序根据编写或运行它们的人的直觉来做不同的事情，那将是一场多么灾难。

当然，来自STDIN 的数据可能是无限的。在这种情况下，将所有内容存储在某个地方是不切实际的。

Answer 2

如果您想循环打印用户定义的文本次数， 你可以像这样使用 do while 循环：

#!/usr/bin/env perl
#Program: stdin.pl
use strict;
use warnings;
use feature 'say'; # like print but automatic ending newline.

my $i = 1; # Our incrementer.
my $input; # Our text from standard input that we want to loop.
my $total; # How many times we want to print the text on a loop.

say "Please provide the desired text of your standard input.";
chomp($input = <STDIN>); # chomp removes a newline from the standard input. 
say "Please provide the amount of times that you want to print your standard input to the screen.";
chomp($total = <STDIN>);
say ">>> I'm in your loop! <<<"; 
do # A do while loop iterates at least once and up to the total number of iterations provided by user. 
{
say "Iteration $i of text: $input";
$i++;
}while($i <= $total);
say ">>> I'm out of your loop! <<<";

这是我在标准输入中使用“Hello”和“8”执行代码时得到的结果：

> perl .\stdin.pl
Please provide the desired text of your standard input.
Hello!
Please provide the amount of times that you want to print your standard input to the screen.
8
>>> I'm in your loop! <<<
Iteration 1 of text: Hello!
Iteration 2 of text: Hello!
Iteration 3 of text: Hello!
Iteration 4 of text: Hello!
Iteration 5 of text: Hello!
Iteration 6 of text: Hello!
Iteration 7 of text: Hello!
Iteration 8 of text: Hello!
>>> I'm out of your loop! <<<