使用 marklogic 使用外部 Web 服务

Question

遇到困难。查找有关如何使用 marklogic 访问外部 Web 服务的示例？ （也许我的搜索词有误？我也试过xdmp:http-get、xdmp:http-post、发布http 请求、mash-up、编排）。

我首先需要了解，在我继续合并来自使用 ML 在一个页面中提供 3 个不同的 Web 服务（这个混搭的正确术语是什么？）。

将非常感谢使用 ML 的示例。我见过 celsius 到 fahrenheit 的转换示例，还有股票报价请求和响应，但在 ML 中没有。我不知道如何或从哪里开始。你能指出我正确的方向吗？渴望学习将 ML 用于 Web 服务。

非常感谢。

Answer 1

我想说这里有例子：http://docs.marklogic.com/xdmp:http-post

但为了完整起见，让我也添加这些：

基于： http://www.w3schools.com/xml/tempconvert.asmx?op=FahrenheitToCelsius

SOAP 1.1：

let $envelop :=
  <soap:Envelope xmlns:xsi="http://www.w3.org/2001/XMLSchema-instance" xmlns:xsd="http://www.w3.org/2001/XMLSchema" xmlns:soap="http://schemas.xmlsoap.org/soap/envelope/">
    <soap:Body>
      <FahrenheitToCelsius xmlns="http://www.w3schools.com/xml/">
        <Fahrenheit>100</Fahrenheit>
      </FahrenheitToCelsius>
    </soap:Body>
  </soap:Envelope>
return
  xdmp:http-post(
    "http://www.w3schools.com/xml/tempconvert.asmx",
    <options xmlns="xdmp:http">
      <headers>
        <Content-Type>text/xml; charset=utf-8</Content-Type>
        <SOAPAction>"http://www.w3schools.com/xml/FahrenheitToCelsius"</SOAPAction>
      </headers>
    </options>,
    $envelop
  )

SOAP 1.2：

let $envelop :=
  <soap12:Envelope xmlns:xsi="http://www.w3.org/2001/XMLSchema-instance" xmlns:xsd="http://www.w3.org/2001/XMLSchema" xmlns:soap12="http://www.w3.org/2003/05/soap-envelope">
    <soap12:Body>
      <FahrenheitToCelsius xmlns="http://www.w3schools.com/xml/">
        <Fahrenheit>100</Fahrenheit>
      </FahrenheitToCelsius>
    </soap12:Body>
  </soap12:Envelope>
return
  xdmp:http-post(
    "http://www.w3schools.com/xml/tempconvert.asmx",
    <options xmlns="xdmp:http">
      <format xmlns="xdmp:document-get">xml</format>
      <headers>
        <Content-Type>application/soap+xml; charset=utf-8</Content-Type>
      </headers>
    </options>,
    $envelop
  )

HTTP POST：

let $body := text {
  string-join(
    ("Fahrenheit=" || encode-for-uri(string(100))),
    "&"
  )
}
return
  xdmp:http-post(
    "http://www.w3schools.com/xml/tempconvert.asmx/FahrenheitToCelsius",
    <options xmlns="xdmp:http">
      <headers>
        <Content-Type>application/x-www-form-urlencoded</Content-Type>
      </headers>
    </options>,
    $body
  )

HTH！