如何使用热键中断循环

Question

这应该很容易！ I've checked out this thread，但没用。

我似乎无法使用热键跳出循环。这个想法是您可以使用单个热键启动和停止循环过程。

似乎timeron 的值一旦开始就永远不会进入循环。

这是一个示例脚本：

#singleinstance force

timeron = 0
return

!f7::
    if(timeron){
        timeron = 0
        msgbox Okay, the loop is off.
    }else{
        timeron = 1 ;if this is not set to one, the loop will not begin
        msgbox Turning on the loop.
        gosub, STARTLOOPING
    }
RETURN


STARTLOOPING:
    ;do this over and over
    loop{
        if(!timeron)
            break   
        ;now wait for the right length of time before continuing the loop
        msgbox, The loop yet continues....
        Sleep, 5000
        if(!timeron)
            break
    }
RETURN

我在这里错过了什么？

Answer 1

由于您的 !F7 永远不会结束，第二次按 !F7 将被忽略。 默认情况下，每个热键一次只允许一个线程。

添加

#MaxThreadsPerHotkey 2

作为脚本的第二行，第二次按 !F7 可以停用循环。

Answer 2

为什么不使用计时器呢？它们允许您的脚本在计时器运行之间执行其他操作，从而允许热键中断它们：

timeron := false
Exit
!F7::
    if(timeron) {
        timeron := false
        SetTimer, MyTimer, Off
    } else {
        timeron := true
        ; Call GoSub once if you want the subroutine
        ; to fire immediately at the beginning
        GoSub, MyTimer
        ; Then let the timer repeat it
        SetTimer, MyTimer, 5000
    }
return

MyTimer:
    Msgbox, Looping like crazy!
return

您始终可以用计时器替换循环的功能。如果您有某种 for 循环/计数器，则可以改用全局变量。