复制节点并更改其内容

Question

我有点卡在我想对 xml 文件进行的转换上。

基本上我正在尝试复制所有的 xml，但更改一些标签，这些标签只能这样开始

XML 代码：

<test alt="foo" title="bar"/>

通过 xsl 后我想得到什么：

<test alt="foo"/>

或者

<change alt="foo" title=""/>

问题是，有时我的标签有很多属性，所以我不想进行模板匹配，然后手动更改每个属性。

其实我就是这样做的：

<xsl:template match="test">
    <change><xsl:apply-templates select="@*|node()"/></change>
</xsl:template>

<xsl:template match="test/@title">
    <xsl:attribute name="title">
        <xsl:value-of select=""/>
    </xsl:attribute>
</xsl:template>

但它不会改变输出中标题的内容。

Answer 1

对于所有此类任务，您应该从身份转换模板开始

<xsl:template match="@* | node()">
  <xsl:copy>
    <xsl:apply-templates select="@* | node()"/>
  </xsl:copy>
</xsl:template>

然后为需要特殊处理的节点添加模板，例如

<xsl:template match="@* | node()">
  <xsl:copy>
    <xsl:apply-templates select="@* | node()"/>
  </xsl:copy>
</xsl:template>

<xsl:template match="test/@title"/>

将复制所有未更改的内容，但会删除 test 元素的所有 title 属性。

或者

    <xsl:template match="@* | node()">
      <xsl:copy>
        <xsl:apply-templates select="@* | node()"/>
      </xsl:copy>
    </xsl:template>

<xsl:template match="test">
    <change><xsl:apply-templates select="@*|node()"/></change>
</xsl:template>

<xsl:template match="test/@title">
    <xsl:attribute name="title"/>
</xsl:template>

应该实现您的第二个要求。如果您仍有问题，请发布最少但完整的示例，以便我们重现问题。

Answer 2

要删除除alt 之外的任何属性，请使用身份转换，但有一个例外：

样式表（移除其他属性）

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform" >

    <xsl:output method="xml" version="1.0" encoding="utf-8" indent="yes"/>

    <xsl:template match="@*|node()">
          <xsl:copy>
             <xsl:apply-templates select="@*|node()"/>
          </xsl:copy>
    </xsl:template>

    <xsl:template match="@*[name() != 'alt']"/>

</xsl:stylesheet>

输出

<?xml version="1.0" encoding="utf-8"?>
<test alt="foo"/>

---

否则，要将除alt 之外的所有属性的值设置为""，请使用：

样式表（使其他属性为空）

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform" >

    <xsl:output method="xml" version="1.0" encoding="utf-8" indent="yes"/>

    <xsl:template match="@*|node()">
          <xsl:copy>
             <xsl:apply-templates select="@*|node()"/>
          </xsl:copy>
    </xsl:template>

    <xsl:template match="test">
        <change>
            <xsl:apply-templates select="@*|node()"/>
        </change>
    </xsl:template>

    <xsl:template match="@*[name() != 'alt']">
        <xsl:attribute name="{name()}"/>
    </xsl:template>

</xsl:stylesheet>

输出

<?xml version="1.0" encoding="utf-8"?>
<change alt="foo" title=""/>