XSLT 2.0 - 如何合并兄弟元素

Question

如何将特定元素与相同类型的相邻兄弟元素合并为一个元素？我觉得这应该很简单，但找不到答案。

我的代码：

...
<nodeX>
  <a>words</a>
  <b>things</b>
  <g>hi</g>
  <g>there</g>
  <g>friend</g>
  <c>stuff</c>
  <g>yep</g>
</nodeX>
...

期望的输出：

...
<nodeX>
  <a>words</a>
  <b>things</b>
  <g>hi there friend</g>
  <c>stuff</c>
  <g>yep</g>
</nodeX>
...

我正在处理一个极其复杂且多变且层次结构很深的文档，因此除了这些元素会在某些上下文中出现以及当它们与相邻元素一起出现时，我无法处理许多假设。兄弟姐妹，那些兄弟姐妹需要合并。任何帮助将不胜感激。

更新：

使用 zx485 和 Martin Honnen 的建议，以下似乎可以很好地仅打开特定元素：

<xsl:template match="nodeX">
    <xsl:copy>
        <xsl:copy-of select="@*" />
        <xsl:for-each-group select="*" group-adjacent="name()">
            <xsl:choose>
                <xsl:when test="name()='g'">
                    <xsl:copy>
                        <xsl:copy-of select="current-group()/@*" />
                        <xsl:value-of select="current-group()"/>
                    </xsl:copy>
                </xsl:when>
                <xsl:otherwise>
                    <xsl:apply-templates select="current-group()"/>
                </xsl:otherwise>
            </xsl:choose>
        </xsl:for-each-group>
    </xsl:copy>
</xsl:template>

Answer 1

对于 XSLT-2.0，这并不难。这是一个XSLT-2.0 Grouping 问题。在这种情况下，使用 xsl:for-each-group 和属性 group-adjacent。

以下模板匹配所有nodeX 元素并复制它们，包括它们的属性。它遍历所有子元素并按name() 对相邻元素进行分组。然后它复制组的第一个元素并添加具有相同名称的所有元素的属性。现在这个组中所有元素的text()s 用一个分隔符连接在一起 - 这里是一个空格。

<xsl:template match="nodeX">
    <xsl:copy>
        <xsl:copy-of select="@*" />
        <xsl:for-each-group select="*" group-adjacent="name()">
            <xsl:copy>
                <xsl:copy-of select="current-group()/@*" />
                <xsl:value-of select="current-group()" separator=" " />
            </xsl:copy>
        </xsl:for-each-group>
    </xsl:copy>
</xsl:template> 

输出为：

<nodeX>
   <a>words</a>
   <b>things</b>
   <g>hi there friend</g>
   <c>stuff</c>
   <g>yep</g>
</nodeX>