如果条目存在，则从带括号的条目中提取四个不带括号的数字

Question

我有什么：

• B 列中包含大约 1000 个报告标题的列表。
• 其中一些标题在文本和数字字符串的某处有一个用括号括起来的四位数字（例如：(3672)）。
• 我想在同一行的 C 列中提取这四个数字 - 不带括号。
• 如果B列中没有带括号的四位数字，则在C列中返回“”。

到目前为止我所拥有的：

我可以成功识别 B 列中的单元格，这些单元格中有四位数字用括号括起来。问题是它返回了包括四个数字在内的整个标题。

取自：VBA RegEx extracting data from within a string

注意：我正在使用 Excel Professional Plus 2010，已选中“Microsoft VBScript 正则表达式 5.5”旁边的框。

Sub ExtractTicker()

Dim regEx
Dim i As Long
Dim pattern As String
Set regEx = CreateObject("VBScript.RegExp")
regEx.IgnoreCase = True
regEx.Global = True
regEx.pattern = "(\()([0-9]{4})(\))"

For i = 2 To ActiveSheet.UsedRange.Rows.Count
    If (regEx.Test(Cells(i, 2).Value)) Then
        Cells(i, 3).Value = regEx.Replace(Cells(i, 2).Value, "$2")
    End If
Next i

End Sub

Answer 1

试试

regEx.pattern = "(.*\()([0-9]{4})(\).*)"

.* 和字符串的开头和结尾确保您捕获整个字符串，然后将其完全替换为第二个子匹配 ([0-9]{4}) p>

全面优化代码

• 使用变量数组而不是范围
• 当您对完整字符串运行不区分大小写的匹配时，设置 Global 和 IgnoreCase 是多余的
• 您使用的是后期绑定，因此您不需要参考

代码

Sub ExtractTicker()

Dim regEx As Object
Dim pattern As String
Dim X
Dim lngCNt As Long

X = Range([b1], Cells(Rows.Count, "B").End(xlUp)).Value2
Set regEx = CreateObject("VBScript.RegExp")

With regEx
    .pattern = "(.*\()([0-9]{4})(\).*)"
    For lngCNt = 1 To UBound(X)
        If .Test(X(lngCNt, 1)) Then
            X(lngCNt, 1) = .Replace(X(lngCNt, 1), "$2")
        Else
            X(lngCNt, 1) = vbNullString
        End If
    Next
End With

[c1].Resize(UBound(X, 1), 1).Value2 = X

End Sub