在delphi中使用C dll什么都不返回

Question

我一直在尝试基于documentation 在 delphi 中重用 C dll 文件。

服务器运行良好，我可以访问和使用本地服务器上的数据库 java和php。

在 delphi 上，我使用了动态加载，并且在所有返回变量的函数上运行良好，但在返回接口的函数上失败了。

unit for library :
unit SQLDBC_C;

interface
uses windows, classes, sysutils;

type
  SQLDBC_IRuntime = interface
  end;

var
  getSDKVersion : function :Pchar; stdcall;
  ClientRuntime_GetClientRuntime: function (errorText:Pchar; errorTextSize:Integer) : SQLDBC_IRuntime; stdcall;

implementation

var
  libhandle : THandle;

procedure initLibrary;
begin
  libhandle := LoadLibrary('libSQLDBC_C.dll');
  if libhandle>=23 then begin
     @getSDKVersion:=GetProcAddress(libhandle,'getSDKVersion');
     @ClientRuntime_GetClientRuntime:=
        GetProcAddress(libhandle,'ClientRuntime_GetClientRuntime');
  end;
end;

initialization
begin
  initLibrary;
end;

finalization
begin
  if libhandle>=32 then
    FreeLibrary(libhandle);
end;

end.

这是测试程序：

procedure TForm1.Button1Click(Sender: TObject);
var
  err : array [0..200] of char;
  rt : SQLDBC_IRuntime;

begin
  Memo1.Clear;
  FillChar(err, sizeof(err), 0);
  Memo1.Lines.Add(getSDKVersion); //this function successed

  rt := ClientRuntime_GetClientRuntime(@err,200); 
  //this function had no return value, (rt always nil) but no error return at err variable
  if assigned(rt) then begin
    ......
  end;
end;

我已经阅读了geskill、Dan Hacker、max 和Ron 提出的类似问题，但它无法解决我的问题。

谁能告诉我这里出了什么问题？

Answer 1

我无法测试它，因为我没有libSQLDBC_C.dll。

问题是 already explained 。作为您的情况的解决方法，您可以在 Delphi ClientRuntime_GetClientRuntime 声明中返回一个指针

ClientRuntime_GetClientRuntime: function (errorText:Pchar;
                                errorTextSize:Integer): Pointer; stdcall;

并将其转换为SQLDBC_IRuntime 接口：

var
  err : array [0..200] of char;
  rt : SQLDBC_IRuntime;

begin
  Pointer(rt):= ClientRuntime_GetClientRuntime(@err,200); 

Answer 2

返回接口的 C++ 函数不容易映射到 Delphi 函数。 Delphi 中托管类型的返回值的调用约定与 C++ 使用的不匹配。

为了说明，我创建了一个简单的 C++ 测试 DLL 来导出这个函数：

extern "C" __declspec(dllexport) IUnknown* __stdcall GetInterface()
{
    CoInitialize(NULL);
    IUnknown* result;
    CoCreateInstance(CLSID_ActiveDesktop, NULL, CLSCTX_INPROC_SERVER, 
      IID_IUnknown, (void**) &result);
    return result;
}

将其映射到 Delphi 的明显方法如下：

function GetInterface: IUnknown; stdcall; external DLL name '_GetInterface@0';

然而，当我们调用这个函数时，它总是返回nil。

解决方法完全按照 Serg 的建议：

function GetInterface: Pointer; stdcall; external DLL name '_GetInterface@0';

然后我们可以这样称呼它：

var
  intf: IUnknown;
....
Pointer(intf) := GetInterface;

当我们这样做时，intf 不是nil，我们可以很高兴地调用它的方法。

所以，我们在这里了解到的是，Delphi 不能轻易调用返回接口的外部函数，除非这些外部函数也在 Delphi 中实现。但至少我们有一个可行的解决方法。

---

不幸的是，这种解决方法对您没有立即用处。那是因为SQLDBC_IRuntime 是一个 C++ 类。它不是 COM 兼容接口。注意SQLDBC_IRuntime 没有实现IInterface。所以它不提供_AddRef、_Release 和QueryInterface。 Delphi 的接口支持基于IInterface 的可用性。这意味着你不能使用 Delphi 的SQLDBC_IRuntime。

您需要创建一个 C++ 桥接 DLL，以 Delphi 可以调用的方式公开功能。例如，通过公开调用 SQLDBC_IRuntime 的 C++ 方法的普通旧函数。