DECLARE @xml XML = N'
<response>
<message_infos>
<message_info>
<id>397300589</id>
<pdu_id>673399673</pdu_id>
<status>12</status>
<id>397300589</id>
<pdu_id>673399675</pdu_id>
<status>12</status>
</message_info>
<message_info>
<id>397300591</id>
<pdu_id>673399669</pdu_id>
<status>12</status>
<id>397300591</id>
<pdu_id>673399671</pdu_id>
<status>12</status>
</message_info>
</message_infos>
</response>'
SELECT
id = MIN(CASE WHEN RowNumGroup = 1 THEN val END)
, pdu_id = MIN(CASE WHEN RowNumGroup = 2 THEN val END)
, [status] = MIN(CASE WHEN RowNumGroup = 0 THEN val END)
FROM (
SELECT
val = t.c.value('(./text())[1]', 'BIGINT')
, RowNum = ROW_NUMBER() OVER (ORDER BY 1/0)
, RowNumGroup = ROW_NUMBER() OVER (ORDER BY 1/0) % 3
FROM @xml.nodes('/response/message_infos/message_info/*') t(c)
) t
GROUP BY RowNum - CASE WHEN RowNumGroup = 0 THEN 3 ELSE RowNumGroup END
2016 年 5 月 30 日更新
准备数据：
SET NOCOUNT ON
IF OBJECT_ID('tempdb.dbo.#xml') IS NOT NULL
DROP TABLE #xml
GO
CREATE TABLE #xml (data XML)
GO
INSERT INTO #xml
SELECT TOP(10000) N'
<response>
<message_infos>
<message_info>
<id>397300589</id>
<pdu_id>673399673</pdu_id>
<status>12</status>
<id>397300589</id>
<pdu_id>673399675</pdu_id>
<status>12</status>
</message_info>
<message_info>
<id>397300591</id>
<pdu_id>673399669</pdu_id>
<status>12</status>
<id>397300591</id>
<pdu_id>673399671</pdu_id>
<status>12</status>
</message_info>
</message_infos>
</response>'
FROM [master].dbo.spt_values
米凯尔·埃里克森
DECLARE @d DATETIME = GETDATE()
SELECT T.X.value('(id/text())[sql:column("N.N")][1]', 'INT') AS id,
T.X.value('(pdu_id/text())[sql:column("N.N")][1]', 'INT') AS pdu_id,
T.X.value('(status/text())[sql:column("N.N")][1]', 'INT') AS [status]
FROM #xml x
CROSS APPLY data.nodes('/response/message_infos/message_info') AS T(X)
CROSS APPLY (
VALUES
(1),(2),(3),(4),(5),
(6),(7),(8),(9),(10)
) AS N(N)
WHERE N.N <= T.X.value('count(id)', 'INT')
SELECT 'Mikael Eriksson: ' + CAST(CAST(GETDATE() - @d AS TIME) AS VARCHAR(100))
GO
Shnugo
DECLARE @d DATETIME = GETDATE()
WITH AllMessageInfos AS (
SELECT ROW_NUMBER() OVER(ORDER BY(SELECT NULL)) AS Mi_Index
, mi.query('.') AS TheMI
FROM #xml x
CROSS APPLY data.nodes('/response/message_infos/message_info') AS A(mi)
)
, AllIDs AS (
SELECT Mi_Index
, ROW_NUMBER() OVER(PARTITION BY Mi_Index ORDER BY (SELECT NULL)) AS id_Index
, id.value('.','NVARCHAR(MAX)') AS id
FROM AllMessageInfos
CROSS APPLY TheMI.nodes('message_info/id') AS a(id)
)
, AllPdu_IDs AS (
SELECT Mi_Index
, ROW_NUMBER() OVER(PARTITION BY Mi_Index ORDER BY (SELECT NULL)) AS pdu_Index
, id.value('.','NVARCHAR(MAX)') AS pdu_id
FROM AllMessageInfos
CROSS APPLY TheMI.nodes('message_info/pdu_id') AS a(id)
)
, AllStatus AS (
SELECT Mi_Index
, ROW_NUMBER() OVER(PARTITION BY Mi_Index ORDER BY (SELECT NULL)) AS status_Index
, id.value('.', 'INT') AS status
FROM AllMessageInfos
CROSS APPLY TheMI.nodes('message_info/status') AS a(id)
)
SELECT i.Mi_Index AS MessageInfoIndex
, i.id_Index AS SubSetIndex
, i.id
, p.pdu_id
, s.[status]
FROM AllIDs AS i
JOIN AllPdu_IDs AS p ON i.Mi_Index = p.Mi_Index AND i.id_Index = p.pdu_Index
JOIN AllStatus AS s ON i.Mi_Index = s.Mi_Index AND i.id_Index = s.status_Index
SELECT 'Shnugo: ' + CAST(CAST(GETDATE()-@d AS TIME) AS VARCHAR(100))
GO
蒙特维兹多
DECLARE @d DATETIME = GETDATE()
SELECT
m.value('for $i in . return count(../../*[. << $i])', 'INT') AS message_info_position,
m.value('for $i in . return count(../*[. << $i]) + 1', 'INT') AS internal_position,
m.value('fn:local-name(.)', 'SYSNAME') AS element_name,
m.value('.', 'NVARCHAR(4000)') AS element_value
FROM #xml x
CROSS APPLY data.nodes('/response/message_infos/message_info/*') AS A(m)
SELECT 'Montewhizdoh: ' + CAST(CAST(GETDATE()-@d AS TIME) AS VARCHAR(100))
GO
德瓦特（旧）
DECLARE @d DATETIME = GETDATE()
SELECT
id = MAX(CASE WHEN name = 'id' THEN val END)
, pdu_id = MAX(CASE WHEN name = 'pdu_id' THEN val END)
, [status] = MAX(CASE WHEN name = 'status' THEN val END)
FROM (
SELECT
name = t.c.value('local-name(.)', 'SYSNAME')
, val = t.c.value('.', 'INT')
, RowNum = ROW_NUMBER() OVER (ORDER BY 1/0)
, RowNumGroup = ROW_NUMBER() OVER (ORDER BY 1/0) % 3
FROM #xml x
CROSS APPLY data.nodes('/response/message_infos/message_info/*') t(c)
) t
GROUP BY RowNum - CASE WHEN RowNumGroup = 0 THEN 3 ELSE RowNumGroup END
SELECT 'Devart (OLD): ' + CAST(CAST(GETDATE()-@d AS TIME) AS VARCHAR(100))
GO
德瓦特（新）
DECLARE @d DATETIME = GETDATE()
SELECT
id = MIN(CASE WHEN RowNumGroup = 1 THEN val END)
, pdu_id = MIN(CASE WHEN RowNumGroup = 2 THEN val END)
, [status] = MIN(CASE WHEN RowNumGroup = 0 THEN val END)
FROM (
SELECT
val = t.c.value('(./text())[1]', 'BIGINT')
, RowNum = ROW_NUMBER() OVER (ORDER BY 1/0)
, RowNumGroup = ROW_NUMBER() OVER (ORDER BY 1/0) % 3
FROM #xml x
CROSS APPLY data.nodes('/response/message_infos/message_info/*') t(c)
) t
GROUP BY RowNum - CASE WHEN RowNumGroup = 0 THEN 3 ELSE RowNumGroup END
SELECT 'Devart (NEW): ' + CAST(CAST(GETDATE()-@d AS TIME) AS VARCHAR(100))
性能对比（Core i5 4460 3.2GHz、DDR3 8Gb、SQL Server 2014 SP1 Express）：
Mikael Eriksson: 00:00:00.327
Shnugo: 00:00:00.913
Montewhizdoh: 00:00:01.680
Devart (OLD): 00:00:00.363
Devart (NEW): 00:00:00.200