查找从今天开始的最后 10 天并在 Google 表格中查询答案

【问题标题】：Find the last 10 days from today and query in Google Sheets查找从今天开始的最后 10 天并在 Google 表格中查询
【发布时间】：2021-02-18 19:37:07
【问题描述】：

我在一个名为“报告”的选项卡中设置了这张表：

可以看出，A 列包含报告的日期和时间。最新的是 2 月 16 日，最早的是 1 月 28 日。

我想在另一个标签中查询从今天开始的最近 10 天。所以，如果今天是 2 月 17 日，我需要查询到 2 月 7 日之前的所有报告。

注意：我不需要最近 10 份报告，我需要最近 10 天，不管累积多少。

我尝试过这样的事情：

=QUERY(SORT({
'Reports'!A1:A;
}, 1, 0),
"where Col2 is not null limit 10", 0)

这是表格： https://docs.google.com/spreadsheets/d/1w7beVyUr0pEUoRSgqQYYOi0y0Sbd8scC3B825GKA3sQ/edit?usp=sharing

【问题讨论】：

您的日期数据存在很多问题。一半的日期是文本，而不是真实日期。另一半是数字，但不是您所在国家/地区认可的格式。这些信息是如何进入您的工作表的？此外，您的工作表当前设置为“仅查看”；所以我和其他任何人都不能访问您的工作表来测试公式或留下笔记。请将您的链接权限更改为“知道链接的任何人...”和“编辑”。

标签： sorting google-sheets google-sheets-formula

【解决方案1】：

试试这个：

=QUERY({Report!A1:B} ; "SELECT * 
WHERE Col2 is not null AND Col1 >= date '" 
& TEXT(NOW()-10; "yyyy-MM-dd") & "' ")

【讨论】：

【解决方案2】：

尝试：

=QUERY({Report!A1:B};
 "where Col1 >= date '"&TEXT(TODAY()-10; "yyyy-mm-dd")&"'
    and Col1 <= date '"&TEXT(TODAY();    "yyyy-mm-dd")&"'"; 0)

或来自控制表：

=ARRAYFORMULA(QUERY({IFNA(IF(N(Control!A2:A)<>0; Control!A2:A; DATE(
 REGEXEXTRACT(Control!A2:A; "/(\d+) "); 
 REGEXEXTRACT(Control!A2:A; "/(\d+)/"); 
 REGEXEXTRACT(Control!A2:A; "^\d+"))+
 INDEX(SPLIT(Control!A2:A; " ");;2)))\ Control!B2:B}; 
 "where Col1 >= "&DATEVALUE(TODAY()-10)&"
    and Col1 <= "&DATEVALUE(TODAY())&"
  format Col1 'mm/dd/yyyy hh:MM:ss'"; 0))

【讨论】：

它不起作用。我刚刚更新了问题并添加了访问的 URL！
嘿，@player0，看看我对 OP 的评论：日期格式。
又是我，@player0。我还应该注意到海报在巴西；所以所有公式都采用分号换逗号（等）格式。如果您继续在这方面寻求解决方案，只是提醒您节省时间。
@ErikTyler 感谢提醒。它看起来很熟悉：stackoverflow.com/a/66179934/5632629 ...无论如何，名为 Report 的工作表都有很好的日期 - i.stack.imgur.com/mewGA.png
@player0，我现在对数据将如何以及在何处实际进入此工作表（或现实世界的等效数据）感到困惑。如您所述，我看到“报告”表中有干净的数据。但是谁做的呢？它是如何到达那里的（该表中没有公式）？这是否准确地代表了真实数据将如何以及在何处进入工作表？无论如何，毫无疑问，考虑到我们所得到的，问题似乎已经得到解决。