用另一个命名空间替换一个命名空间答案

【问题标题】：Replacing one namespace with another用另一个命名空间替换一个命名空间
【发布时间】：2017-02-10 12:41:33
【问题描述】：

在下面的输入 XML 中，我得到了 ns1 和 ns2 前缀。
在输出中，命名空间 ns1 应替换为 dh，命名空间 ns2 应替换为 sk。

谁能帮忙解决这个问题。

<?xml version="1.0" encoding="UTF-8" ?> 
<sh:sampleDocument schemaVersion="" creationDate=""xmlns:sh="htpp://sample1.com">
    <sampleHeader>
        <ns1:sampledocumentheader xmlns:ns1="htpp://sample2.com">
            <ns1:HeaderVersion />                
            <ns1:ContactInformation>
                <ns1:Contact />                    
                <ns1:EmailAddress />                    
                <ns1:FaxNumber />                    
                <ns1:TelephoneNumber />                    
                <ns1:ContactTypeIdentifier />                    
            </ns1:ContactInformation>
        </ns1:sampledocumentheader>
    </sampleHeader>
    <sampleBody>
        <sampleList>
            <sampleEvent>
                <Time />                    
                <action />                    
                <ns2:sampleExtension xmlns:ns2="htpp://sample3.com">
                    <ns2:Value />                        
                    <ns2:Number />                        
                </ns2:sampleExtension>
            </sampleEvent>
        </sampleList>
    </sampleBody>
</sh:sampleDocument>

【问题讨论】：

这样做的目的是什么？前缀没有任何意义，可以是完全任意的；真正重要的是它绑定到的 URI。
接收者应用程序需要这些前缀来接受数据。我也和他们讨论过，但他们想要那些前缀。
所以他们懒得做对了，结果你还有额外的工作要做？

标签： node.js xml xslt xpath xml-namespaces

【解决方案1】：

应该没有必要这样做。命名空间前缀的选择是完全任意的。如果目标应用程序需要使用特定的前缀，那么需要修复的是目标应用程序，而不是您的 XML。

不管怎样，试试吧：

XSLT 1.0

<xsl:stylesheet version="1.0" 
xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
xmlns:ns1="htpp://sample2.com"
xmlns:ns2="htpp://sample3.com"
exclude-result-prefixes="ns1 ns2">
<xsl:output method="xml" version="1.0" encoding="UTF-8" indent="yes"/>
<xsl:strip-space elements="*"/>

<!-- identity transform -->
<xsl:template match="@*|node()">
    <xsl:copy>
        <xsl:apply-templates select="@*|node()"/>
    </xsl:copy>
</xsl:template>

<xsl:template match="ns1:*">
    <xsl:element name="dh:{local-name()}" namespace="{namespace-uri()}">
        <xsl:apply-templates select="@*|node()"/>
    </xsl:element>
</xsl:template>

<xsl:template match="ns2:*">
    <xsl:element name="sk:{local-name()}" namespace="{namespace-uri()}">
        <xsl:apply-templates select="@*|node()"/>
    </xsl:element>
</xsl:template>

</xsl:stylesheet>

【讨论】：