通过 OLE 调用 Word CentimetersToPoints 时出现未指定的错误

Question

当在 Delphi (XE) 中执行时，以下代码在 CentimetersToPoint 调用上失败并出现 OLE 800040005“未指定”错误，类似的 VBS 或 VBA 版本通过

var w : OleVariant;

w := CreateOleObject('Word.Application');
w.Visible := true;
Writeln(w.CentimetersToPoints(2.0));

类型库提供的 FWIW

/ [id(0x00000173), helpcontext(0x09700173)]
// single CentimetersToPoints([in] single Centimeters);

默认情况下，Delphi 只将浮点值作为 Double 传递，所以我尝试直接调用 IDispatch.Invoke 并将参数作为 VT_R4 传递，但没有更好的结果。

编辑：有效的 VB 版本（保存到 .vbs）

set w = CreateObject("Word.Application")
w.Visible = true
msgbox w.CentimetersToPoints(2.0)

对于可能出现的问题还有其他建议吗？

Answer 1

我最初怀疑问题在于该函数需要Single 并且Delphi 将您的浮点数转换为其他内容。当我在调试器中跟踪它时，我发现传递给Invoke 的变体具有VType 的varCurrency 和2 的货币值。我不确定这是怎么发生的！

正如我在回答这个question 时发现的那样，将单精度浮点数转换为变体非常棘手。我最初怀疑您可以使用我在那里提供的解决方案来解决您的问题。

function VarFromSingle(const Value: Single): Variant;
begin
  VarClear(Result);
  TVarData(Result).VSingle := Value;
  TVarData(Result).VType := varSingle;
end;

....

w := CreateOleObject('Word.Application');
w.Visible := true;
Writeln(w.CentimetersToPoints(VarFromSingle(2.0)));

但这也失败了，以同样的方式，原因我还不明白。

和你一样，我尝试使用IDispatch.Invoke 调用该函数。这是我想出的：

program SO16279098;

{$APPTYPE CONSOLE}

uses
  SysUtils, Variants, Windows, ComObj, ActiveX;

function VarFromSingle(const Value: Single): Variant;
begin
  VarClear(Result);
  TVarData(Result).VSingle := Value;
  TVarData(Result).VType := varSingle;
end;

var
  WordApp: Variant;
  param: Variant;
  retval: HRESULT;
  disp: IDispatch;
  Params: TDispParams;
  result: Variant;

begin
  try
    CoInitialize(nil);
    WordApp := CreateOleObject('Word.Application');
    disp := IDispatch(WordApp);

    param := VarFromSingle(2.0);
    Params := Default(TDispParams);
    Params.cArgs := 1;
    Params.rgvarg := @param;
    retval := disp.Invoke(
      371,//CentimetersToPoints
      GUID_NULL,
      LOCALE_USER_DEFAULT,
      DISPATCH_METHOD,
      Params,
      @Result,
      nil,
      nil
    );
    // retval = E_FAIL

    Params := Default(TDispParams);
    retval := disp.Invoke(
      404,//ProductCode
      GUID_NULL,
      LOCALE_USER_DEFAULT,
      DISPATCH_METHOD,
      Params,
      @Result,
      nil,
      nil
    );
    // retval = S_OK
  except
    on E: Exception do
      Writeln(E.ClassName, ': ', E.Message);
  end;
  Readln;
end.

我不能以这种方式调用CentimetersToPoints，但可以调用ProductCode 函数。

要添加到您的成功/失败指标集合中，当我使用 PowerShell 调用 CentimetersToPoints 函数时，我成功了。当我使用 Python 的win32com.client 调用时，我得到E_FAIL。

显然我们缺少一些特殊的魔法成分。似乎所有的 MS 工具都知道这个魔法。

我的结论是不可能使用 Delphi 中实现的变体调度来调用CentimetersToPoints。它不知道魔法，不管魔法是什么。

显然可以在IDispatch 上调用Invoke 并成功。我们可以看出这一点，因为其他环境可以做到这一点。所以，我还不知道缺失的魔法是什么。

如果您可以使用早期绑定的 COM，那么您可以回避这个问题：

Writeln((IDispatch(w) as WordApplication).CentimetersToPoints(2.0));

---

好的，使用Hans Passant 的help，我有一些Delphi 代码可以调用这个函数：

program SO16279098;

{$APPTYPE CONSOLE}

uses
  SysUtils, Variants, Windows, ComObj, ActiveX;

function VarFromSingle(const Value: Single): Variant;
begin
  VarClear(Result);
  TVarData(Result).VSingle := Value;
  TVarData(Result).VType := varSingle;
end;

var
  WordApp: Variant;
  param: Variant;
  retval: HRESULT;
  disp: IDispatch;
  Params: TDispParams;
  result: Variant;

begin
  try
    CoInitialize(nil);
    WordApp := CreateOleObject('Word.Application');
    disp := IDispatch(WordApp);

    param := VarFromSingle(2.0);
    Params := Default(TDispParams);
    Params.cArgs := 1;
    Params.rgvarg := @param;
    retval := disp.Invoke(
      371,//CentimetersToPoints
      GUID_NULL,
      LOCALE_USER_DEFAULT,
      DISPATCH_METHOD or DISPATCH_PROPERTYGET,
      Params,
      @Result,
      nil,
      nil
    );
    Writeln(Result);
  except
    on E: Exception do
      Writeln(E.ClassName, ': ', E.Message);
  end;
  Readln;
end.

由于未知原因，您需要包含DISPATCH_PROPERTYGET 以及DISPATCH_METHOD。

question that I asked 可能会使这个问题重复。所以，我投票结束。