XSLT 1.0 贪婪背包分组方法？

Question

我有一个 XML 数据集（从 SharePoint 2007 提供给 DVWP），其结构类似于：

<Rows>
  <Row ID="1" Spanoffset="0" Span="55" Spantail="55"/>
  <Row ID="2" Spanoffset="30" Span="31" Spantail="61"/>
  <Row ID="3" Spanoffset="61" Span="20" Spantail="81"/>
  <Row ID="4" Spanoffset="82" Span="30" Spantail="112"/>
</Rows>

假设每一行代表一个从@Spanoffset 开始且宽度为@Span 的条形，@Spantail 在那里，所以如果我需要它就不必计算它。我正在尝试将这些行有效地打包在一起，以便将不会重叠的行组合在一起。数据集由@Spanoffset 预先排序。这本质上是一个背包问题，因为每一行都可以适合多个可能的组。我想做的是一个简单的贪婪解决方案，并且知道如何用 c# 或 java 对其进行编码，但是由于我无法将节点标记为已访问（我可以，但是当我回到递归树时我会丢失它）而且我在访问节点时似乎无法删除它们，我不知道如何解决这个问题。

例如，上面的数据看起来像这样：

<div style="clear:both">
  <div style="width: 110px; margin-left: 0px; float:left;">1</div>
  <div style="width: 40px; margin-left: 12px; float:left;">3</div>
  <div style="width: 60px; margin-left: 2px; float:left;">4</div>
</div>
<div style="clear:both">
  <div style="width: 62px; margin-left: 60px; float:left;">2</div>
</div>

我没有费心试图让浮动正常工作，因为我还没有能够让Row 节点以正确的顺序每个只出现一次。一旦我把它们弄到那里，我就可以确定我可以解决格式问题。

到目前为止，我提出的最好的 XSLT 是：

<xsl:template match="row">
  <xsl:variable name="tail" select="@Spantail"/>
  <div style="width:{2*@Span}px;
    left:{2*(@Spanoffset)}px;">
    <xsl:value-of select="@ID"/>
  </div>                        
  <xsl:apply-templates select="(following-sibling::row)[@Spanoffset>=$tail][1]"/>
</xsl:template>

生成

<div style="width: 110px;left: 0px">1</div>
<div style="width: 40px; left: 122px">3</div>
<div style="width: 60px; left: 164px">4</div>
<div style="width: 62px; left: 60px">2</div>
<div style="width: 40px; left: 122px">3</div>
<div style="width: 60px; left: 164px">4</div>
<div style="width: 40px; left: 122px">3</div>
<div style="width: 60px; left: 164px">4</div>
<div style="width: 60px; left: 164px">4</div>

所以我的问题是 2（我看到），我认为它们是相互交织的。 1）如何修复/重构我的模板以仅发出每行一次。 和 2）如何将分组包装在容器<div>元素中。

这两天一直在努力解决这个问题，有人能帮忙吗？

编辑： 好吧，经过一些睡眠后，我通过向我的模板添加一个布尔参数来拥有包装容器，并在其为真时使用一些CDATA 标签来发出<div> 标签。布尔值默认为 true，当我调用嵌套的应用模板时，我将其设置为 false，因此将组包装在容器中。我仍然看不到将<Row>s 标记为已访问的方法。

Answer 1

我认为仅使用核心 XSLT 非常棘手，但使用 XSLT 扩展函数 node-set() 会更容易：

<xsl:template name="add-row">
    <xsl:param name="row"/>
    <xsl:param name="prev-group" />
    <xsl:if test="$row and not($row/@ID = $prev-group/Row/@ID)">
        <xsl:copy-of select="$row" />
        <xsl:call-template name="add-row">
            <xsl:with-param name="row" select="$row/following-sibling::Row[@Spanoffset &gt; $row/@Spantail][1]" />
            <xsl:with-param name="prev-group" select="$prev-group" />
        </xsl:call-template>
    </xsl:if>   
</xsl:template>

<xsl:template name="add-group">
    <xsl:param name="first-row" />
    <xsl:param name="prev-group" select="exsl:node-set(/)" />
    <xsl:if test="$first-row">
        <xsl:variable name="group">
            <xsl:call-template name="add-row">
                <xsl:with-param name="row" select="$first-row" />
                <xsl:with-param name="prev-group" select="$prev-group" />
            </xsl:call-template>
        </xsl:variable>
        <div clear="both">
            <xsl:for-each select="exsl:node-set($group)/Row">
                <div style="width: {2*@Span}px; left: {2*@Spanoffset}px"><xsl:value-of select="@ID"/></div>                             
            </xsl:for-each>
        </div>
        <xsl:call-template name="add-group">
            <xsl:with-param name="first-row" select="$first-row/following-sibling::Row[@Spanoffset &lt; preceding-sibling::Row/@Spantail][1]" />
            <xsl:with-param name="prev-group" select="exsl:node-set($group)" />
        </xsl:call-template>
    </xsl:if>
</xsl:template>

<xsl:template match="Rows">
    <xsl:call-template name="add-group">
        <xsl:with-param name="first-row" select="Row[1]" />
    </xsl:call-template>
</xsl:template>

不要忘记在样式表标签中声明扩展前缀和命名空间：

<xsl:stylesheet
  version="1.0"
  xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
  extension-element-prefixes="exsl"
  xmlns:exsl="http://exslt.org/common">

http://exslt.org/common 是 Java XSLT 处理器（例如 Xalan 或 Saxon）的有效命名空间；如果您使用的是 MSXML，请改用 urn:schemas-microsoft-com:xslt。