如何应用 XSL 模板从文档的不同部分开始和结束 XML 元素答案

【问题标题】：How to apply XSL templates to start and finish XML element from different parts of the document如何应用 XSL 模板从文档的不同部分开始和结束 XML 元素
【发布时间】：2015-07-27 08:56:24
【问题描述】：

我正在尝试研究如何创建一个 HTML 文档，其中有时来自 XML 源的一组元素被“包装”在引导面板中。

XML 描述了垂直表单布局。因此，您有一组包含单个字段的行。如果有一个 PANELSTART 字段，我想在屏幕上启动一个面板，继续写出内容，然后当我点击一个 PANELEND 字段时，我想用匹配的</div> 关闭面板。但是 XSL 不允许这样做，因为所有元素都需要匹配的结束元素。
我试过了

<xsl:text>

但这似乎也不起作用。我有一个例子来说明。

源 XML：

<?xml version="1.0"?>
<rows>
    <row><field type="B><plainValue>B0</plainValue></field></row>
    <row><field type="PANELSTART"></field></row>
    <row><field type="B"><plainValue>B1</plainValue></field></row>
    <row><field type="PANELEND"/></row>
    <row><field type="C"><plainValue>C0</plainValue></field></row>
    <row><field type="D"><plainValue>D0</plainValue></field></row>
    <row><field type="B"><plainValue>B2</plainValue></field></row>
</rows>

XSLT：

<?xml version="1.0" encoding="ISO-8859-1"?>
<xsl:stylesheet version="1.0"
   xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
    <xsl:output method="html" />
 <xsl:template match="field[@type='PANELSTART']">
    <div class='panel'>panel header</div>
        <div class='panel-body'>
 </xsl:template>
 <xsl:template match="field[@type='B']">
     <p>content goes here</p>
 </xsl:template>
 <xsl:template match="field[@type='PANELEND']">
     </div>
 </xsl:template>
</xsl:stylesheet>

预期结果：

    <p>B0</p>
    <div class="panel">panel header</div>
    <div class="panel-body">
       <p>B1</p>
    </div>
    <p>C0</p>
    <p>D0</p>
    <p>B2</p>

非常感谢您对如何执行此操作的想法。不幸的是，我无法更改 XML 的结构。

【问题讨论】：

有趣的问题。一个rows 字段中是否可以有多个连续的PANELSTART/PANELEND 部分？
您使用的是 XSLT 1.0 还是 XSLT 2.0？
每行只有一个 PANELSTART，每行只有一个 PANELEND。在某些方面，不需要字段元素。最初我打算每行有很多字段，但现在每行只有一个字段。此外，面板不是嵌套的。 PANELSTART 总是有一个匹配的 PANELEND。
@TimC，它是 XSLT 1.0，但如果需要我可以切换到 2.0。
您能否编辑您的问题以在这种情况下显示预期的 HTML？谢谢！

标签： xml xslt

【解决方案1】：

在 XSLT 1.0 中，您可以使用“兄弟递归”：

<?xml version="1.0" encoding="UTF-8" ?>
<xsl:transform xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="1.0">

    <xsl:output method="html" indent="yes" version="5.0"/>

    <xsl:template match="rows">
        <div>
            <xsl:apply-templates select="row[1]"/>
        </div>
    </xsl:template>

    <xsl:template match="row[field[@type = 'PANELSTART']]">
        <div class="panel">panel header</div>
        <div class="panel-body">
            <xsl:apply-templates select="following-sibling::*[1]"/>
        </div>
        <xsl:apply-templates select="following-sibling::row[field[@type = 'PANELEND']][1]/following-sibling::*[1]"/>
    </xsl:template>

    <xsl:template match="row">
        <p>
            <xsl:apply-templates/>
        </p>
        <xsl:apply-templates select="following-sibling::*[1][not(self::row[field[@type = 'PANELEND']])]"/>
    </xsl:template>

</xsl:transform>

在线http://xsltransform.net/bdxtqY/2。

【讨论】：

感谢 Martin，请参阅我对 XML 的编辑。您的解决方案适用于我的初始示例，但缺少我的初始示例。我一直在xsltransform.net/6qVRKx3 使用您的代码，看看我是否可以让它工作。我很欣赏 xsltransform.net 的链接——我以前没有遇到过它——非常方便。明天我将继续查看示例和其他答案。
这看起来很相似。我也许可以在你的例子中使用一些东西。 Following sibling until reaching a specific tag
@JohnTempler，我已经编辑了代码以涵盖更复杂的情况，仍然使用兄弟递归。
谢谢马丁，效果很好。非常感谢。
我已经使用您在此处上传的答案xsltransform.net/bFDb2D8/2 实施了我的最终解决方案

【解决方案2】：

如果您能够使用 XSLT 2.0，您可能会让我们使用 xsl:for-each-group 及其 group-starting-with 属性

 <xsl:for-each-group select="row/field" group-starting-with="field[@type='PANELSTART']">

因此，类型属性为“PANELSTART”的每个字段构成每个组的开始。

试试这个 XSLT

<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="2.0">
    <xsl:output method="html" encoding="UTF-8" indent="yes" />

    <xsl:template match="rows">
        <xsl:for-each-group select="row/field" group-starting-with="field[@type='PANELSTART']">
        <div class='panel'>panel header</div>
            <div class='panel-body'>
                <xsl:apply-templates select="current-group()" />                
            </div>
        </xsl:for-each-group>
    </xsl:template>

    <xsl:template match="field[@type='B']">
        <p>content goes here</p>
    </xsl:template>

    <xsl:template match="field[@type='PANELEND']" />
</xsl:stylesheet>

不过，您可能会删除匹配“PANELEND”的模板。

阅读 xsl:for-each-group http://www.xml.com/pub/a/2003/11/05/tr.html

【讨论】：

这看起来很有趣。明天我会读一读。我更新了我的 XML 示例，因为它没有充分反映我的真实情况。

【解决方案3】：

此 XSLT 忽略所有 PANELSTART 和 PANELEND 行（实际上不是 B 的所有内容 - 但如有必要，可以重新组织它以忽略仅 PANELSTART 和 PANELEND） .它不是在fields 上循环，而是在rows 上循环。这意味着整个field/type B 集合被视为一个实体，因此您可以在其周围插入div。

它可以在rows 的多次出现下正常工作（每个都将获得一个自己的div），并且当其中没有“类型B”时将忽略整个fields 集合。

<?xml version="1.0" encoding="ISO-8859-1"?>
<xsl:stylesheet version="1.0"
   xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
    <xsl:output method="html" />

 <xsl:template match="rows">
    <xsl:if test="row/field/@type='B'">
    <div class='panel'>panel header</div>
    <div class='panel-body'>
        <xsl:apply-templates select="row/field[@type='B']" mode="process" />
    </div>
    </xsl:if>
</xsl:template>

<xsl:template match="field[@type='B']" mode="process">
    [<xsl:value-of select="." />]
</xsl:template>

</xsl:stylesheet>

【讨论】：