vb.net OleDbDataAdapter 不能与 Select From Where 一起使用

Question

如果我对此进行调试，我只会得到一个无效的列名错误（“对象名称”）。我正在使用 SQL 数据库。

Protected Sub ddlKunden_SelectedIndexChanged(ByVal sender As Object, ByVal e As System.EventArgs) Handles ddlKunden.SelectedIndexChanged
    Dim strSql As String
    Dim kontakt As String = ddlKunden.SelectedItem.Value
    Dim dtbP As DataTable
    Using connection As OleDbConnection = New OleDbConnection(strConnection)
        connection.ConnectionString = strConnection
        connection.Open()

        'Kontaktpersonen laden
        strSql = "SELECT * FROM Kontaktpersonen WHERE Nr =" & Chr(34) & kontakt & Chr(34)

        dtbP = New DataTable()
        Using dad As New OleDbDataAdapter(strSql, connection)
            dad.Fill(dtbP)
        End Using
        ddlKontaktperson.Items.Clear()
        ddlKontaktperson.DataSource = dtbP
        ddlKontaktperson.DataTextField = "AP_Nam"
        ddlKontaktperson.DataValueField = "ID"
        ddlKontaktperson.DataBind()
    End Using

    ddlKontaktperson.Visible = True

End Sub

错误出现在

dad.fill(dtbP)

它应该选择 Nr="SELECTED VALUE" 的所有行，然后您在下拉列表中选择它。然后所有这些行都应该保存在 Datatable 中，并在另一个下拉列表中使用。

当我在没有 where 的情况下尝试完全相同的事情时，它会起作用。
示例：

'Kunden laden
            strSql = "SELECT * FROM Kontakte"
            dtbK = New DataTable()
            Using dad As New OleDbDataAdapter(strSql, connection)
                dad.Fill(dtbK)
            End Using
            ddlKunden.Items.Clear()
            ddlKunden.DataSource = dtbK
            ddlKunden.DataTextField = "Nr"
            ddlKunden.DataValueField = "Nr"
            ddlKunden.DataBind()

Answer 1

请尝试以下代码 您不需要在参数周围使用“'” 只需将这些值作为参数添加到 oledbcommand 及其值和类型 否则，你的 sql 命令将容易受到 sql 注入的攻击

Dim strConnection As String = "Provider=sqloledb;Data Source=(local);" &
                              "Initial Catalog=kodyaz;" &
                              "User Id=sa;Password=sa"

Dim kontakt As Int32 = 1

Dim dtbP As DataTable

Using connection As OleDbConnection = New OleDbConnection(strConnection)
    connection.Open()

    Dim cmd As New OleDbCommand()
    cmd.Connection = connection
    cmd.CommandText = "SELECT * FROM Kontaktpersonen WHERE Nr = ?"
    cmd.Parameters.AddWithValue("Nr", kontakt)

    dtbP = New DataTable()
    Using dad As New OleDbDataAdapter(cmd)
        dad.Fill(dtbP)
    End Using

End Using