delphi中的类属性线程安全吗？

Question

我想使用我自己的具有一些属性的类。我可以使用read 和write 来自定义写入或读取私有变量的方式和（例如）哪个（例如）私有变量。

一个示例是此类中的整数 (MyInteger)：

type
  TMyClass = class
  private
    MyInteger : Integer;
    function SomeFunction : Integer;
  public
    property TheInteger : Integer read SomeFunction write MyInteger;
end;

如果（例如）类会不断访问（读取）MyInteger，而另一个线程从当前实例的另一个线程访问（写入）TheInteger（写入）是否安全？

希望你们明白我的意思...基本上我不知道如果多个线程同时访问内存中的 var 是否安全...（没有关键部分）

编辑：

这个类也会有区别吗：

type
  TMyClass = class
  private
    MyInteger : Integer;
    function SomeFunction : Integer;
  public
    property TheInteger : Integer read MyInteger write MyInteger;
end;

还有这个：

type
  TMyClass = class
  private
    function SomeFunction : Integer;
  public
    MyInteger : Integer;
end;

?

Answer 1

变量所在的位置并不意味着任何类型的线程安全。这是两个完全不同的概念。

使变量线程安全与否的关键在于您管理对它的访问的方式。

例如，这将是线程安全的，因为操作 FMyInt 的唯一方法是通过三种方法之一，它们都以线程安全的方式实现：

type
  TMyClass = class
  strict private
    FMyInt : Integer;
  public
    procedure IncrementValue;
    function QueryValue : Integer;
    function SubtractValue( aWhat : Integer) : Integer;
  end;

procedure TMyClass.IncrementValue;
begin
  InterlockedIncrement( FMyInt);
end;

function TMyClass.QueryValue : Integer;
begin
  result := InterlockedExchangeAdd( FMyInt, 0);
end;

function TMyClass.SubtractValue( aWhat : Integer) : Integer;
begin
  result := InterlockedExchangeAdd( FMyInt, -aWhat);
end;

这也是如此，但效率较低。 Interlocked 并不适合所有情况，所以它真的取决于用例应该使用什么方法。

type
  TMyClass = class
  strict private
    FMyInt : Integer;
    FLock : TCriticalSection;
  public
    constructor Create;
    destructor Destroy;  override;
    procedure IncrementValue;
    function QueryValue : Integer;
    function SubtractValue( aWhat : Integer) : Integer;
  end;

constructor TMyClass.Create;
begin
  inherited;
  FLock := TCriticalSection.Create;
end;

destructor TMyClass.Destroy;
begin
  FreeAndNil( FLock);
  inherited;
end;

procedure TMyClass.IncrementValue;
begin
  FLock.Enter;
  try
     Inc(FMyInt);
  finally
    FLock.Leave;
  end;
end;

function TMyClass.QueryValue : Integer;
begin
  FLock.Enter;
  try
    result := FMyInt;
  finally
    FLock.Leave;
  end;
end;

function TMyClass.SubtractValue( aWhat : Integer) : Integer;
begin
  FLock.Enter;
  try
    Dec( FMyInt, aWhat);
    result := FMyInt;
  finally
    FLock.Leave;
  end;
end;

请注意，如果我将值放入 record 并有一堆函数和过程进行操作，则同样有效。变量的存储位置无关紧要。

注意事项

切勿混用不同种类的锁。例如，将 Interlocked-Functions 与 TCriticalSection 混合，或将 TCriticalSection 与 TMutex 混合，或将任何类型的锁与完全无人看守的访问混合。这样做会导致失败，因为不同类型的锁彼此不认识。

请记住，大多数锁机制只是逻辑锁，它并不能真正阻止您对数据做一些疯狂的事情。因此，尽可能地封装对数据的访问以保持控制是一种很好的方法。

Answer 2

你问在线程安全方面是否有任何区别：

type
  TMyClass = class
  private
    MyInteger : Integer;
  public
    property TheInteger : Integer read MyInteger write MyInteger;
end;

和：

type
  TMyClass = class
  public
    MyInteger : Integer;
end;

完全没有区别。编译器为两种变体生成相同的代码。编译器根本不插入同步代码。

事实上，编译器在任何情况下都不会插入线程同步代码。某些库函数具有线程同步，例如TInterfacedObject._AddRef 等，但编译器本身从不编写同步代码。处理线程安全的责任始终落在程序员身上。

---

举个更具体的例子，让我们看看你问题中的具体代码。

您的共享变量是一个整数。只要整数是对齐的，即它存储在 4 字节边界上，就永远不会发生撕裂。读取访问永远不会观察到部分写入。

您的场景是单个写入线程和多个读取线程。您没有指定额外的排序约束。有了这些事实和约束，就不需要任何锁定。任何数据竞争都必须是良性的，无锁代码在语义上与使用锁或互锁访问的代码没有区别。

什么时候需要同步访问？

• 如果有多个写线程，需要同步访问。
• 如果您的变量未对齐，或者比指针宽，那么您需要同步。