发送电子邮件：对于 MIME 类型 multipart/mixed 没有对象 DCH

Question

我正在尝试使用 Java 代码发送电子邮件，但从 GroovyConsole 运行。当我只发送没有附件的电子邮件时，它工作得很好，但一旦我添加附件的多部分逻辑，它就会失败。

编辑：我使用的是 Javamail 1.4.7 版

这是我遇到的错误。

javax.activation.UnsupportedDataTypeException: no object DCH for MIME type multipart/mixed; 

boundary="----=_Part_16_24710054.1375885523061"

at javax.activation.ObjectDataContentHandler.writeTo(DataHandler.java:891)

它发生在下面的 Transport.send(mimeMsg) 行。

import java.util.Properties;
import javax.mail.*;
import javax.mail.internet.*;
import javax.activation.*;


Properties properties = new Properties()
Session session
MimeMessage mimeMsg 

properties.put("mail.smtp.host", "[my host ip]")

session = Session.getDefaultInstance(properties)
mimeMsg = new MimeMessage(session)

String recipient = "[to email address]"

mimeMsg.addRecipient(Message.RecipientType.TO, new InternetAddress(recipient))

mimeMsg.setSubject("This is the subject")
mimeMsg.setText("This is the message #1")

mimeMsg.setFrom(new InternetAddress("[from email address]"))

BodyPart messageBodyPart = new MimeBodyPart()
messageBodyPart.setText(mimeMsg.getContent())    
Multipart multipart = new MimeMultipart()

String filePath = "[full & correct path to test.txt]"
DataSource source = new FileDataSource(filePath)
messageBodyPart.setDataHandler(new DataHandler(source))

String fileName = "test.txt"
messageBodyPart.setFileName("test.txt")

multipart.addBodyPart(messageBodyPart)

mimeMsg.setContent(multipart)

Transport.send(mimeMsg)

println "Message Sent!"

Answer 1

我已经通过以下步骤解决了同样的问题。

1-解压mail.jar文件（解压jar文件后会得到如下文件夹 com,javax,META-INF) 2-将以上所有文件夹放在类文件夹中 3- 重启你的网络服务器。

Answer 2

我认为这是与 GroovyConsole 运行方式有关的类加载器问题...

如果我将以下 @Grab 和 @GrabcConfig 添加到脚本中，它会起作用...

@Grab( 'javax.mail:mail:1.4.7' )
@GrabConfig(systemClassLoader=true, initContextClassLoader=true)
import javax.mail.*
import javax.mail.internet.*
import javax.activation.*

def props = new Properties().with { p ->
    p.'mail.smtp.host' = 'my mail server'
    p
}

def session = Session.getDefaultInstance( props )

def message = new MimeMessage( session )

message.addRecipient( Message.RecipientType.TO, new InternetAddress( 'to address' ) )
message.subject = 'This is the subject'
message.text = 'This is the message #1'
message.from =  new InternetAddress( 'from address' )

def textpart = new MimeBodyPart()
textpart.text = 'This is the message #2'

def attachment = new MimeBodyPart()
attachment.dataHandler = new DataHandler( new FileDataSource( '/path/to/file.txt' ) )
attachment.fileName = 'file.txt'

def multi = new MimeMultipart()
multi.addBodyPart( textpart )
multi.addBodyPart( attachment )

message.content = multi

Transport.send( message )

或者，删除两个 @Grab 和 @GrabConfig 行，然后从命令行运行它：

groovy -cp /path/to/mail-1.4.7.jar:/path/to/activation-1.1.jar mail.groovy