XSLT -- 为根元素生成唯一的 id 并将该值附加到子元素的 id答案

【问题标题】：XSLT -- generate unique id for root element and append that value to the id of child elementsXSLT -- 为根元素生成唯一的 id 并将该值附加到子元素的 id
【发布时间】：2012-10-05 18:50:06
【问题描述】：

我需要：

(1) 为根元素生成唯一的id属性

(2) 将该 id 附加到子元素

(3) 将任意父元素的名称和序列追加到子元素的id属性中

**注意——我的机器上有一个 XML 编辑器，它可以使用 XSLT 2.0，但更喜欢 1.0，因为每当我使用 Visual Basic 运行宏时，我认为 Microsoft xml/xslt 处理器只能处理 xslt 1.0。好像不喜欢2.0。

源 XML 示例：

<root>
<segment>
<para>Text of the segment here.</para>
</segment>
<segment>
<para>Text of the segment here.</para>
<para>Text of the segment here.</para>
</segment>
<segment>
<para>Text of the segment here.</para>
<sub_segment>
<para>Text of the segment here.</para>
</sub_segment>
</segment>
</root>

所需的输出 XML：

<root id="idrootx2x1">
<segment id="idrootx2x1.segment.1">
<para id="idrootx2x1.segment.1.para.1">Text of the segment here.</para>
</segment>
<segment id="idrootx2x1.segment.2">
<para id="idrootx2x1.segment.2.para.1">Text of the segment here.</para>
<para id="idrootx2x1.segment.2.para.2">Text of the segment here.</para>
</segment>
<segment id="idrootx2x1.segment.3">
<para id="idrootx2x1.segment.3.para.1">Text of the segment here.</para>
<sub_segment id="idrootx2x1.segment.3.sub_segment.1">
<para id="idrootx2x1.segment.3.sub_segment.1.para.1">Text of the segment here.</para>
</sub_segment>
</segment>
</root>

这是我目前拥有的 XSLT：

<xsl:template match="*|@*|text()">
<xsl:copy>
    <xsl:apply-templates select="*|@*|text()"/> 
</xsl:copy> 
</xsl:template>

<xsl:template match="root">
<xsl:copy>
    <xsl:attribute name="id"><xsl:value-of select="generate-id()"/></xsl:attribute>
    <xsl:apply-templates select="*|@*|text()"/>
</xsl:copy>
</xsl:template>

<xsl:template match="segment | para | sub_segment">
<xsl:copy>
    <xsl:attribute name="id">
        <xsl:value-of select="name(.)"/>.<xsl:number format="1" level="single"/>
    </xsl:attribute>
    <xsl:apply-templates select="*|@*|text()"/>
</xsl:copy>
</xsl:template>

【问题讨论】：

令人惊讶的是，您自己将所有这些标签一一标记为代码。下一次，也许可以使用“格式为代码”按钮一次标记整个块？

标签： xml xslt identity

【解决方案1】：

您可以像这样将您的父母编号传递给孩子：

<xsl:template match="@*|node()">
<xsl:copy>
    <xsl:apply-templates select="@*|node()"/>
</xsl:copy>
</xsl:template>

<xsl:template match="root">
<xsl:copy>
    <xsl:attribute name="id"><xsl:value-of select="generate-id()"/></xsl:attribute>
    <xsl:apply-templates select="@*|node()">
        <xsl:with-param name="prev_id" select="generate-id()"/>
    </xsl:apply-templates>
</xsl:copy>
</xsl:template>

<xsl:template match="segment|para|sub_segment">
<xsl:param name="prev_id"/>
<xsl:copy>
    <xsl:variable name="cur_id">
        <xsl:value-of select="concat($prev_id,'.',name())"/>.<xsl:number format="1" level="single"/>
    </xsl:variable>
    <xsl:attribute name="id"><xsl:value-of select="$cur_id"/></xsl:attribute>
    <xsl:apply-templates select="@*|node()">
        <xsl:with-param name="prev_id" select="$cur_id"/>
    </xsl:apply-templates>
</xsl:copy>
</xsl:template>

如果有一些其他非编号元素包裹了编号元素，请将标识模板更改为

<xsl:template match="@*|node()">
<xsl:param name="prev_id"/>
<xsl:copy>
    <xsl:apply-templates select="@*|node()">
        <xsl:with-param name="prev_id" select="$prev_id"/>
    </xsl:apply-templates>
</xsl:copy>
</xsl:template>

以便它转发父编号

【讨论】：