用于 INSERT 和 UPDATE 的 SQL Server 存储过程，最好分开还是压缩？

Question

我正在创建用于在我的 SQL Server 数据库中插入和更新数据的存储过程。起初我正在为 Add/Set 创建一个单独的过程，但后来我偶然发现了一个查询，该查询允许我将它们压缩为一个过程。我想与 SO 社区核实以这种方式进行的任何可能的未来问题。

单独的程序

--INSERT Procedure
CREATE PROCEDURE [dbo].[AddDataType]
    @TypeName [nvarchar](255),
    @TypeProperty [nvarchar](255)
AS
BEGIN
    SET NOCOUNT ON;

    INSERT INTO DataType(TypeName, TypeProperty)
    VALUES(@TypeName, @TypeProperty)

    SELECT SCOPE_IDENTITY()
END

--UPDATE Procedure
CREATE PROCEDURE [dbo].[SetDataType]
    @ID [int],
    @TypeName [nvarchar](255),
    @TypeProperty [nvarchar](255)
AS
BEGIN
    SET NOCOUNT ON;

    UPDATE DataType SET TypeName = @TypeName, TypeProperty = @TypeProperty
    WHERE ID = @ID
 END

EXEC AddDataType @TypeName = 'Test Name', @TypeProperty = 'Test Property' --INSERT
EXEC SetDataType @ID = 42, @TypeName = 'Test Name', @TestProperty = 'Test Property' --UPDATE

合并

CREATE PROCEDURE [dbo].[SetDataType]
    @ID [int] = NULL,
    @TypeName [nvarchar](255),
    @TypeProperty [nvarchar](255)
AS
BEGIN
    SET NOCOUNT ON;

    UPDATE DataType SET TypeName = @TypeName, TypeProperty = @TypeProperty
    WHERE ID = @ID

    IF @@ROWCOUNT = 0
        INSERT INTO DataType(TypeName, TypeProperty)
        VALUES(@TypeName, @TypeProperty)

    IF @ID IS NULL
        SELECT SCOPE_IDENTITY()
END

EXEC SetDataType @TypeName = 'New Type Name', @TypeProperty = 'New Type Property' --INSERT
EXEC SetDataType @ID = 42, @TypeName = 'Updated Type Name', @TypeProperty = 'Updated Type Property' --UPDATE

到目前为止，我有 15 个类型表，我为它们创建了过程，并试图减少创建的过程的数量，但是我不想牺牲性能。我知道第二种方法需要更多处理，但它是否足以引起问题？我没有看到存储大量数据的类型表，不超过 100 条记录，平均在 10-20 条左右。

感谢任何想法或建议。

Answer 1

什么版本的 SQL Server？这些信息总是有用的，所以请养成用特定版本标记问题的习惯。

如果sql-server-2008 或更高版本，您可能会考虑使用MERGE 而不是单独的INSERT/UPDATE 操作，但自从写下这个答案后，我肯定改变了自己的态度，更喜欢您提出的UPDATE / IF @@ROWCOUNT = 0 / INSERT 方法。有关详细信息，请参阅：

• Use Caution with SQL Server's MERGE Statement
• So, you want to use MERGE, eh?

这是一个MERGE 示例（在 tempdb 中运行它），但我再次建议不要使用它。

CREATE TABLE dbo.DataType
(
    ID             int IDENTITY(1,1),
    TypeName       nvarchar(255),
    [TypeProperty] nvarchar(255),
    CONSTRAINT PK_DataType PRIMARY KEY (ID)
);

INSERT dbo.DataType(TypeName, [TypeProperty]) VALUES (N'name 1', N'property 1');
GO

然后是一个程序：

CREATE PROCEDURE dbo.MergeDataType
    @ID           int = NULL,
    @TypeName     nvarchar(255),
    @TypeProperty nvarchar(255)
AS
BEGIN
    SET NOCOUNT ON;

    WITH [source](ID, TypeName, [TypeProperty]) AS 
    (
        SELECT @ID, @TypeName, @TypeProperty
    )
    MERGE dbo.DataType WITH (HOLDLOCK) AS [target] 
      USING [source] ON [target].ID = [source].ID
    WHEN MATCHED THEN
        UPDATE SET [target].TypeName       = @TypeName,
                   [target].[TypeProperty] = @TypeProperty
    WHEN NOT MATCHED THEN
        INSERT (TypeName, [TypeProperty]) 
        VALUES (@TypeName, @TypeProperty);
END
GO

现在让我们运行它并检查结果：

EXEC dbo.MergeDataType 
    @TypeName     = N'foo', 
    @TypeProperty = N'bar';

EXEC dbo.MergeDataType 
    @ID           = 1, 
    @TypeName     = N'name 1', 
    @TypeProperty = N'new property';
GO

SELECT ID, TypeName, [TypeProperty] FROM dbo.DataType;
GO

清理：

DROP TABLE dbo.DataType;
DROP PROCEDURE dbo.MergeDataType;

Answer 2

USE [//Your Database Name]
GO

SET ANSI_NULLS ON
GO
SET QUOTED_IDENTIFIER ON
GO

ALTER PROCEDURE [dbo].[InsertIcone] 
    -- Add the parameters for the stored procedure here
(
@amount decimal(18,0),
@payer  nvarchar(50),
@paymentMode  nvarchar(50),
@date date,
@description nvarchar(Max),
@operatorId int
)
AS
begin
if exists (select *  from wallet2 as t where payer=@payer)
begin
    update wallet2 set amount=@amount,payer=@payer,paymentMode=@paymentMode,
    [date]=@date,[description]=@description where id=(select id  from 
    wallet2 as t where payer=@payer) and operatorId=@operatorId
end
else 
begin
         insert into dbo.Wallet2 
         values(@amount,@payer,@paymentMode,@date,@description,@operatorId);
    end

END