每月列中值的唯一计数答案

【问题标题】：Unique count of values in column per month每月列中值的唯一计数
【发布时间】：2021-04-15 11:05:47
【问题描述】：

Excel 表格：

     |       A        |         B       |       C          |    D   |   E     |     F   |     G   |
-----|----------------|-----------------|------------------|--------|---------|---------|---------|-----
1    |   month&year   |      date       |     customer     |        | 2020-01 | 2020-03 | 2020-04 |
-----|----------------|-----------------|------------------|--------|---------|---------|---------|-----
2    |     2020-01    |    2020-01-10   |    Customer A    |        |    3    |    2    |    4    |
3    |     2020-01    |    2020-01-14   |    Customer A    |        |         |         |         |
4    |     2020-01    |    2020-01-17   |    Customer B    |        |         |         |         | 
5    |     2020-01    |    2020-01-19   |    Customer B    |        |         |         |         | 
6    |     2020-01    |    2020-01-23   |    Customer C    |        |         |         |         | 
7    |     2020-01    |    2020-01-23   |    Customer B    |        |         |         |         | 
-----|----------------|-----------------|---------------- -|--------|---------|---------|---------|-----
8    |     2020-03    |    2020-03-18   |    Customer E    |        |         |         |         | 
9    |     2020-03    |    2020-03-19   |    Customer A    |        |         |         |         | 
-----|----------------|-----------------|------------------|--------|---------|---------|---------|-----
10   |     2020-04    |    2020-04-04   |    Customer B    |        |         |         |         | 
11   |     2020-04    |    2020-04-07   |    Customer C    |        |         |         |         | 
12   |     2020-04    |    2020-04-07   |    Customer A    |        |         |         |         | 
13   |     2020-04    |    2020-04-07   |    Customer E    |        |         |         |         | 
14   |     2020-04    |    2020-04-08   |    Customer A    |        |         |         |         | 
15   |     2020-04    |    2020-04-12   |    Customer A    |        |         |         |         | 
16   |     2020-04    |    2020-04-15   |    Customer B    |        |         |         |         | 
17   |                |

在我的 Excel 文件中，我想计算 每月唯一的客户数量，正如您在 Cell E2:G2 中看到的那样。

我已经插入了Column A 作为辅助列，它只从Column B 的日期中提取月份和年份。
因此，日期格式与Cell E1:G2 中的时间线相同。

我猜想获得每月唯一计数的公式与=COUNTIFS($A:$A,E$1) 有某种关系，但我不知道如何修改此公式以获得预期值。

你有什么想法吗？

【问题讨论】：

您可以创建一个数据透视表，在其中将“月和年”作为行标签并使用“客户”作为值。初始化数据透视表时，选择将数据添加到数据模型中。然后，您可以设置值以显示唯一计数。
你有什么版本的 Excel？
Office365。但是，如果您也有 Excel 2016 的解决方案，那就太好了。

标签： excel

【解决方案1】：

这是适用于 Office 365 的一种方法，如果您有权访问 UNIQUE：

=COUNTA(UNIQUE(IF($A$2:$A$16=G$1,$C$2:$C$16,""),,FALSE))-1

对于旧版本，以下将与 CTRL+SHIFT+ENTER（数组条目）一起使用

=SUM(--(FREQUENCY(IFERROR(MATCH($A$2:$A$16&$C$2:$C$16,E$1&$C$2:$C$16,0),"a"),MATCH($A$2:$A$16&$C$2:$C$16,E$1&$C$2:$C$16,0))>0))

【讨论】：

【解决方案2】：

你可以在没有任何帮助的情况下做到这一点。

=SUM(--(UNIQUE(FILTER($C$2:$C$16,TEXT($B$2:$B$16,"yyyy-mm")=E$1))<>""))

对于旧版本的 excel，请在您的帮助列中使用以下公式。

=SUMPRODUCT(--($A$2:$A$16=D$1)*(1/COUNTIFS($A$2:$A$16,$A$2:$A$16,$C$2:$C$16,$C$2:$C$16)))

【讨论】：

我不知道为什么，但在我这边只有当我使用辅助列和这个公式时才有效：=SUM(--(UNIQUE(FILTER($C$2:$C$16; $A$2:$A$16=E$1))""))。可能是因为我使用的是德语 Excel 版本。对于没有 UNIQUE 函数的旧版 Excel，您是否也有解决方案？
对于旧版本的 excel，您需要使用帮助列，如您的问题所示。然后使用这个公式=SUMPRODUCT(--($A$2:$A$16=D$1)*(1/COUNTIFS($A$2:$A$16,$A$2:$A$16,$C$2:$C$16,$C$2:$C$16)))