数据绑定到文本框

Question

   Dim myconn As New SqlConnection("Server=server,Trusted_Connection=True,Database=database")
    'selects from mt table linking the current pc to a row
    Dim sql As String = "SELECT * from idset " & vbcrlf &
    "Where pcname= '" & pcname & "'"
    Dim ds As New DataSet
    Dim da As New SqlDataAdapter(sql, myconn)

    da.Fill(ds, "Setup")


    txtClientID.DataBindings.Add("text", ds.Tables("idset"), "CLID")

我不知道为什么它由于某种原因不能工作它没有填充数据集我是不是声明了一些错误？

Answer 1

它不起作用的原因是因为你指定传入的表应该映射到一个名为Setup的表。您的数据集不包含名为Setup 的表，因此传入的表将被命名为...好吧，Setup。

试试这个：

da.Fill(ds, "idset")

另外，我强烈建议你：

• 设置option strict
• 始终使用parameterized/prepared SQL 查询。
• 在处理一次性物品时始终使用Using 语句。

说真的。

---

调试绑定的最佳方法是使用BindingSource 并处理BindingComplete 事件。

Private bs As BindingSource
Private ds As DataSet

Private Sub Initialize(pcname As String)

    Me.ds = New DataSet()

    Using connection As New SqlConnection("Server=server,Trusted_Connection=True,Database=database")
        connection.Open()
        Using command As New SqlCommand()
            command.Connection = connection
            command.CommandText = "SELECT * from [idset] Where [pcname] = @pcname;"
            command.Parameters.AddWithValue("@pcname", pcname)
            Using adapter As New SqlDataAdapter(command)
                adapter.Fill(Me.ds, "idset")
            End Using
        End Using
    End Using

    Me.bs = New BindingSource(Me.ds, "idset")

    AddHandler bs.BindingComplete, AddressOf Me.HandleBindingCompleted

    Me.txtClientID.DataBindings.Add("Text", Me.bs, "CLID")

End Sub

Private Sub HandleBindingCompleted(sender As Object, e As BindingCompleteEventArgs)
    If (Not e.Exception Is Nothing) Then
        Debug.WriteLine(e.ErrorText)
    End If
End Sub