SpreadsheetFormatRows 格式颜色 ColdFusion答案

【问题标题】：SpreadsheetFormatRows format color ColdFusionSpreadsheetFormatRows 格式颜色 ColdFusion
【发布时间】：2016-06-09 13:40:00
【问题描述】：

我正在使用 ColdFusion 和 SpreadsheetNew、SpreadsheetAddRows、SpreadsheetFormatRows 等函数创建 Excel 文件。根据我阅读的位于here 的文档，它们是颜色和fgcolor 的属性。我有点困惑，这两者之间的区别是什么。一种是文本颜色，另一种是背景颜色吗？我一直在使用 fgcolor 来设置行的背景颜色。

// HEADER ROW FORMAT
formatHeaderRow = StructNew();
formatHeaderRow.fgcolor="royal_blue";

我的主要问题是，根据文档，我可以提供 org.apache.poi.hssf.util.HSSFColor 颜色类中的任何值作为我的颜色。但是，我真的需要提供 HEX 值或 RGB。我知道 Excel 可以处理它，因为您可以在 excel 的颜色选择器中输入任何一个。有没有办法为我的行颜色输入 HEX 或 RGB 值？

谢谢！

更新

<cfscript>
// create XLSX workbook with a few cells
// and grab underlying POI objects
cfSheet = Spreadsheetnew("Sheet1", true);
poiWorkbook = cfSheet.getWorkBook();
poiSheet = poiWorkbook.getSheet("Sheet1");


// Create reusuable style objects 
// NOTE: Excel limits the maximum number of styles allowed. So do not create a new
// style for every cell. Create distinct styles once, and apply to multiple cells/rows.
Color = createObject("java", "java.awt.Color");

// Style 1: Cell with background color (only)
backgroundOnlyStyle = poiWorkbook.createCellStyle();
backgroundOnlyStyle.setFillPattern( backgroundOnlyStyle.SOLID_FOREGROUND );
XSSFColor = createObject("java", "org.apache.poi.xssf.usermodel.XSSFColor");
backgroundOnlyStyle.setFillForegroundColor( XSSFColor.init(Color.decode("##055910")) );

// Apply styles to cell A1. Note: POI indexes are 0-based
SpreadSheetSetCellValue(cfSheet, "background color only", 1, 1);
poiSheet.getRow( 0 ).setRowStyle( backgroundOnlyStyle );


</cfscript>

<!--- stream it to the browser --->
<cfheader name="Content-Disposition" value="inline; filename=reportName.xlsx">
<cfcontent type="application/vnd.openxmlformats-officedocument.spreadsheetml.sheet" variable="#SpreadSheetReadBinary(cfSheet)#">

【问题讨论】：

任何特定版本的 ColdFusion。文档链接转到 CF 9
嗯...好问题。 My answer 假定为 CF11。 CF9 使用的是旧版本的 POI，所以我不确定是否存在相同的方法。
@JamesAMohler - 我正在使用 CF 10，我相信 Leigh 的回答会奏效。谢谢！

标签： coldfusion apache-poi coldfusion-10 cfspreadsheet

【解决方案1】：

我有点搞不懂这两者有什么区别。

可以理解。属性名称是根据POI（底层 java 库）中使用的约定建模的，从 IMO 开始有点令人困惑。由于 ColdFusion 仅实现 POI 功能的一个子集，因此名称被断章取义，使其更加混乱。为了回答您的问题，在 POI 中实际上有三个 (3) 相关的颜色属性：

字体颜色 - 即Font.setColor()

单元格文本的颜色。在 CF 中，这是由 dataFormat.color 属性控制的。
单元格图案前景色 - 即CellStyle.setFillForegroundColor

尽管有这个名字，但这是大多数人认为的单元格背景颜色（下图中的黄色）。在 CF 中，这由 dataFormat.fgColor 属性控制。
单元格图案背景颜色 - CellStyle.setFillBackgroundColor

（可选）多色单元格图案中使用的辅助颜色（下图中的红色）。没有等价的 ColdFusion。

是否有任何方法可以为我的行颜色输入 HEX 或 RGB 值？

最后我检查了核心 CF 功能不支持它。但是，您可以利用does support it 的底层 POI 库。假设您使用的是较新的 .XLSX 格式，可以通过创建 CellStyle 并应用所需的 XSSFColor 来完成。

这是一个如何通过 POI 设置字体和/或单元格背景颜色的示例（使用 CF11 测试）。虽然在实际代码中，我还是建议将基本逻辑封装在一个可重用的函数中。

示例：

// create XLSX workbook with a few cells
// and grab underlying POI objects
cfSheet = Spreadsheetnew("Sheet1", true);
poiWorkbook = cfSheet.getWorkBook();
poiSheet = poiWorkbook.getSheet("Sheet1");


// Create reusuable style objects 
// NOTE: Excel limits the maximum number of styles allowed. So do not create a new
// style for every cell. Create distinct styles once, and apply to multiple cells/rows.
Color = createObject("java", "java.awt.Color");

// Style 1: Cell with background color (only)
backgroundOnlyStyle = poiWorkbook.createCellStyle();
backgroundOnlyStyle.setFillPattern( backgroundOnlyStyle.SOLID_FOREGROUND );
XSSFColor = createObject("java", "org.apache.poi.xssf.usermodel.XSSFColor");
backgroundOnlyStyle.setFillForegroundColor( XSSFColor.init(Color.decode("##055910")) );

// Style 2: Cell with font color (only)
textOnlyStyle = poiWorkbook.createCellStyle();
textFont = poiWorkbook.createFont();
XSSFColor = createObject("java", "org.apache.poi.xssf.usermodel.XSSFColor");
textFont.setColor( XSSFColor.init(Color.decode("##bd13be")) );
textOnlyStyle.setFont( textFont );

// Style 3: Cell with both backgound and Text color
backgroundAndTextStyle = poiWorkbook.createCellStyle();
textFont = poiWorkbook.createFont();
XSSFColor = createObject("java", "org.apache.poi.xssf.usermodel.XSSFColor");
textFont.setColor( XSSFColor.init(Color.decode("##a20932")) );
backgroundAndTextStyle.setFont( textFont );
XSSFColor = createObject("java", "org.apache.poi.xssf.usermodel.XSSFColor");
backgroundAndTextStyle.setFillPattern( backgroundAndTextStyle.SOLID_FOREGROUND );
backgroundAndTextStyle.setFillForegroundColor( XSSFColor.init(Color.decode("##192fda")) );

// Apply styles to cell A1. Note: POI indexes are 0-based
SpreadSheetSetCellValue(cfSheet, "background color only", 1, 1);
poiSheet.getRow( 0 ).getCell( 0 ).setCellStyle( backgroundOnlyStyle );

// Apply styles to cell A2
SpreadSheetSetCellValue(cfSheet, "text color only", 2, 1);
poiSheet.getRow( 1 ).getCell( 0 ).setCellStyle( textOnlyStyle );

// Apply styles to cell A3
SpreadSheetSetCellValue(cfSheet, "background AND text color", 3, 1);
poiSheet.getRow( 2 ).getCell( 0 ).setCellStyle( backgroundAndTextStyle );

// Save to file
SpreadSheetWrite(cfSheet, "c:/path/to/yourFile.xlsx", true);

【讨论】：

我将如何使用您的示例来格式化整行？
poiSheet.getRow( 2 ).setRowStyle( backgroundAndTextStyle );
如果我在上面使用您的代码并将第一个 .setCellStyle(textOnlyStyle) 替换为 .setRowStyle(textOnlyStyle) ，则会引发找不到 .setRowStyle 方法的错误。当我执行 writeDump(poiSheet.getRow(0)); 时我没有看到它要么
出于某种原因，我似乎无法保存我的 trycf.com 帖子，所以我将上面的代码添加到了这篇文章中。如果您将其粘贴到 trycf.com 并在 ColdFusion 10 下运行，您将看到错误 - 方法不存在。不过在较新的版本中工作正常。
我只是要在每个单元格上调用 setCellStyle，我看不到任何其他方法可以让它工作。

【解决方案2】：

周末，我们的组织从 ACF11 升级到 ACF2018，我发现给出的已接受答案不再有效，因为代码已被弃用并且不再起作用。 ACF2018 使用来自 ACF11 的 Apache POI Utility 的更新版本。显然 SOLID_FOREGROUND 属性已从 CellStyleobject 中删除并移至 FillPatternType 对象。我只是想对@Leigh 在 2016 年给出的已接受答案进行更新。顺便说一句，非常感谢 @Leigh 提供了一个很好的代码示例，它已经工作了好几年。希望这个答案能在更新到新版本的 ACF 时使某人免于将来的悲痛。

根据 3.17 版的文档，该字段已被删除。

Use FillPatternType.SOLID_FOREGROUND instead.

From source code of apache-poi 3.15 I can see:

/**
 * Fill Pattern: Solidly filled
 * @deprecated 3.15 beta 3. Use {@link FillPatternType#SOLID_FOREGROUND} instead.
 */
@Removal(version="3.17")
static final short SOLID_FOREGROUND = 1; //FillPatternType.SOLID_FOREGROUND;

我修改了上面@Leigh 的代码并添加了以下行

FillPatternType = createObject("java", "org.apache.poi.ss.usermodel.FillPatternType");

然后我修改了以下两行

backgroundOnlyStyle.setFillPattern( backgroundOnlyStyle.SOLID_FOREGROUND );
...
backgroundAndTextStyle.setFillPattern( backgroundAndTextStyle.SOLID_FOREGROUND );

并将它们更改为

backgroundOnlyStyle.setFillPattern( FillPatternType.SOLID_FOREGROUND );
...
backgroundAndTextStyle.setFillPattern( FillPatternType.SOLID_FOREGROUND );

我创建了一个工作示例和@Leigh 代码的要点，并验证它适用于从 ACF10 到 ACF2018 的所有 ACF 版本。 https://trycf.com/gist/cb4edf103a75b60e0d62259b0f9941ff/acf2018?theme=monokai

<cfscript>
// create XLSX workbook with a few cells
// and grab underlying POI objects
cfSheet = Spreadsheetnew("Sheet1", true);
poiWorkbook = cfSheet.getWorkBook();
poiSheet = poiWorkbook.getSheet("Sheet1");


// Create reusuable style objects 
// NOTE: Excel limits the maximum number of styles allowed. So do not create a new
// style for every cell. Create distinct styles once, and apply to multiple cells/rows.
Color = createObject("java", "java.awt.Color");
FillPatternType = createObject("java", "org.apache.poi.ss.usermodel.FillPatternType");

// Style 1: Cell with background color (only)
backgroundOnlyStyle = poiWorkbook.createCellStyle();
backgroundOnlyStyle.setFillPattern( FillPatternType.SOLID_FOREGROUND );
XSSFColor = createObject("java", "org.apache.poi.xssf.usermodel.XSSFColor");
backgroundOnlyStyle.setFillForegroundColor( XSSFColor.init(Color.decode("##055910")) );

// Style 2: Cell with font color (only)
textOnlyStyle = poiWorkbook.createCellStyle();
textFont = poiWorkbook.createFont();
XSSFColor = createObject("java", "org.apache.poi.xssf.usermodel.XSSFColor");
textFont.setColor( XSSFColor.init(Color.decode("##bd13be")) );
textOnlyStyle.setFont( textFont );

// Style 3: Cell with both backgound and Text color
backgroundAndTextStyle = poiWorkbook.createCellStyle();
textFont = poiWorkbook.createFont();
XSSFColor = createObject("java", "org.apache.poi.xssf.usermodel.XSSFColor");
textFont.setColor( XSSFColor.init(Color.decode("##a20932")) );
backgroundAndTextStyle.setFont( textFont );
XSSFColor = createObject("java", "org.apache.poi.xssf.usermodel.XSSFColor");
backgroundAndTextStyle.setFillPattern( FillPatternType.SOLID_FOREGROUND );
backgroundAndTextStyle.setFillForegroundColor( XSSFColor.init(Color.decode("##192fda")) );

// Apply styles to cell A1. Note: POI indexes are 0-based
SpreadSheetSetCellValue(cfSheet, "background color only", 1, 1);
poiSheet.getRow( 0 ).getCell( 0 ).setCellStyle( backgroundOnlyStyle );

// Apply styles to cell A2
SpreadSheetSetCellValue(cfSheet, "text color only", 2, 1);
poiSheet.getRow( 1 ).getCell( 0 ).setCellStyle( textOnlyStyle );

// Apply styles to cell A3
SpreadSheetSetCellValue(cfSheet, "background AND text color", 3, 1);
poiSheet.getRow( 2 ).getCell( 0 ).setCellStyle( backgroundAndTextStyle );

</cfscript>

<!--- Now that spreadsheet is prepared, initiate download --->  
<cfheader name="Content-Disposition" value="attachment;filename=yourfile.xlsx">
<cfcontent variable="#spreadsheetReadBinary(cfSheet)#" type="application/vnd.ms-excel">

【讨论】：