使用 xslt1.0 从字符串中删除所有单个字符

Question

<title>
 <article_title>Land a b   c   d      Band</article_title>
</title>

使用以下函数

replace(article_title, '(^[^ ]+)(.+\s+)([^ ]+)$', '$1 $3')

这个字符串被转换为 Land Band，这正是我想要的。

但问题是我在 xslt 1.0 中需要这个解决方案，因为我正在使用的 java 应用程序只能处理 xslt 1.0 解析。

Answer 1

这个 XSLT 1.0 转换（有一个讨厌的 SO 错误并且代码没有缩进 - 我为这个视觉混乱道歉......）：

<xsl:stylesheet version="1.0"
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
 <xsl:output omit-xml-declaration="yes" indent="yes"/>
 <xsl:strip-space elements="*"/>

 <xsl:template match="node()|@*">
  <xsl:copy>
   <xsl:apply-templates select="node()|@*"/>
  </xsl:copy>
 </xsl:template>

 <xsl:template match="text()" name="removeSingles">
   <xsl:param name="pText" select="."/>

   <xsl:variable name="vText" select="normalize-space($pText)"/>

   <xsl:if test="string-length($vText)">
    <xsl:variable name="vLeftChars" select=
    "substring-before(concat($vText, ' '), ' ')"/>

    <xsl:if test="string-length($vLeftChars) >1">
     <xsl:value-of select="$vLeftChars"/>
     <xsl:if test=
      "not(string-length($vLeftChars)
          >=
           string-length($vText)
           )
      ">
       <xsl:text> </xsl:text>
      </xsl:if>
    </xsl:if>

    <xsl:call-template name="removeSingles">
     <xsl:with-param name="pText" select=
     "substring-after($vText, ' ')"/>
    </xsl:call-template>
   </xsl:if>
 </xsl:template>
</xsl:stylesheet>

应用于提供的 XML 文档时：

<title>
 <article_title>Land a b   c   d      Band</article_title>
</title>

产生想要的正确结果：

<title>
   <article_title>Land Band</article_title>
</title>