榆树 0.19.1 中 4 位数字的当前年份

Question

如何使用 ELM 0.19.1 获取 4 位数字的当前年份？我读过一些东西，但 0.19.1 没有任何作用。

签名：

getCurrentYear : Int

执行：

getCurrentYear => 2020

编辑：

也许正在执行new Date().getFullYear() javascript 代码？

Answer 1

最简单的方法是在启动应用程序时通过flags 传递年份，因为当前年份不太可能在应用程序运行过程中发生变化。在这种情况下，您可以使用您建议的 JavaScript 的 sn-p (ellie example)：

    Elm.Main.init({ 
      node: document.querySelector('main'), 
      flags: {
        year: new Date().getFullYear(),
      } 
    });

module Main exposing (main)

import Browser
import Html exposing (Html, p, text)


type alias Flags =
    { year : Int }


main : Program Flags Model Msg
main =
    Browser.element
        { init = \flags -> ( Model flags.year, Cmd.none )
        , view = view
        , update = update
        , subscriptions = \_ -> Sub.none
        }


type alias Model =
    { year : Int }


type Msg
    = NoOp


update : Msg -> Model -> ( Model, Cmd Msg )
update msg model =
    case msg of
        NoOp ->
            ( model, Cmd.none )


view : Model -> Html Msg
view model =
    p [] [ text "The year is ", text (String.fromInt model.year) ]

或者，您可以使用Time.now 来请求当前时间，正如Robin Zigmond's answer 所建议的那样，但这指向Elm 0.18 文档（用于elm-lang/core 而不是elm/time）。对于 0.19，您需要 Time.Posix 和 Time.Zone 才能调用 Time.toYear。您可以链接 Time.now（Task 产生 Posix 值）和 Time.here（Task 产生带有当前时区偏移量的 Zone）以在一个 Cmd 中检索这些值。这是一个示例 (also on ellie)

module Main exposing (main)

import Browser
import Html exposing (Html, p, text)
import Task exposing (Task)
import Time


type alias Flags =
    { year : Int }


main : Program () Model Msg
main =
    Browser.element
        { init = \() -> ( Model 0, whatYearIsIt |> Task.perform GotYear )
        , view = view
        , update = update
        , subscriptions = \_ -> Sub.none
        }


whatYearIsIt : Task x Int
whatYearIsIt =
    Task.map2 Time.toYear Time.here Time.now


type alias Model =
    { year : Int }


type Msg
    = GotYear Int


update : Msg -> Model -> ( Model, Cmd Msg )
update msg model =
    case msg of
        GotYear year ->
            ( { model | year = year }, Cmd.none )


view : Model -> Html Msg
view model =
    p [] [ text "The year is ", text (String.fromInt model.year) ]

Answer 2

正如我在评论中已经说过的，不可能在 Elm 中定义一个返回当前年份的函数。您必须从 Elm 运行时系统（基本上是 JavaScript，但您不必自己编写）获取此类信息。这通过commands 发生，您可以在其中告诉运行时系统为您做一些事情。但请注意，您不能简单地检索该命令的“返回值”并将其返回到您的 Elm 代码中。相反，您必须将其传递给一个可以将其转换为“消息”的函数（请参阅基本 Elm 架构教程 here，在您可以使用 Elm 做任何事情之前理解这一点至关重要） - 这样您就可以存储值在您的模型中，从而将其显示在您的应用中。

这些模式确实需要一些时间来了解，特别是如果您不习惯纯函数式编程 - 但是一旦您习惯了它，好处是巨大的，包括几乎可以保证没有运行时错误，以及大大增强的能力推理你的代码。

为了获得具体的年份，您似乎需要this library，它为您（作为now）提供Task，而不是Cmd。您可以使用Task.perform 将其转换为命令，该命令已记录在here - 实际上它甚至提供了一个与您的用例非常匹配的示例 - 我将在此处复制它以供后代使用：

import Time  -- elm install elm/time
import Task

type Msg
  = Click
  | Search String
  | NewTime Time.Posix

getNewTime : Cmd Msg
getNewTime =
  Task.perform NewTime Time.now

您必须填写此内容以适合您自己的用例，尤其是您自己的 Msg 类型。但它给出了一个很好的基本轮廓。要获取用户的当前年份，您需要将Time.Posix 类型替换为Int，并将Time.now 命令替换为(Task.map2 Time.toYear Time.here Time.now)，正如@bdukes 在他的回答中所解释的那样。