如何使用 elixir/phoenix 从 csv 文件导入用户？

Question

我有一个 csv 文件，其中包含用户列表和 UserController 中的以下导入方法，我想通过提交带有表单的 csv 文件来导入这些用户。看起来我做错了。

users_controller

  def import(conn, %{"user" => user_params}) do
    user_params["file"]
    |> File.stream!()
    |> CSV.decode
    |> Enum.each(fn(user) -> User.changeset(%User{}, %{name: Enum.at(user, 0), email: Enum.at(user, 1)}) |> Repo.insert end)
    conn
    |> put_flash(:info, "Imported")
    |> redirect(to: user_path(conn, :index))
  end

路线

post "/import", UsersController, :import, as: :import_csv

表格

<%= render "import_form.html", changeset: @changeset,
                        action: import_csv_path(@conn, :import) %>

-

<%= form_for @changeset, @action, [multipart: true], fn f -> %>
  <div class="form-group">
    <%= label f, :file, class: "control-label" %>
    <%= file_input f, :file %>
  </div>

  <div class="form-group">
    <%= submit "Submit", class: "btn btn-primary" %>
  </div>
<% end %>

型号

  schema "users" do
    field :name, :string
    field :email, :string
    field :file, :any, virtual: true
    timestamps()
  end

  def changeset(struct, params \\ %{}) do
    struct
    |> cast(params, [:name, :email, :file])
    |> validate_required([:name, :email])
    |> unique_constraint(:email)
  end

---

以下代码适用于 iex

  def import(file) do
    file
    |> File.stream!()
    |> CSV.decode
    |> Enum.each(fn(user) -> User.changeset(%User{}, %{name: Enum.at(user, 0), email: Enum.at(user, 1)}) |> Repo.insert end)
  end

Answer 1

您的参数中没有返回文件。这是我为多部分文件返回的参数

[warn] module=UcxChat.AttachmentController line=10 function=create/2  attachment params: %{"channel_id" => "300233dd-782f-4718-9eed-00b8cc412a79", "description" => "", "file" => %Plug.Upload{content_type: "text/plain", filename: "test.txt", path: "/var/folders/wt/3q11kty15rqfb5v9rpqg0ssm0000gn/T//plug-1494/multipart-421483-239132-3"}, "file_name" => "test.txt", "type" => "text/plain", "user_id" => "427452eb-c9cf-457b-9c55-0904c9d24385"}

您可以看到params["file"] 是一个Plug.upload 结构。

要获取实际文件，您应该获取 :path 字段，例如：

  def import(conn, %{"user" => user_params}) do
    user_params["file"].path
    |> File.stream!()
    |> CSV.decode
    |> Enum.each(fn(user) -> User.changeset(%User{}, %{name: Enum.at(user, 0), email: Enum.at(user, 1)}) |> Repo.insert end)
    conn
    |> put_flash(:info, "Imported")
    |> redirect(to: user_path(conn, :index))
  end

您可能还想进行一些错误处理。比如：

def import(conn, %{"user" => user_params}) do
  user_params["file"].path
  |> File.stream!()
  |> CSV.decode
  |> Enum.map(fn(user) -> 
    User.changeset(%User{}, %{name: Enum.at(user, 0), email: Enum.at(user, 1)}) |> Repo.insert 
  end)
  |> Enum.filter(fn 
    {:error, cs} -> true
    _ -> false
  end)
  |> case do
    [] -> 
      conn
      |> put_flash(:info, "Imported")
      |> redirect(to: user_path(conn, :index))
    errors -> 
      errors = parse_errors(errors)  # create this fun 
      conn
      |> put_flash(:erorr, errors)
      |> render("import.html")
  end
end