XPath 每个元素的最后一次出现

Question

我有类似的 XML

<root>
    <a>One</a>
    <a>Two</a>
    <b>Three</b>
    <c>Four</c>
    <a>Five</a>
    <b>
        <a>Six</a>
    </b>
</root>

并且需要选择根中任何子节点名称的最后一次出现。在这种情况下，所需的结果列表将是：

<c>Four</c>
<a>Five</a>
<b>
    <a>Six</a>
</b>

感谢任何帮助！

Answer 1

XPath 2.0 解决方案和当前接受的答案都非常低效 (O(N^2))。

此解决方案具有亚线性复杂度：

<xsl:stylesheet version="1.0"
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
 <xsl:output omit-xml-declaration="yes" indent="yes"/>
 <xsl:strip-space elements="*"/>

 <xsl:key name="kElemsByName" match="/*/*"
  use="name()"/>

 <xsl:template match="/">
  <xsl:copy-of select=
    "/*/*[generate-id()
         =
          generate-id(key('kElemsByName', name())[last()])
         ]"/>
 </xsl:template>
</xsl:stylesheet>

应用于提供的 XML 文档时：

<root>
    <a>One</a>
    <a>Two</a>
    <b>Three</b>
    <c>Four</c>
    <a>Five</a>
    <b>
        <a>Six</a>
    </b>
</root>

产生想要的正确结果：

<c>Four</c>
<a>Five</a>
<b>
   <a>Six</a>
</b>

说明：这是Muenchian grouping 的修改变体——所以不是第一个。但每组中的最后一个节点被处理。

II XPath 2.0 单线：

用途：

/*/*[index-of(/*/*/name(), name())[last()]]

使用 XSLT 2.0 作为 XPath 2.0 主机进行验证：

<xsl:stylesheet version="2.0"
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
 <xsl:output omit-xml-declaration="yes" indent="yes"/>

 <xsl:template match="/">
  <xsl:sequence select=
    "/*/*[index-of(/*/*/name(), name())[last()]]"/>
 </xsl:template>
</xsl:stylesheet>

当对同一个 XML 文档（前面提供）应用此转换时，会产生相同的正确结果：

<c>Four</c>
<a>Five</a>
<b>
    <a>Six</a>
</b>

Answer 2

如果你可以使用 XPath 2.0，这将起作用

/root//*[not(name() = following-sibling::*/name())]

Answer 3

基于 XSLT 的解决方案：

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="1.0">
    <xsl:output method="xml" indent="yes" omit-xml-declaration="yes"/>
    <xsl:strip-space elements="*"/>

    <xsl:template match="root/*">
        <xsl:variable name="n" select="name()"/>
        <xsl:copy-of
            select=".[not(following-sibling::node()[name()=$n])]"/>
    </xsl:template>
</xsl:stylesheet>

产生的输出：

<c>Four</c>
<a>Five</a>
<b>
   <a>Six</a>
</b>

第二种解决方案（您可以将其用作单个 XPath 表达式）：

<xsl:template match="/root">
    <xsl:copy-of select="a[not(./following-sibling::a)]
        | b[not(./following-sibling::b)]
        | c[not(./following-sibling::c)]"/>
</xsl:template>

Answer 4

现在，XSLT 2.0 为这些问题提供了grouping techniques：

<xsl:stylesheet version="2.0"
    xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
    <xsl:output omit-xml-declaration="yes" indent="yes" />
    <xsl:strip-space elements="*" />

    <xsl:template match="/root">
        <xsl:for-each-group select="*" group-by="name()">
            <!-- <xsl:sort select="index-of(/root/*, current-group()[last()])" order="ascending"/> -->
            <xsl:copy-of select="current-group()[last()]" />
        </xsl:for-each-group>
    </xsl:template>
</xsl:stylesheet>

将产生：

<a>Five</a>
<b>
  <a>Six</a>
</b>
<c>Four</c>

除非受到<xsl:sort>! 的明确影响，否则按文档顺序进行分组！