错误的 XSLT 代码？

Question

这是 XML

<?xml version="1.0" encoding="utf-8"?>
<Groups>
    <GroupData ID="xxx" Key="4" Temp="yyy">
        <ItemData ID="zzz" Value="3"/>
    </GroupData>
    <GroupData ID="yyy" Key="4" Temp="yyy">
        <ItemData ID="abc" Value="3"/>
    </GroupData>
    <GroupData ID="zzz" Temp="yyy">
        <ItemData ID="pqr" Value="1982"/>
    </GroupData>
    <GroupData ID="xxx" Key="4" Temp="yyy">
        <ItemData ID="www" Value="1982"/>
    </GroupData>
    <GroupData ID="yyy" Key="4" Temp="yyy">
        <ItemData ID="def" Value="1982"/>
    </GroupData>
    <GroupData ID="zzz" Temp="yyy">
        <ItemData ID="tuv" Value="1982"/>
    </GroupData>
</Groups>

我想变成这样：

<GroupData ID="xxx" Key="4" Temp="yyy">
 <ItemData ID="zzz" Value="3"/>
 <ItemData ID="www" Value="1982"/>
</GroupData>

以其他GroupData id 依此类推。

这是我的非工作 XSLT 代码：

<?xml version = "1.0" encoding = "utf-8"?>
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:key name="group-data" match="GroupData" use="ItemData"/>
<xsl:template match="/">
  <xsl:for-each select="Groups/GroupData[generate-id() = generate-id(key('group-data', ItemData)[1])]">
    <xsl:copy-of select="key('group-data', ItemData)"/>
  </xsl:for-each>
</xsl:template>
</xsl:stylesheet>

附：我一直在查看 Muenchian Method 和该论坛的另一个主题，但我想自己编写它，因为我必须将它应用到更大、更扭曲的 XML 文档上。

Answer 1

首先出错的是你的钥匙

<xsl:key name="group-data" match="GroupData" use="ItemData"/>

这表示您希望按子 ItemData 元素的内容对 GroupData 元素进行分组。但是你所有的 ItemData 元素都没有价值，所以你只有一个“组”。看起来您实际上想在这里按 ID 属性进行分组

<xsl:key name="group-data" match="GroupData" use="@ID"/>

现在，在您的 xsl:for-each 中，您拥有获取不同组元素的正确语法，但在循环中您只想创建第一个不同 的副本GroupData，然后复制组中所有项目的子 ItemData 元素。

<xsl:copy>
   <xsl:copy-of select="@*|key('group-data', @ID)/ItemData"/>
</xsl:copy>

试试这个 XSLT

<?xml version = "1.0" encoding = "utf-8"?>
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
   <xsl:output method="xml" indent="yes" />
   <xsl:key name="group-data" match="GroupData" use="@ID"/>
   <xsl:template match="/">
     <xsl:for-each select="Groups/GroupData[generate-id() = generate-id(key('group-data', @ID)[1])]">
         <xsl:copy>
               <xsl:copy-of select="@*|key('group-data', @ID)/ItemData"/>
         </xsl:copy>
     </xsl:for-each>
   </xsl:template>
</xsl:stylesheet>

实际上，如果您使用identity transform 来复制元素并使用更符合XSLT 精神的模板，这里会更好。试试这个：

<?xml version = "1.0" encoding = "utf-8"?>
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
   <xsl:output method="xml" indent="yes" />
   <xsl:key name="group-data" match="GroupData" use="@ID"/>
   <xsl:template match="/">
          <xsl:apply-templates select="Groups/GroupData[generate-id() = generate-id(key('group-data', @ID)[1])]" />
  </xsl:template>

   <xsl:template match="GroupData">
       <GroupData>
            <xsl:apply-templates select="@*|key('group-data', @ID)/ItemData" />
       </GroupData>
  </xsl:template>

  <xsl:template match="@*|node()">
    <xsl:copy>
      <xsl:apply-templates select="@*|node()"/>
    </xsl:copy>
  </xsl:template>

</xsl:stylesheet>