如何使用 XSLT 转换按标签分隔值/循环标签答案

【问题标题】：How to separate the values by tag using XSLT Transformation/ loop the tag如何使用 XSLT 转换按标签分隔值/循环标签
【发布时间】：2020-06-09 05:46:16
【问题描述】：

我正在尝试按标签分隔地图输出值。现在我在一个（BOM）标签中获取所有值。我希望输出由每个 BOMTransactionType（已删除/已添加）分隔。我正在使用 XSLT 转换来分离它。谁能让我知道我该怎么做。谢谢。

DataProcess Shape 中的 XSLT 转换逻辑：

<xsl:stylesheet version="1.0"

 xmlns:xsl="http://www.w3.org/1999/XSL/Transform">

 <xsl:output omit-xml-declaration="yes" indent="yes"/>

 <xsl:strip-space elements="*"/>



 <xsl:template match="/*">

 <PLMData>

 <ChangeOrders>

  <AffectedItems>

   <BOM>

     <xsl:apply-templates/>

   </BOM>

 </AffectedItems>

 </ChangeOrders>

</PLMData>

 </xsl:template>



//Split the ItemNumber

 <xsl:template match="ItemNumber/text()" name="split">

 <xsl:param name="pText" select="."/>



 <xsl:if test="$pText">

  <xsl:element name="ItemNumber">

   <xsl:value-of select= "substring-before(concat($pText, ','), ',')"/>

  </xsl:element>

  <xsl:call-template name="split">

   <xsl:with-param name="pText" select="substring-after($pText, ',')"/>

  </xsl:call-template>

 </xsl:if>

 </xsl:template>



//Split the BOMTransactionType 

<xsl:template match="BOM/BOMTransactionType/text()" name="split1">

 <xsl:param name="bText" select="."/>

 <xsl:param name="bOrd" select="1"/>



 <xsl:if test="$bText">

  <xsl:element name="BOMTransactionType">

   <xsl:value-of select= "substring-before(concat($bText, ','), ',')"/>

  </xsl:element>

  <xsl:call-template name="split1">

   <xsl:with-param name="bText" select="substring-after($bText, ',')"/>

  </xsl:call-template>

 </xsl:if>

 </xsl:template>



</xsl:stylesheet>

输入：

<PLMData>

<ChangeOrders>

<AffectedItems>

<BOM>

<ItemNumber>P00001,020-00003-01</ItemNumber>

<BOMTransactionType>Added,Deleted</BOMTransactionType>

</BOM>

</AffectedItems>

</ChangeOrders>

</PLMData>

输出：

<PLMData>

<ChangeOrders>

<AffectedItems>

<BOM>

<ItemNumber>P00001</ItemNumber>

<ItemNumber>020-00003-01</ItemNumber>

<BOMTransactionType>Added</BOMTransactionType>

<BOMTransactionType>Deleted</BOMTransactionType>

</BOM>

</AffectedItems>

</ChangeOrders>

</PLMData>

预期输出：

<PLMData>

<ChangeOrders>

<AffectedItems>

<BOM>

<ItemNumber>P00001</ItemNumber>

<BOMTransactionType>Added</BOMTransactionType>

</BOM>

<BOM>

<ItemNumber>020-00003-01</ItemNumber>

<BOMTransactionType>Deleted</BOMTransactionType>

</BOM>

</AffectedItems>

</ChangeOrders>

</PLMData>

【问题讨论】：

标签： xslt transformation

【解决方案1】：

我会这样做：

XSLT 1.0

<xsl:stylesheet version="1.0" 
xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:output method="xml" version="1.0" encoding="UTF-8" indent="yes"/>
<xsl:strip-space elements="*"/>

<!-- identity transform -->
<xsl:template match="@*|node()">
    <xsl:copy>
        <xsl:apply-templates select="@*|node()"/>
    </xsl:copy>
</xsl:template>

<xsl:template match="BOM">
    <xsl:call-template name="tokenize">
        <xsl:with-param name="item-numbers" select="ItemNumber"/>
        <xsl:with-param name="transaction-types" select="BOMTransactionType"/>
    </xsl:call-template>
</xsl:template>

<xsl:template name="tokenize">
    <xsl:param name="item-numbers"/>
    <xsl:param name="transaction-types"/>
    <xsl:param name="delimiter" select="','"/>
    <BOM>
        <ItemNumber>
            <xsl:value-of select="substring-before(concat($item-numbers, $delimiter), $delimiter)" />
        </ItemNumber>
        <BOMTransactionType>
            <xsl:value-of select="substring-before(concat($transaction-types, $delimiter), $delimiter)" />
        </BOMTransactionType>
    </BOM>
    <xsl:if test="contains($item-numbers, $delimiter)">
        <!-- recursive call -->
        <xsl:call-template name="tokenize">
            <xsl:with-param name="item-numbers" select="substring-after($item-numbers, $delimiter)"/>
            <xsl:with-param name="transaction-types" select="substring-after($transaction-types, $delimiter)"/>
        </xsl:call-template>
    </xsl:if>
</xsl:template>

</xsl:stylesheet>

【讨论】：