WinExec() 的可接受替代品？

Question

我想运行用户在 INI 文件中定义的命令。

命令可以是EXE文件，也可以是其他文件（如DOC文件）和参数。

由于 WinExec() 可以处理参数（例如“cmd /?”），但 ShellExec() 可以处理非 EXE 文件（例如“Letter.doc”），因此我将两者结合使用。

我担心未来的 Windows 版本，因为 WinExec() 已被弃用，甚至从 16 位时代开始。

这是我目前的功能：

procedure RunCMD(cmdLine: string; WindowMode: integer);

  procedure ShowWindowsErrorMessage(r: integer);
  begin
    MessageDlg(SysErrorMessage(r), mtError, [mbOK], 0);
  end;

var
  r, g: Cardinal;
begin
  // We need a function which does following:
  // 1. Replace the Environment strings, e.g. %SystemRoot%  --> ExpandEnvStr
  // 2. Runs EXE files with parameters (e.g. "cmd.exe /?")  --> WinExec
  // 3. Runs EXE files without path (e.g. "calc.exe")       --> WinExec
  // 4. Runs EXE files without extension (e.g. "calc")      --> WinExec
  // 5. Runs non-EXE files (e.g. "Letter.doc")              --> ShellExecute
  // 6. Commands with white spaces (e.g. "C:\Program Files\xyz.exe") must be enclosed in quotes. 

  cmdLine := ExpandEnvStr(cmdLine);

  // TODO: Attention: WinExec() is deprecated, but there is no acceptable replacement
  g := WinExec(PChar(cmdLine), WindowMode);
  r := GetLastError;
  if g = ERROR_BAD_FORMAT then
  begin
    // e.g. if the user tries to open a non-EXE file
    ShellExecute(0, nil, PChar(cmdLine), '', '', WindowMode);
    r := GetLastError;
  end;
  if r <> 0 then ShowWindowsErrorMessage(r);
end;

function ExpandEnvStr(const szInput: string): string;
// http://stackoverflow.com/a/2833147/3544341
const
  MAXSIZE = 32768;
begin
  SetLength(Result, MAXSIZE);
  SetLength(Result, ExpandEnvironmentStrings(pchar(szInput),
    @Result[1],length(Result)));
end;

Microsoft 建议使用 CreateProcess()，但我不接受它作为 WinExec() 的真正替代品。

例如，给定以下命令行：

"C:\Program Files\xyz.exe" /a /b /c

由于 ShellExecute() 和 CreateProcess() 需要严格分离命令和参数，我必须自己解析这个字符串。这真的是我唯一可以走的路吗？是否有人编写了具有此功能的公开可用代码？

附加说明：进程不应附加到调用者。我的程序将在命令启动后立即关闭。

Answer 1

CreateProcess() 是 WinExec() 的替代品。文档明确说明了这一点。

顺便说一句，您原始代码中的错误处理是完全错误的。你在滥用GetLastError()。事实上，WinExec() 和 ShellExecute() 都没有报告 GetLastError() 开始的错误。因此，即使 WinExec() 或 ShellExecute() 成功（并且您甚至没有检查 ShellExecute() 是成功还是失败），您也可能会报告早期 API 调用的随机错误。

试试这样的：

procedure RunCMD(cmdLine: string; WindowMode: integer);

  procedure ShowWindowsErrorMessage(r: integer);
  var
    sMsg: string;
  begin
    sMsg := SysErrorMessage(r);
    if (sMsg = '') and (r = ERROR_BAD_EXE_FORMAT) then
      sMsg := SysErrorMessage(ERROR_BAD_FORMAT);
    MessageDlg(sMsg, mtError, [mbOK], 0);
  end;

var
  si: TStartupInfo;
  pi: TProcessInformation;
  sei: TShellExecuteInfo;
  err: Integer;
begin
  // We need a function which does following:
  // 1. Replace the Environment strings, e.g. %SystemRoot%  --> ExpandEnvStr
  // 2. Runs EXE files with parameters (e.g. "cmd.exe /?")  --> WinExec
  // 3. Runs EXE files without path (e.g. "calc.exe")       --> WinExec
  // 4. Runs EXE files without extension (e.g. "calc")      --> WinExec
  // 5. Runs non-EXE files (e.g. "Letter.doc")              --> ShellExecute
  // 6. Commands with white spaces (e.g. "C:\Program Files\xyz.exe") must be enclosed in quotes. 

  cmdLine := ExpandEnvStr(cmdLine);
  {$IFDEF UNICODE}
  UniqueString(cmdLine);
  {$ENDIF}

  ZeroMemory(@si, sizeof(si));
  si.cb := sizeof(si);
  si.dwFlags := STARTF_USESHOWWINDOW;
  si.wShowWindow := WindowMode;

  if CreateProcess(nil, PChar(cmdLine), nil, nil, False, 0, nil, nil, si, pi) then
  begin
    CloseHandle(pi.hThread);
    CloseHandle(pi.hProcess);
    Exit;
  end;

  err := GetLastError;
  if (err = ERROR_BAD_EXE_FORMAT) or
     (err = ERROR_BAD_FORMAT) then
  begin
    ZeroMemory(@sei, sizeof(sei));
    sei.cbSize := sizeof(sei);
    sei.lpFile := PChar(cmdLine);
    sei.nShow := WindowMode;

    if ShellExecuteEx(@sei) then Exit;
    err := GetLastError;
  end;

  ShowWindowsErrorMessage(err);
end;

Answer 2

虽然相似的ShellExecute 和CreateProcess 有不同的用途。

ShellExecute 可以打开非可执行文件。它在注册表中查找给定文件的关联程序的信息并将执行它。 ShellExecute 也非常适合启动默认 Web 浏览器，您可以将 URL 传递给它。

因此，如果您要将 TXT 文件传递​​给 ShellExecute，它将打开相关的程序，例如记事本。但是它会因 CreateProcess 失败。

CreateProcess 是一个较低级别的函数，它允许您更好地控制进程的输入和输出。例如，您可以使用 CreateProcess 调用具有文本输出的命令行程序并捕获该输出并做出相应的反应。

考虑到您的顾虑，您将需要使用 ShellExecute。但是，您需要将命令与参数分开。这将是第一个非转义的空白字符。

我个人很少直接调用 ShellExecute 或 CreateProcess。我倾向于使用包装这些函数的JCL 中的以下函数。

JclMiscel.pas

• CreateDosProcessRedirected
• WinExec32
• WinExec32AndWait
• WinExecAndRedirectOutput
• CreateProcessAsUser
• CreateProcessAsUserEx

JclShell.pas

• ShellExecEx
• ShellExec
• ShellExecAndWwait
• RunAsAdmin

JclSysUtils.pas

• 执行（8 个重载版本，是我使用最多的版本）