自定义逻辑属性的元素不起作用

Question

在将元素转换为属性时，我正在检查父元素的名称是否存在于我们尝试转换为属性的元素中。

planet_name 等示例是元素，它包含父元素（行星），因此需要将其转换为属性，否则按原样。

我编写了 xslt，但它无法正常工作，有人可以帮忙吗？提前致谢。

示例 XML 示例：

<world>
            <planet>
               <planet_name>solaris</plante_name>
               <planet_number>23</plante_number>
               <test>value1</test>
             </planet>
</world>

预期输出：

<world>
            <planet planet_name="solaris" planet_number="23">
               <test>value1</test>
             </planet>
</world>

XSLT 如下

<xsl:stylesheet version="1.0"
    xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
    <xsl:output indent="yes" />
    <xsl:strip-space elements="*" />

    <!--Identity transform -->
    <xsl:template match="@*|node()">
        <xsl:copy>
            <xsl:apply-templates select="@*|node()" />
        </xsl:copy>
    </xsl:template>

    <!--Match elements that contain children elements that don't contain children 
        elements themselves. -->
    <xsl:template match="*[*[not(*)]]">
        <xsl:copy>
            <xsl:for-each select="*">
                <xsl:variable name="attrName" select="name()" />
                <xsl:variable name="parentName" select="name(..)" />
                <xsl:choose>
                    <xsl:when test="contains(normalize-space($parentName),normalize-space($attrName))">
                        <xsl:attribute name="{name()}">
                           <xsl:value-of select="$parentName" />
                        </xsl:attribute>
                    </xsl:when>
                    <xsl:otherwise>
                        <xsl:copy>
                            <xsl:apply-templates select="node()" />
                        </xsl:copy>
                    </xsl:otherwise>
                </xsl:choose>
            </xsl:for-each>
        </xsl:copy>
    </xsl:template>
</xsl:stylesheet>

Answer 1

我会建议一种不同的方法：

XSLT 1.0

<xsl:stylesheet version="1.0" 
xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:output method="xml" version="1.0" encoding="UTF-8" indent="yes"/>
<xsl:strip-space elements="*"/>

<xsl:template match="*">
    <xsl:copy>
        <xsl:copy-of select="@*"/>
        <xsl:apply-templates select="*[starts-with(name(), name(current()))]" mode="attr"/>
        <xsl:apply-templates select="node()[not(starts-with(name(), name(current())))]"/>
    </xsl:copy>
</xsl:template>

<xsl:template match="*" mode="attr">
    <xsl:attribute name="{name()}">
        <xsl:value-of select="." />
    </xsl:attribute>
</xsl:template>

</xsl:stylesheet>