列出 XML 文件中的每个节点答案

【问题标题】：List every node in an XML file列出 XML 文件中的每个节点
【发布时间】：2010-10-29 12:47:29
【问题描述】：

简单的情况...对于任何随机 XML 文件，我想创建它包含的每个节点的列表，但没有任何重复！所以像：

<root name="example">
  <child id="1">
    <grandchild/>
  </child>
  <child id="2"/>
  <child id="3"/>
</root>

翻译成：

/root
/root/@name
/root/child
/root/child/@id
/root/child/grandchild

如何做到这一点，仅使用 XSLT？

【问题讨论】：

好问题，+1。请参阅我的答案以获得完整的、不太长且高效的 XSLT 1.0 解决方案。 :)
在我自己的答案中查看我的评论和我自己的代码。不过，您的解决方案很棒。但我不想要编号，只想要名字。

标签： xslt xslt-1.0

【解决方案1】：

只是为了好玩，没有扩展功能。

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
    <xsl:template match="text()"/>
    <xsl:template match="*|@*">
        <xsl:param name="pPath"/>
        <xsl:param name="pNames" select="'&#xA;'"/>
        <xsl:variable name="vPath"
                      select="concat($pPath,'/',
                                     substring('@',
                                               1 div (count(.|../@*) =
                                                      count(../@*))),
                                     name())"/>
        <xsl:variable name="vNames">
            <xsl:if test="not(contains($pNames,
                                       concat('&#xA;',$vPath,'&#xA;')))">
                <xsl:value-of select="concat($vPath,'&#xA;')"/>
            </xsl:if>
            <xsl:apply-templates select="*[1]|@*">
                <xsl:with-param name="pPath" select="$vPath"/>
                <xsl:with-param name="pNames" select="$pNames"/>
            </xsl:apply-templates>
        </xsl:variable>
        <xsl:value-of select="$vNames"/>
        <xsl:apply-templates select="following-sibling::*[1]">
            <xsl:with-param name="pPath" select="$pPath"/>
            <xsl:with-param name="pNames" select="concat($pNames,$vNames)"/>
        </xsl:apply-templates>
    </xsl:template>
</xsl:stylesheet>

输出：

/root
/root/@name
/root/child
/root/child/@id
/root/child/grandchild

编辑：更好的 XSLT/XPath 2.0 示例。此 XPath 2.0 行：

string-join(
   distinct-values(
      (//*|//@*)
         /string-join(
            (ancestor::node()/name(),
             if (self::attribute())
                then concat('@',name())
                else name()),
            '/')),
   '&#xA;')

【讨论】：

接受这个只是因为它是迄今为止最短的解决方案。 :-) XPath 2.0 版本看起来也很有趣，但不幸的是，我必须使用 1.0...
@Workshop Alex：很高兴这对您有所帮助。到今天为止，使用 XSLT 2.0 没有任何限制：有 .NET、Java、.COM 实现免费和付费。
是的，我知道。不幸的是，我将使用 MSXML 从 Delphi/WIN32 应用程序调用样式表。这个样式表实际上将有助于确定另一个 Delphi/WIN32 应用程序在内部和外部发送什么。除了它已经使用的之外，我只是不想在其中添加依赖项。
@Workshop Alex：使用 MSXML 的依赖项几乎与使用... Altova XSLT 2.0 的依赖项相同。
我知道，但是对 MSXML 的依赖已经是项目的一部分。 Altova 或其他任何东西的依赖都不是。此样式表用于调试目的，因此我更愿意避免向项目添加更多组件。（基本上，我正在开发一种工具，可以让测试人员更容易看到内部 XML 文件。）

【解决方案2】：

我自己也解决了！这样：

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform" xmlns:fo="http://www.w3.org/1999/XSL/Format" xmlns:msxsl="urn:schemas-microsoft-com:xslt" exclude-result-prefixes="fo msxsl">
  <xsl:output method="text" standalone="yes" encoding="UTF-8"/>
  <xsl:param name="Detect">false</xsl:param>
  <xsl:param name="Root"/>
  <xsl:variable name="NewLine" select="'
'"/>
  <xsl:template match="/">
          <xsl:variable name="Nodes">
            <xsl:apply-templates select="/" mode="Loop"/>
          </xsl:variable>
          <xsl:variable name="SortedNodes">
            <xsl:apply-templates select="msxsl:node-set($Nodes)" mode="Nodes">
              <xsl:sort select="." order="ascending" case-order="lower-first" data-type="text"/>
            </xsl:apply-templates>
          </xsl:variable>
          <xsl:apply-templates select="msxsl:node-set($SortedNodes)" mode="Text"/>
  </xsl:template>
  <!-- Elementen. -->
  <xsl:template match="*" mode="Loop">
    <xsl:param name="Node"/>
    <Node>
      <xsl:value-of select="$Node"/>/<xsl:value-of select="name()"/>
    </Node>
    <xsl:apply-templates select="@*" mode="Loop">
      <xsl:with-param name="Node" select="concat($Node, '/', name())"/>
    </xsl:apply-templates>
    <xsl:apply-templates select="*" mode="Loop">
      <xsl:with-param name="Node" select="concat($Node, '/', name())"/>
    </xsl:apply-templates>
  </xsl:template>
  <!-- Attributen. -->
  <xsl:template match="@*" mode="Loop">
    <xsl:param name="Node"/>
    <Node>
      <xsl:value-of select="$Node"/>/@<xsl:value-of select="name()"/>
    </Node>
  </xsl:template>
  <!-- Node. -->
  <xsl:template match="Node" mode="Nodes">
    <xsl:if test="(1=position()) or (preceding-sibling::*[1]/. != .)">
      <Node>
        <xsl:value-of select="."/>
      </Node>
    </xsl:if>
  </xsl:template>
  <xsl:template match="Node" mode="Text"><xsl:value-of select="concat(., $NewLine)"/></xsl:template>
</xsl:stylesheet>

只有 48 行。 :-)

【讨论】：

我的解决方案是 133 行，因为它使用的现有代码比你想要的要多得多——我真的不得不删掉一些代码。我的解决方案还可以生成任何其他节点的路径：根 (/)、文本节点、PI、cmets 和命名空间节点。另外，我只需要 2 分钟来重用这段代码，而从头开始编写即使是简单的解决方案也可能需要至少 10 分钟并且容易出错，因此实际上可能需要更长的时间。 :)

【解决方案3】：

这种转换（133 行，其中许多已被注释掉）：

<xsl:stylesheet version="1.0"
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
 xmlns:msxsl="urn:schemas-microsoft-com:xslt"
 exclude-result-prefixes="msxsl">
 <xsl:output omit-xml-declaration="yes" indent="yes"/>
 <xsl:strip-space elements="*"/>

 <xsl:key name="kPathByVal" match="path" use="."/>

 <xsl:template match="node()|@*">
  <path>
    <xsl:call-template name="buildPath"/>
  </path>
  <xsl:apply-templates select="node()|@*"/>
 </xsl:template>

 <xsl:template match="/">
  <xsl:variable name="vrtfPaths">
   <xsl:apply-templates/>
  </xsl:variable>

  <xsl:variable name="vPaths" select="msxsl:node-set($vrtfPaths)/*"/>

  <xsl:for-each select=
   "$vPaths[generate-id()
           =
            generate-id(key('kPathByVal',.)[1])
           ]
   ">
    <xsl:value-of select="concat(.,'&#xA;')"/>
  </xsl:for-each>
 </xsl:template>

<xsl:template name="buildPath">
 <xsl:variable name="pNode" select="."/>
  <xsl:variable name="theResult">
    <xsl:for-each select="$pNode">
    <xsl:variable name="theNode" select="."/>
    <xsl:for-each select=
    "$theNode
    |
     $theNode/ancestor-or-self::node()[..]">
      <xsl:element name="slash">/</xsl:element>
      <xsl:choose>
        <xsl:when test="self::*">
          <xsl:element name="nodeName">
            <xsl:value-of select="name()"/>
          </xsl:element>
        </xsl:when>
        <xsl:otherwise> <!-- This node is not an element -->
          <xsl:choose>
            <xsl:when test="count(. | ../@*) = count(../@*)">
            <!-- Attribute -->
              <xsl:element name="nodeName">
                <xsl:value-of select="concat('@',name())"/>
              </xsl:element>
            </xsl:when>
            <xsl:when test="self::text()">  <!-- Text -->
              <xsl:element name="nodeName">
                <xsl:value-of select="'text()'"/>
                <xsl:variable name="thisPosition"
                          select="count(preceding-sibling::text())"/>
                <xsl:variable name="numFollowing"
                          select="count(following-sibling::text())"/>
                <xsl:if test="$thisPosition + $numFollowing > 0">
                  <xsl:value-of select=
                  "concat('[', $thisPosition +1, ']')"/>
                </xsl:if>
              </xsl:element>
            </xsl:when>
            <xsl:when test="self::processing-instruction()">
            <!-- Processing Instruction -->
              <xsl:element name="nodeName">
                <xsl:value-of select="'processing-instruction()'"/>
                <xsl:variable name="thisPosition"
                   select="count(preceding-sibling::processing-instruction())"/>
                <xsl:variable name="numFollowing"
                    select="count(following-sibling::processing-instruction())"/>
                <xsl:if test="$thisPosition + $numFollowing > 0">
                  <xsl:value-of select=
                  "concat('[', $thisPosition +1, ']')"/>
                </xsl:if>
              </xsl:element>
            </xsl:when>
            <xsl:when test="self::comment()">   <!-- Comment -->
              <xsl:element name="nodeName">
                <xsl:value-of select="'comment()'"/>
                <xsl:variable name="thisPosition"
                         select="count(preceding-sibling::comment())"/>
                <xsl:variable name="numFollowing"
                         select="count(following-sibling::comment())"/>
                <xsl:if test="$thisPosition + $numFollowing > 0">
                  <xsl:value-of select=
                  "concat('[', $thisPosition +1, ']')"/>
                </xsl:if>
              </xsl:element>
            </xsl:when>
            <!-- Namespace: -->
            <xsl:when test=
              "count(. | ../namespace::*)
              =
               count(../namespace::*)">

              <xsl:variable name="apos">'</xsl:variable>
              <xsl:element name="nodeName">
                <xsl:value-of select="concat('namespace::*',
                '[local-name() = ', $apos, local-name(), $apos, ']')"/>

              </xsl:element>
            </xsl:when>
          </xsl:choose>
        </xsl:otherwise>
      </xsl:choose>
    </xsl:for-each>
    <!-- <xsl:text>&#xA;</xsl:text> -->
  </xsl:for-each>
 </xsl:variable>
 <xsl:value-of select="$theResult"/>
</xsl:template>

应用于提供的 XML 文档时：

<root name="example">
  <child id="1">
    <grandchild/>
  </child>
  <child id="2"/>
  <child id="3"/>
</root>

产生想要的正确结果：

/root
/root/@name
/root/child
/root/child/@id
/root/child/grandchild

【讨论】：

几乎！但我不希望其中有 [1] 编号的东西。只有节点自己命名。（参见示例。）