过滤的下拉列表 SQL Server 和 VB.NET [关闭]

Question

我不是程序员，只是想为自己制作一个小应用程序的爱好者。

我的查询是我有两个下拉列表（vb.net 表单），一个是“builder”，下一个是“projects”（均通过 MSSQL 中的“BuilderID”链接），我想过滤“Projects”列出链接到所选“Builder”的那些

我的“builder”下拉列表很好，我在想第二个“project List”的存储过程，基于选择的builder查询项目表的某种方式。

我正在尝试编辑这个问题，但不确定要添加什么，因为玛丽回答得很好，她一定明白我在问什么。

Answer 1

我不确定你是如何填写你的第一个列表的，所以我从头开始。重要的是将 ValueMember 设置为 ID。然后使用 SelectedIndexChanged 事件，您可以获得下一个查询的构建器 ID。同样的理论也适用于填充网格。好可爱的宝贝！

Imports System.Data.SqlClient
Public Class DWGBrowse

    Public Property FinishedLoading As Boolean = False

    Private Sub DWGBrowse_Load(sender As Object, e As EventArgs) Handles MyBase.Load
        FillBuildersList()
        FinishedLoading = True
    End Sub

    Private Sub FillBuildersList()
        Dim strSQL = "Select * From Builders;"
        Dim dt As New DataTable
        Using cn As New SqlConnection(My.Settings.BuildersConnection)
            Using cmd As New SqlCommand(strSQL, cn)
                Try
                    cn.Open()
                    Using dr As SqlDataReader = cmd.ExecuteReader
                        dt.Load(dr)
                    End Using
                Catch ex As Exception
                    MessageBox.Show(ex.Message)
                Finally
                    cn.Close()
                End Try
            End Using
        End Using
        BuilderBox.DataSource = dt
        BuilderBox.DisplayMember = "BuilderName" 'Whatever your column is called
        BuilderBox.ValueMember = "BuilderId" 'the name of your ID column
        BuilderBox.SelectedIndex = -1
    End Sub

    Private Sub BuilderBox_SelectedIndexChanged(sender As Object, e As EventArgs) Handles BuilderBox.SelectedIndexChanged
        If Not FinishedLoading Then Exit Sub
        Try
            Using sqlConnection As New System.Data.SqlClient.SqlConnection(My.Settings.BuildersConnection)
                Dim id As Integer = CInt(BuilderBox.SelectedValue)
                Dim dt As New DataTable
                Dim sqlString As String = "Select * From Projects Where BuilderID = @ID"
                Using cmd As New System.Data.SqlClient.SqlCommand(sqlString, sqlConnection)
                    cmd.Parameters.Add("@ID", SqlDbType.Int).Value = id
                    ProjectBox.DataSource = Nothing
                    sqlConnection.Open()
                    Using dr As System.Data.SqlClient.SqlDataReader = cmd.ExecuteReader
                        dt.Load(dr)
                        ProjectBox.DisplayMember = "ProjectName"
                        ProjectBox.ValueMember = "ProjectID"
                        ProjectBox.DataSource = dt
                    End Using
                End Using
            End Using
        Catch ex As Exception
            MessageBox.Show(ex.Message)
        End Try
    End Sub

    Private Sub ProjectBox_SelectedIndexChanged(sender As Object, e As EventArgs) Handles ProjectBox.SelectedIndexChanged
        Dim id As Integer = CInt(ProjectBox.SelectedValue)
        Dim dt As New DataTable
        Dim strSQL As String = "Select * From Drawings Where ProjectID = @ID"
        Using cn As New SqlConnection(My.Settings.BuildersConnection)
            Using cmd As New SqlCommand(strSQL, cn)
                cmd.Parameters.Add("@ID", SqlDbType.Int).Value = CInt(ProjectBox.SelectedValue)
                cn.Open()
                Using dr As SqlDataReader = cmd.ExecuteReader
                    dt.Load(dr)
                End Using
            End Using
        End Using
        DataGridView1.DataSource = dt
    End Sub

End Class