将 xml 转换为 csv（第一行的标签名称为列名，第二行包含匹配的数据到列（标签））答案

【问题标题】：Transform xml to csv(First row has tag names as Column name, second row includes the matched data to the column(tag))将 xml 转换为 csv（第一行的标签名称为列名，第二行包含匹配的数据到列（标签））
【发布时间】：2014-06-09 21:53:26
【问题描述】：

我目前正在将 xml 转换为 csv，在 csv 中应该有两行，第一行是 xml 中的所有标签名称（其中包含数据的标签），第二行是与第一行匹配的所有数据标签。我有两个单独的 xsl：

<xsl:stylesheet version="1.0"
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
 <xsl:output method="text"/>
 <xsl:strip-space elements="*"/>

    <xsl:template match="/">
    <xsl:apply-templates select="//text()"/>
    </xsl:template>

    <xsl:template match="text()">
      <xsl:copy-of select="."/>
      <xsl:if test="not(position()=last())">,</xsl:if>
    </xsl:template>
</xsl:stylesheet>

这个可以将我期望的第二行数据的 xml 转换为 csv。

我有以下xsl可以从xml中抓取所有标签，但我只想要带有数据的标签，比如<Languages><Lanuage1>English</Language1><Lanuage2>French</Language2></Languages>我只需要标签Language1和Language2

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:output method="xml"/>
  <xsl:template match="@*">
    <xsl:element name="{name()}">
      <xsl:value-of select="."/>
    </xsl:element>
  </xsl:template>
  <xsl:template match="*">
    <xsl:copy>
      <xsl:apply-templates select="*|@*"/>
      <xsl:if test="not(position()=last())">,</xsl:if>
    </xsl:copy>
  </xsl:template>
</xsl:stylesheet>

谁能解决上面的标签问题，把这两个xsl组合起来。

谢谢。

【问题讨论】：

这个问题不清楚。请发布您的输入 XML 和预期输出。

标签： java xml xslt csv

【解决方案1】：

怎么样：

<?xml version="1.0" encoding="utf-8"?>
<xsl:stylesheet version="1.0"
                xmlns:xsl="http://www.w3.org/1999/XSL/Transform">

<xsl:output method="text"/>

<xsl:template match="/">
  <xsl:variable name="nodes" select="//*[normalize-space(text()) != '']"/>
  <xsl:for-each select="$nodes">
    <xsl:value-of select="local-name()"/>
    <xsl:if test="not(position()=last())">
      <xsl:text>,</xsl:text>
    </xsl:if>
  </xsl:for-each>
  <xsl:text>&#x0A;</xsl:text>
  <xsl:for-each select="$nodes">
    <xsl:value-of select="."/>
    <xsl:if test="not(position()=last())">
      <xsl:text>,</xsl:text>
    </xsl:if>
  </xsl:for-each>
</xsl:template>

</xsl:stylesheet>

【讨论】：