Ltac 调用“cofix”失败。错误：所有方法都必须在互归纳类型中构造元素

Question

Require Import Streams.

CoFixpoint map {X Y : Type} (f : X -> Y) (s : Stream X) : Stream Y :=
  Cons (f (hd s)) (map f (tl s)).

CoFixpoint interleave {X : Type} (s : Stream X * Stream X) : Stream X := Cons (hd (fst s)) (Cons (hd (snd s)) (interleave (tl (fst s), tl (snd s)))).

Lemma map_interleave : forall {X Y : Type} (f : X -> Y) (s1 s2 : Stream X), map f (interleave (s1, s2)) = interleave (map f s1, map f s2).
Proof.
  Fail cofix. (* error *)
Abort.

输出：

Ltac call to "cofix" failed.
Error: All methods must construct elements in coinductive types.

我不确定这意味着什么 - map 和 interleave 都是直接构建共归纳类型值的核心递归函数。有什么问题？

Answer 1

问题源于= 表示法代表eq，它是一种归纳类型，不是一种互感类型。

相反，您可以证明流 map f (interleave (s1, s2)) 和 interleave (map f s1, map f s2) 在扩展上相等。这是 Coq 参考手册的摘录 (§1.3.3)

为了证明两个流s1 和s2 的外延相等，我们必须构造一个无限的相等证明，即EqSt s1 s2 类型的无限对象。

将eq 更改为EqSt 后，我们可以证明引理：

Lemma map_interleave : forall {X Y : Type} (f : X -> Y) (s1 s2 : Stream X),
  EqSt (map f (interleave (s1, s2))) (interleave (map f s1, map f s2)).
Proof.
  cofix.
  intros X Y f s1 s2.
  do 2 (apply eqst; [reflexivity |]).
  case s1 as [h1 s1], s2 as [h2 s2].
  change (tl (tl (map f (interleave (Cons h1 s1, Cons h2 s2))))) with
         (map f (interleave (s1, s2))).
  change (tl (tl (interleave (map f (Cons h1 s1), map f (Cons h2 s2))))) with
         (interleave (map f s1, map f s2)).
  apply map_interleave.
Qed.

顺便说一句，在this CPDT 章节中可以找到许多处理协推数据类型的技巧。