如何使用 xslt 在元素内拆分 xml 数据？答案

【问题标题】：How to split xml data inside an element using xlst?如何使用 xslt 在元素内拆分 xml 数据？
【发布时间】：2014-03-25 15:12:56
【问题描述】：

我有这样的 xml 数据：

<Invoice >
  <cac:AllowanceCharge>
  <cbc:ChargeIndicator>false</cbc:ChargeIndicator>

  <cbc:AllowanceChargeReason>ISK:y!#x!#w!#q!#t!#</cbs:AllowanceChargeReason>

  <cbc:MultiplierFactorNumeric>0.1</cbc:MultiplierFactorNumeric>
    </Invoice>

我必须将这个 AllowanceChargeReason 拆分为 !# 字符，并将结果放入一个数组中。并用这个数组循环，结果我想得到这个结果。如何为以下结果编写 xslt 代码？

<table>
<xsl:for-each >
<tr>
.......
</tr>
</xsl>
</table>

结果：

</table>
    <table>
    <tr>
      <td>
       y
      </td>
     <td>
       x
     </td>
     <td>
       w
     </td>
     <td>
       q
     </td>
    </tr> 
    </table>

【问题讨论】：

XSLT 没有“数组”类型。请展示您正在使用的 XML 格式的示例作为输入、您尝试实现的相应输出以及您迄今为止尝试过的 XSLT。
搜索 tokenize。
您可以使用 XSLT 2.0 还是仅限于 1.0 版？
我使用的是 1.0 版
以上信息是否足以解决问题？

标签： xml xslt xslt-1.0

【解决方案1】：

要在 XSLT 1.0 中执行此操作，您需要创建一个命名模板，该模板将递归调用自身。它会将要拆分的字符串作为参数，以及要拆分的分隔符

 <xsl:template name="split">
     <xsl:param name="text" select="." />
     <xsl:param name="delimiter" select="'!#'" />

注意，在这种情况下，参数中的“选择”值是默认值，只有在没有显式参数传递给模板时才适用。

在模板中，如果文本包含分隔符，您将输入文本

<xsl:choose>
   <xsl:when test="contains($text, $delimiter)">

如果是这样，您将使用substring-before 输出字符串的第一部分，然后使用substring-after 递归调用命名模板

  <td><xsl:value-of select="substring-before($text, $delimiter)" /></td>
  <xsl:call-template name="split">
       <xsl:with-param name="text" select="substring-after($text, $delimiter)" />
       <xsl:with-param name="delimiter" select="$delimiter" />
  </xsl:call-template>

文本不包含分隔符时，直接输出即可。

例如，给定以下 XML

<Invoice>
  <AllowanceChargeReason>ISK:y!#x!#w!#q!#t!#</AllowanceChargeReason>
</Invoice>

还有下面的 XSLT

<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="1.0">
    <xsl:output method="html" indent="yes"/>
    <xsl:template match="AllowanceChargeReason">
        <table>
            <tr>
                <xsl:call-template name="split">
                    <xsl:with-param name="text" select="substring-after(., ':')" />
                </xsl:call-template>
            </tr>
        </table>
    </xsl:template>

    <xsl:template name="split">
        <xsl:param name="text" select="." />
        <xsl:param name="delimiter" select="'!#'" />

        <xsl:if test="$text != ''">
            <xsl:choose>
                <xsl:when test="contains($text, $delimiter)">
                    <td><xsl:value-of select="substring-before($text, $delimiter)" /></td>
                    <xsl:call-template name="split">
                        <xsl:with-param name="text" select="substring-after($text, $delimiter)" />
                        <xsl:with-param name="delimiter" select="$delimiter" />
                    </xsl:call-template>
                </xsl:when>
                <xsl:otherwise>
                    <td><xsl:value-of select="$text" /></td>
                </xsl:otherwise>
            </xsl:choose>
        </xsl:if>
    </xsl:template>
</xsl:stylesheet>

那么下面是输出

<table>
   <tr>
      <td>y</td>
      <td>x</td>
      <td>w</td>
      <td>q</td>
      <td>t</td>
   </tr>
</table>

请注意，当您将其应用于实际的 XML 示例时，您必须考虑命名空间。

【讨论】：