VBA将msoThemeColor存储在变量中

Question

我希望将 mso 主题颜色存储在一个变量中，以便图表颜色和模式可以动态变化（在这种情况下为变量 Th）。这是我当前的代码：

Dim Th As Long
Th = "msoThemeColorAccent" & ActiveCell.Offset(-5, 0)
If ActiveCell = "Realized" Then
    ActiveChart.SeriesCollection(Srs).Select

    With Selection.Format.Fill
        .ForeColor.ObjectThemeColor = Th
        .Solid
    End With
    With Selection.Format.Line
       .ForeColor.ObjectThemeColor = Th
    End With
End If

我认为这里的问题是我没有使用正确的 Dim 分类。我在这里看到了关于将 RGB 存储为变量的问题（使用 Dim Long 似乎是解决方案），但在 msoThemeColors 上还没有。谢谢，如果我可以提供任何其他详细信息，请告诉我！

Answer 1

很难判断发生了什么，因为您的代码严重依赖默认成员。无论如何：

Dim Th As Long

这是正确的。

Dim themeColorIndex As MsoThemeColorIndex

这是正确的和明确的（请参阅 MSDN 上的 MsoThemeColorIndex）。

作为Scott Holtzman said，这里可能的值是Enum 值，而不是字符串：您根本无法通过将字符串连接到定义的Enum 名称之一来生成正确的值。

所以通过这样做：

Th = "msoThemeColorAccent" & ActiveCell.Offset(-5, 0)

我的猜测是ActiveCell.Offset(-5, 0) 必须包含一个介于 1 和 6 之间的数字。这是一个危险的假设：ActiveCell 可以是字面上的任何东西。如果该值在特定单元格中，请通过其地址引用它：

themeColorIndex = Sheet1.Range("B12").Value

这稍微好一点，但它仍然假设B12 中的值可以隐式转换为Long 整数。

Dim selectedValue As Variant
selectedValue = Sheet1.Range("B12").Value
If Not IsNumeric(selectedValue) Then 
    MsgBox "Invalid value!"
    Exit Sub
End If

If Sheet1.Range("E12").Value <> "Realized" Then Exit Sub

Dim themeColorIndex As MsoThemeColorIndex
themeColorIndex = selectedValue

如果您只对msoThemeColorAccent1 到msoThemeColorAccent6 感兴趣，那么您会希望B12 包含值5 到10，它们是基础枚举值您正在寻找的。​​p>

如果您的工作表出于可用性原因必须允许值 1 到 6，那么您可以这样做：

Dim themeColorIndex As MsoThemeColorIndex
'msoThemeColorAccent1 underlying value is 5, so we add 4 to the value:
themeColorIndex = selectedValue + 4

那么你在做另一个危险的假设：你假设有一个活跃的图表！假设图表存在于Sheet1，您最好再次明确地参考它：

Dim theChart As ChartObject
Set theChart = Sheet1.ChartObjects(1)
With theChart.SeriesCollection(srs) 'whatever srs means
    With .Format
        .Fill.ForeColor.ObjectThemeColor = themeColorIndex
        .Fill.Solid
        .Line.ForeColor.ObjectThemeColor = themeColorIndex
    End With
End With

Answer 2

由于 msoThemeColorAccent 是一个枚举，下面重构的代码将起作用。

Dim lThemeColor As Long
lThemeColor = ActiveCell.Offset(-5, 0) + 4
'msoThemeColor1 enum is 5, 2 is 6, 3 is 7 ... so add 4 to the value 

If ActiveCell = "Realized" Then

    With ActiveChart.SeriesCollection(Srs).Format
        With .Fill
            .ForeColor.ObjectThemeColor = lThemeColor
            .Solid
        End With
        With .Line
           .ForeColor.ObjectThemeColor = lThemeColor
        End With
    End With

End If