错误：“已经有一个打开的 DataReader 与此连接关联，必须先关闭”

Question

我收到此错误消息，这是我的代码，请帮助我

Private Sub txtceknofak_Leave(sender As Object, e As EventArgs) Handles txtceknofak.Leave

    Dim nf As String
    nf = "select no_fak from terima_cucian where no_fak = '" & txtceknofak.Text & "'"
    comm = New SqlCommand(nf, conn)
    rdr = comm.ExecuteReader()

    If rdr.HasRows Then
        btproses.Enabled = True
        btproses.Focus()
    Else
        MsgBox("Nomor faktur tidak ada")
        txtceknofak.Clear()
        txtceknofak.Focus()
    End If
    rdr.Close()

End Sub

Answer 1

由于连接不是方法的一部分，它似乎是您类中的一个字段。我会对此感到气馁。而是使用局部变量并在需要时打开/关闭它。实际上连接池并不会真正打开/关闭物理连接，所以你不必担心这是低效的。

您可以通过使用Try-Finally 或-更易读、更简洁- 与Using-statement 一起使用来确保即使出现错误也关闭连接：

Private Sub txtceknofak_Leave(sender As Object, e As EventArgs) Handles txtceknofak.Leave
    Dim nf As String = "select no_fak from terima_cucian where no_fak = @no_fak"
    Using conn = New SqlConnection(connectionstring)
        Using comm = New SqlCommand(nf, conn)
            comm.Parameters.AddWithValue("@no_fak", txtceknofak.Text)
            conn.Open()
            Using rdr = comm.ExecuteReader()
                If rdr.HasRows Then
                    btproses.Enabled = True
                    btproses.Focus()
                Else
                    MsgBox("Nomor faktur tidak ada")
                    txtceknofak.Clear()
                    txtceknofak.Focus()
                End If
            End Using
        End Using
    End Using ' *** this will also close the connection *** '
End Sub

我还使用了 sql-parameters 来防止 sql-injection。

Answer 2

创建阅读器的新实例

rdr = new comm.ExecuteReader();

谢谢