如何在 LINK 字段中指定工作簿的相对路径？

Question

在将一系列单元格从 Excel 粘贴到 Word (2013) 后，该字段如下所示：

{ LINK Excel.Sheet.12 "D:\\RelativePath\\1\\work\\tmp.xlsx" Sheet1!NamedRange \a \p }

如果您将源 (.xlsx) 和接收器 (.docx) 移动到 2 文件夹，则需要更改 LINK 字段中的链接，使其看起来像这样：

{ LINK Excel.Sheet.12 "D:\\RelativePath\\2\\work\\tmp.xlsx" Sheet1!NamedRange \a \p }

这样的字段多时，不方便。

这两个我都试过了：

{ LINK Excel.Sheet.12 "...\\...\\work\\tmp.xlsx" Sheet1!NamedRange \a \p }

还有：

{ LINK Excel.Sheet.12 "~\\work\\tmp.xlsx" Sheet1!NamedRange \a \p } 但没有任何效果。

这也不行：

How to create absolute hyperlinks and relative hyperlinks in Word documents

是否可以在LINK字段中指定不是绝对的，而是相对的源地址？

更新 @Cindy Meister 提出了一个解决方案，经过一些改进后，代码运行良好。

他来了：

Sub updateLINKs()
Dim doc As Word.Document
Dim fld As Word.Field
Dim sFilePath As String, sFileName As String
Set doc = ActiveDocument
sFilePath = doc.Path
For Each fld In doc.Fields
    If fld.Type = wdFieldLink Then
      If fld.Result.InlineShapes.Count > 0 And _
         InStr(fld.OLEFormat.ClassType, "Excel") And _
         fld.LinkFormat.SourcePath <> sFilePath Then
           sFileName = fld.LinkFormat.SourceName
           fld.LinkFormat.SourceFullName = sFilePath & "\" & sFileName
      End If
    End If
Next
End Sub

Answer 1

不能在Link 字段中使用相对路径。需要在字段代码中更新/更改路径。这可以通过使用LinkFormat 属性提供的可能性以相当直接的方式完成。

例如，假设相对路径与 Word 文档的路径相同，则以下代码：

1. 从Document.Path 属性中获取路径
2. 循环文档中的所有字段并确定它们是否是来自显示InlineShape（对象，而不是文本）的 Excel 源的 LINK 字段。这些字段以相反的顺序循环，因为更改路径会导致 Word 在后台删除并重新创建 LINK。这意味着从文档开头开始的循环将重复“命中”同一字段，从而导致无限循环。
3. 使用LinkFormat.SourceName 从Link 字段中确定链接对象的当前文件名
4. 连接信息并将其分配给LinkFormat.SourceFullName 属性

注意LinkFormat.SourcePath 和LinkFormat.SourceName 属性是只读的，因此只能使用SourceFullName 更改路径。

Sub UpdateLinks()
    Dim doc As Word.Document
    Dim fld As Word.Field, nrFields As Long, i As Long
    Dim sFilePath As String, sFileName As String

    Set doc = ActiveDocument
    sFilePath = doc.path
    nrFields = doc.Fields.Count
    For i = nrFields To 1 Step -1
        Set fld = doc.Fields(i)
        If fld.Type = wdFieldLink Then
          If fld.result.InlineShapes.Count > 0 And _
             InStr(fld.OleFormat.ClassType, "Excel") Then
               sFileName = fld.LinkFormat.SourceName
               fld.LinkFormat.SourceFullName = sFilePath & "\" & sFileName
          End If
        End If
    Next
End Sub

Answer 2

您不能在 LINK 字段中指定相对路径。这需要在 LINK 字段中嵌入另一个字段，但正如我之前所说，您不能使用 LINK 字段来执行此操作。您发布的链接仅涉及超链接的超链接基础设置，这也不会产生真正的相对链接。

LINK 字段的唯一解决方法是使用更新绝对路径的宏。