显示坐标答案

【问题标题】：Display Co-Ordinates显示坐标
【发布时间】：2013-01-22 07:01:09
【问题描述】：

单元格A1 具有框的左上角坐标，A2 具有框的右下角坐标，如何让A3 以csv 格式显示框的所有坐标？

例如：

Cell A1 = (24,20)
Cell A2 = (26,19)

如何获得？：

Cell A3 = (24,20),(25,20),(26,20),(24,19),(25,19),(26,19)

我正在使用 Excel 2011

【问题讨论】：

没有实际的框，只有具有左上角和右下角坐标的单元格。
谢谢你顺便修了我的帖子，我没跟上这里的格式。

标签： excel vba macos excel-2011

【解决方案1】：

这是你正在尝试的吗？（希望我能正确理解您的问题。如果没有，请随时纠正我）

将此代码粘贴到模块中，然后在单元格A3 中调用=GetCord(A1,A2)，如下面的屏幕截图所示。

Public Function GetCord(rng1 As Range, rng2 As Range) As String
    Dim strTmp As String, strTmp1 As String, strTmp2 As String
    Dim a As Long, b As Long, i As Long, j As Long, k As Long

    strTmp1 = rng1.Value: strTmp2 = rng2.Value

    strTmp1 = Trim(Replace(strTmp1, "(", ""))
    strTmp1 = Trim(Replace(strTmp1, ")", ""))

    strTmp2 = Trim(Replace(strTmp2, "(", ""))
    strTmp2 = Trim(Replace(strTmp2, ")", ""))

    i = Val(Split(strTmp1, ",")(0))
    j = Val(Split(strTmp1, ",")(1))

    k = Val(Split(strTmp2, ",")(0))
    l = Val(Split(strTmp2, ",")(1))

    For b = j To l Step -1
        For a = i To k
            strTmp = strTmp & "(" & a & "," & b & "),"
        Next a
    Next b

    GetCord = Left(strTmp, Len(strTmp) - 1)
End Function

截图

注意：上面的函数是假设y Co-Ordinates 是按降序排列的。为了满足所有场景，您必须在函数中包含该检查。

【讨论】：