C# VS2010：如何使用drawstring绘制滚动文本而不闪烁

Question

我首先要说我已经尝试了很多方法来实现我的目标，现在我正停留在“最佳”解决方案上，但这离我认为的“伟大”解决方案还很远。 .所以我希望在这里得到一个建议。这是在 C# 中使用 Visual Studio 2010。

我的程序播放带有元数据的音频文件，其中可能包括歌词。当我有了歌词时，用户可以选择让歌词一次显示一个短语，或者随着音频滚动。这发生在单行标签上。这不是卡拉 OK 风格，你有整个短语，它会被涂上颜色或其他东西，实际上歌词会随着音乐从左到右滚动。

我尝试过启用和禁用双缓冲。启用它后会更好，但仍然不完美。

1) 在运行时为标签创建一个 Graphics 对象，然后计时器将使用其 Graphics 对象直接绘制到 Label 上。我尝试清除图形，而不是仅绘制图形大小的填充矩形以避免清除闪烁。在其中任何一个之后，都会绘制文本字符串。我在这里尝试了 25ms、50ms 和 100ms，结果大致相同。

2) 在运行时为标签创建一个 Graphics 对象，然后计时器将创建一个标签大小的位图，从该位图创建一个图形对象，绘制填充矩形并在图形对象中绘制字符串，然后将其复制到 Label 的图形对象，我也尝试将位图复制到 Label.Image 字段。

3) 没有创建专用的 Graphics 对象。相反，让计时器使标签无效。然后在Label的Paint事件上，使用e参数的Graphics对象直接绘制填充的矩形，绘制文本字符串。

在所有情况下，结果都是正确滚动的文本，在滚动时会抖动且难以阅读，但在暂停播放时看起来很完美。绘制的时间和内容是准确的。 #3 是我尝试过的众多变体中“最好的”，但正如我所说，阅读文本仍然不容易。鉴于计时器值在 40FPS 和 10FPS 之间变化，并且结果在易读性上并没有太大差异，我认为这归结为我绘制图纸的效率低下。

是我犯了一些明显的错误还是根本缺乏导致这种行为的基础？我很想就如何改进这一点提供一些意见。谢谢。

Answer 1

当您尝试以这种方式在控件上绘图时，该控件将“有帮助地”为您绘制背景。不幸的是，这会导致闪烁。

我过去所做的是创建一个新类，该类继承自您实际想要绘制的控件。这个类应该用一个空子覆盖OnPaintBackground。然后在你的表单上使用这个子类而不是 stock 类。

我只对图片框做过此操作，因此使用其他类型控件的结果可能会有所不同。

您可能还可以像这样设置控件样式（AllPaintingInWmPaint 在这种情况下是最重要的。）：

this.SetStyle(
    ControlStyles.AllPaintingInWmPaint | 
    ControlStyles.UserPaint | 
    ControlStyles.DoubleBuffer, 
    true);

Answer 2

这是我不久前创建的滚动标签控件的代码。它可能需要一些调整，并且它是用 VB.NET 编写的，您必须对其进行转换。它对我来说流畅滚动，没有闪烁。您可以通过更改 2 个计时器调用中的数字或更改 Tick 子中的 .25 来调整速度。

Imports System.ComponentModel

Public Class ScrollingLabel
    Inherits Label

    Private _buffer As Bitmap
    Private _textX As Double
    Private _brush As Brush
    Private _timer As Threading.Timer
    Private _textWidth As Integer

    Public Sub New()
        MyBase.New()
        If Not IsDesignMode() Then
            _timer = New Threading.Timer(AddressOf Tick, Nothing, 25, Threading.Timeout.Infinite)
        End If
        _brush = New SolidBrush(Me.ForeColor)
        _textX = Me.Width
    End Sub

    Protected Overrides Sub OnPaint(e As PaintEventArgs)
        Using g As Graphics = Graphics.FromImage(_buffer)
            g.Clear(Me.BackColor)
            g.DrawString(Me.Text, Me.Font, _brush, New PointF(CSng(_textX), 0))
        End Using
        e.Graphics.DrawImage(_buffer, 0, 0)
    End Sub

    Private Sub ScrollingLabel_Resize(sender As Object, e As EventArgs) Handles Me.Resize
        If _buffer IsNot Nothing Then
            _buffer.Dispose()
        End If
        _buffer = New Bitmap(Me.Width, Me.Height, Imaging.PixelFormat.Format32bppArgb)
    End Sub

    Public Overrides Property ForeColor As Color
        Get
            Return MyBase.ForeColor
        End Get
        Set(value As Color)
            MyBase.ForeColor = value
            If _brush IsNot Nothing Then
                _brush.Dispose()
            End If
            _brush = New SolidBrush(Me.ForeColor)
        End Set
    End Property

    Public Overrides Property Text As String
        Get
            Return MyBase.Text
        End Get
        Set(value As String)
            MyBase.Text = value

            Using g As Graphics = Graphics.FromImage(_buffer)
                _textWidth = CInt(g.MeasureString(Me.Text, Me.Font).Width)
            End Using
        End Set
    End Property

    Private Sub Tick(state As Object)
        If Me.Parent.InvokeRequired Then
            Me.BeginInvoke(New Action(Of Object)(AddressOf Tick), New Object() {state})
        End If
        _textX -= 0.25
        If Math.Abs(_textX) > _textWidth Then
            _textX = Me.Width
        End If
        _timer.Change(25, Threading.Timeout.Infinite)
        Me.Invalidate()
    End Sub

    Private Function IsDesignMode() As Boolean
        If DesignMode Then
            Return True
        End If
        Return CBool(LicenseManager.UsageMode = LicenseUsageMode.Designtime)
    End Function
End Class