以编程方式检测 Windows 上的连接网络速度答案

【问题标题】：Programmatically detect connected network speed on Windows以编程方式检测 Windows 上的连接网络速度
【发布时间】：2012-10-30 07:29:18
【问题描述】：

如何检测我的 NIC 建立的以太网连接类型？也就是说，我的网卡是千兆以太网设备，但由于它是自动感应的，它可能以千兆速度或快速以太网速度连接。

我如何知道它的连接速度？

我尝试使用 WMI 的 Win32_NetworkAdapter、CIM_NetworkAdapter，甚至 wmic NET get Name,Speed，但它们都为 Speed 返回空白。

顺便说一下，我使用的是 Windows XP Pro SP3。但我想要一个也适用于 Windows Server 2003（标准和企业版）、Windows Server 2008 和 Windows Server 2008 R2 的解决方案。

【问题讨论】：

此链接中的第三个帖子包含适用于 XP 的 VBScript：social.msdn.microsoft.com/Forums/uk-UA/scripting/thread/…
@Lizz 谢谢！有用！现在，如果您可以将您的评论作为答案发布，我会尽快将其标记为 the 答案:)

标签： networking wmi ethernet

【解决方案1】：

一个代号为“mystifeid”的神秘人在本站解开了这个谜题，第三帖如下： http://social.msdn.microsoft.com/Forums/uk-UA/scripting/thread/e3936dff-7395-4a6a-ab35-aa1aab0bcd71

这是他们可爱的代码：

Dim strQuery, strQuery2, objLocator, objWMI, objItem, objItem2, colItems, colItems2, resultString, nicName
strQuery = "SELECT * FROM Win32_PerfFormattedData_Tcpip_NetworkInterface"
strQuery2 = "SELECT * FROM Win32_NetworkAdapter"
Set objLocator = CreateObject( "WbemScripting.SWbemLocator" )
Set objWMI = objLocator.ConnectServer( ".", "root\CIMV2" )
objWMI.Security_.ImpersonationLevel = 3
Set colItems2 = objWMI.ExecQuery( strQuery2, "WQL", 0 )
Set colItems = objWMI.ExecQuery( strQuery, "WQL", 0 )
resultString = ""
For Each objItem2 In colItems2
 If objItem2.NetConnectionStatus = 2 Then
  nicName = Mid(objItem2.Name, 1, 5)
  resultString = resultString & "Adapter Name : " & objItem2.Name & VbCrLf
  resultString = resultString & "MAC Address : " & objItem2.MACAddress & VbCrLf
  For Each objItem In colItems
   If Mid(objItem.Name, 1, 5) = nicName Then
    resultString = resultString & "CurrentBandwidth : " & objItem.CurrentBandwidth & VbCrLf
   End If
  Next
 End If
Next
Set objLocator = Nothing
Set objWMI = Nothing
Set colItems = Nothing
Set colItems2 = Nothing
WScript.Echo resultString

PS- 我会尽快针对 Win7 和 Win2008 进行审核，并让大家知道。

【讨论】：