在 XSLT 中拆分和转换分隔字符串答案

【问题标题】：Splitting up and transforming delimited string in XSLT在 XSLT 中拆分和转换分隔字符串
【发布时间】：2014-12-18 17:03:33
【问题描述】：

这是我要转换的 XML 示例：

<dsQueryResponse>
  <Rows>
    <Row Contacts="#111;#Smith, John;#112;#Sue, Mary;#113;#Jones, Rick" />
    <Row Contacts="#114;#Lee, Thomas;#115;#Richards, Kate" />
  </Rows>
</dsQueryResponse>

使用 XSLT，我如何将其拆分，以便输出如下所示：

<div>
  <span>#111;#Smith, John</span>
  <span>#112;#Sue, Mary</span>
  <span>#113;#Jones, Rick</span>
</div>
<div>
  <span>#114;#Lee, Thomas</span>
  <span>#115;#Richards, Kate</span>
</div>

; 被用作分隔符，而每个集合都包含它，这让我感到困惑。

编辑：
是的，我知道这个post。
我已经尝试过了，但它并没有按照我需要的方式拆分。
; 是一个分隔符并且也是拆分内容的一部分。

【问题讨论】：

@Tomalak 这个问题比这复杂一点。
@DanielHaley 这个问题比这复杂一点。
我看过那个帖子并尝试过，但它太分裂了。例如，#111、#Smith, John、#112、#Sue, Mary (4) 而不是 #111;#Smith, John、#112;#Sue, Mary (2)
您使用的是哪个特定的 XSLT 1.0 处理器？
@michael.hor257k 老实说，我不知道。我猜 SharePoint 2010 正在使用什么。

标签： xml xslt xpath xslt-1.0 xslt-grouping

【解决方案1】：

试试这个方法：

XSLT 1.0

<xsl:stylesheet version="1.0" 
xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:output method="xml" omit-xml-declaration="yes" version="1.0" encoding="utf-8" indent="yes"/>

<xsl:template match="/dsQueryResponse">
    <body>
        <xsl:for-each select="Rows/Row">
            <div>
               <xsl:call-template name="tokenize">
                    <xsl:with-param name="text" select="@Contacts"/>
                </xsl:call-template>
            </div>
        </xsl:for-each>
    </body>
</xsl:template>

<xsl:template name="tokenize">
    <xsl:param name="text"/>
    <xsl:param name="delimiter" select="';'"/>
    <xsl:choose>
        <xsl:when test="contains($text, $delimiter) and contains(substring-after($text, $delimiter), $delimiter)">
            <span>
                <xsl:value-of select="substring-before($text, $delimiter)"/>
                <xsl:value-of select="$delimiter"/>
                <xsl:value-of select="substring-before(substring-after($text, $delimiter), $delimiter)"/>
            </span>
            <!-- recursive call -->
            <xsl:call-template name="tokenize">
                <xsl:with-param name="text" select="substring-after(substring-after($text, $delimiter), $delimiter)"/>
            </xsl:call-template>
        </xsl:when>
        <xsl:otherwise>
            <span>
                <xsl:value-of select="$text"/>
            </span>
        </xsl:otherwise>
    </xsl:choose>
</xsl:template>

</xsl:stylesheet>

注意：
如果有 XML 地狱，你的源文档的作者将被烧死。

【讨论】：

哈哈哈！太棒了！（XML 是由 SharePoint 生成的。这肯定不是最容易处理的 XML，哈哈）