如何提取以逗号分隔的元素的键？

Question

XML...

<BaseElement>
     <AttributeList
     >ThreadId=1,ThreadName=Foo,ApplicationName=Bar</AttributeList>
</BaseElement>

我正在尝试提取 ThreadId 中的值...

<xsl:apply-templates select="AttributesList"/>

上面显示了整个列表； ThreadId=1,ThreadName=Foo, ...

查看了子字符串，但本质上看起来相当固定。它需要动态，以便如果 key（在本例中为 ThreadId）更改为 NewFangledThreadId，它会继续运行。

Answer 1

这种转换是完全参数化和通用的：

<xsl:stylesheet version="1.0"
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
 <xsl:output method="text"/>

 <xsl:param name="pAttrName" select="'AttributeList'"/>
 <xsl:param name="pKeyName" select="'ThreadId'"/>

 <xsl:template match="/">
  <xsl:value-of select=
   "substring-before(
           substring-after(concat(',',
                                   /*/*[name()=$pAttrName],
                                   ','
                                  ),
                            concat(',', $pKeyName, '=')
                            ),
                     ','
                     )
   "/>
 </xsl:template>
</xsl:stylesheet>

应用于提供的 XML 文档时：

<BaseElement>
    <AttributeList
    >ThreadId=1,ThreadName=Foo,ApplicationName=Bar</AttributeList>
</BaseElement>

产生了想要的正确结果：

1

当我们只指定时：

 <xsl:param name="pKeyName" select="'ApplicationName'"/>

再次产生正确的结果：

Bar

Answer 2

以下样式表：

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
    <xsl:output method="text"/>
    <xsl:template match="AttributeList">
        <xsl:value-of select="substring-before(substring-after(., '='), ',')"/>
    </xsl:template>
</xsl:stylesheet>

输出：

1

它选择第一个=之后和第一个,之前的字符串部分。