XSLT：根据条件仅拆分某些元素答案

【问题标题】：XSLT: Split only certain elements based on conditionXSLT：根据条件仅拆分某些元素
【发布时间】：2017-05-29 14:09:38
【问题描述】：

我正在尝试以下输入文件的 XSLT 代码：

<?xml version="1.0" encoding="UTF-8"?>
<result>
   <records>
      <dataProcessed>
         <FieldName>Tesco</FieldName>
         <Mode>As Is</Mode>
      </dataProcessed>

      <dataProcessed>
         <FieldName>ASDA|Tesco|Walmart</FieldName>
         <Mode>Split</Mode>
      </dataProcessed>
   </records>
   <records>
      <dataProcessed>
         <FieldName>Orange|MTS</FieldName>
         <Mode>Split</Mode>
      </dataProcessed>
   </records>
</result>

当字段 Mode 的值为 'Split' 时，我需要使用管道分隔符拆分段，并且我需要根据拆分将字段 Mode 的值更改为 1,2 等。期望的输出是：

    <?xml version="1.0" encoding="UTF-8"?>
    <result>
       <records>
          <dataProcessed>
             <FieldName>Tesco</FieldName>
             <Mode>As Is</Mode>
          </dataProcessed>

          <dataProcessed>
             <FieldName>ASDA</FieldName>
             <Mode>1</Mode>
          </dataProcessed>

          <dataProcessed>
             <FieldName>Tesco</FieldName>
             <Mode>2</Mode>
          </dataProcessed>

          <dataProcessed>
             <FieldName>Walmart</FieldName>
             <Mode>3</Mode>
          </dataProcessed>
       </records>
       <records>
          <dataProcessed>
             <FieldName>Orange</FieldName>
             <Mode>1</Mode>
          </dataProcessed>

          <dataProcessed>
             <FieldName>MTS</FieldName>
             <Mode>2</Mode>
          </dataProcessed>
       </records>
    </result>

这是我正在尝试的代码：

<xsl:stylesheet version="1.0"
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
    <xsl:template match="@*|node()">
        <xsl:copy>
            <xsl:apply-templates select="@*|node()"/>
        </xsl:copy>
    </xsl:template>
    <xsl:template match="result/records/dataProcessed[Mode = 'Split']">
  <xsl:copy>
    <xsl:call-template name="parse-comma-separated">
      <xsl:with-param name="elements" select="'FieldName,Mode'"/>
      <xsl:with-param name="text" select="."/>
    </xsl:call-template>
  </xsl:copy>
</xsl:template>

<xsl:template name="parse-comma-separated">
  <xsl:param name="elements"/>
  <xsl:param name="text"/>
  <xsl:choose>
    <xsl:when test="contains($elements, '|')">
      <xsl:element name="{normalize-space(substring-before($elements, ','))}">
        <xsl:value-of select="normalize-space(substring-before($text, ','))"/>
      </xsl:element>
      <xsl:call-template name="parse-comma-separated">
        <xsl:with-param name="elements" select="substring-after($elements, ',')"/>
        <xsl:with-param name="text" select="substring-after($text, ',')"/>
      </xsl:call-template>
    </xsl:when>
    <xsl:otherwise>
      <xsl:element name="{normalize-space($elements)}">
        <xsl:value-of select="normalize-space($text)"/>
      </xsl:element>
    </xsl:otherwise>
  </xsl:choose>
</xsl:template>
</xsl:stylesheet>

【问题讨论】：

您的命名模板毫无意义。尝试从这里改编一个：stackoverflow.com/a/31593480/3016153 请注意，您必须将分隔符更改为|。
我尝试使用此代码，但仍然无法正常工作。我还将分隔符更改为 |

标签： xslt

【解决方案1】：

使用

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">

    <xsl:param name="delimiter" select="'|'"/>

    <xsl:output indent="yes"/>

    <xsl:template match="@* | node()">
        <xsl:copy>
            <xsl:apply-templates select="@* | node()"/>
        </xsl:copy>
    </xsl:template>

    <xsl:template match="result/records/dataProcessed[Mode = 'Split']">
        <xsl:param name="index" select="1"/>
        <xsl:param name="text" select="FieldName"/>
        <xsl:choose>
            <xsl:when test="not(contains($text, $delimiter))">
                <xsl:copy>
                    <FieldName>
                        <xsl:value-of select="$text"/>
                    </FieldName>
                    <Mode>
                        <xsl:value-of select="$index"/>
                    </Mode>
                </xsl:copy>
            </xsl:when>
            <xsl:otherwise>
                <xsl:copy>
                    <FieldName>
                        <xsl:value-of select="substring-before($text, $delimiter)"/>
                    </FieldName>
                    <Mode>
                        <xsl:value-of select="$index"/>
                    </Mode>
                </xsl:copy>
                <xsl:apply-templates select=".">
                    <xsl:with-param name="index" select="$index + 1"/>
                    <xsl:with-param name="text" select="substring-after($text, $delimiter)"/>
                </xsl:apply-templates>
            </xsl:otherwise>
        </xsl:choose>
    </xsl:template>

</xsl:stylesheet>

【讨论】：