是否可以嵌入文件夹中的所有文件？

Question

我想嵌入给定文件夹的所有 xml 文件。现在我正在做这样的事情：

[Embed(source="../somefolder/file1.xml", mimeType="application/octet-stream")]
private var MyClass1:Class;

[Embed(source="../somefolder/file2.xml", mimeType="application/octet-stream")]
private var MyClass2:Class;

[Embed(source="../somefolder/file3.xml", mimeType="application/octet-stream")]
private var MyClass3:Class;

和

var file:XML;
var bytes:ByteArray;

switch (fileId) {
    case 1:
        bytes = new MyClass1();
        break;
    case 2:
        bytes = new MyClass2();
        break;
    case 3:
        bytes = new MyClass3();
        break;
}

file = new XML(bytes.readUTFBytes(bytes.length));

XML 文件列表将增长到 10 多个文件，因此我正在寻找一种更优雅、更动态的方式来嵌入这些文件。

文件应该在编译时嵌入，不能通过 URLLoader 加载它们。

有什么想法吗？

Answer 1

我只能建议您编写某种代码生成脚本。可以有以下选项：

• Flex 编译器扩展（更多细节here 或here）。通过这种方式，您可以预处理代码并嵌入元数据。该解决方案可以由注释（元标记）驱动。
• 蚂蚁脚本。
• 您自己的命令行脚本。

Answer 2

我不认为有办法做这样的事情：

[Embed(source="../somefolder/*", mimeType="application/octet-stream")]

但您可以使用 Zip 文件并访问他的内容。我经常使用http://nochump.com/blog/archives/15 来做这些事情：

package
{
    import flash.display.Sprite;
    import flash.utils.ByteArray;

    import nochump.util.zip.ZipEntry;
    import nochump.util.zip.ZipFile;


    public class TestTextfield extends Sprite
    {
        [Embed(source="files.zip", mimeType="application/octet-stream")]
        private var zipContent:Class;

        public function TestTextfield()
        {
            var zip : ZipFile = new ZipFile(new zipContent);

            for each(var entry : ZipEntry in zip.entries)
            {
                var entryContent : ByteArray = zip.getInput(entry);

                if(entry.name.indexOf(".xml") != -1)
                {
                    var xmlContent : XML = new XML(entryContent.readUTFBytes(entryContent.bytesAvailable));
                    trace("File " + entry.name +" :\n" + xmlContent);
                }
            }
        }

    }
}

此示例将显示嵌入 files.zip 中包含的所有 XML 文件内容