在设计时更新控件背景色

Question

我继承了一个列表框控件来编写一些这样的属性：

''' <summary>
''' Indicates the BackColor to paint the unselected ListBox items when the ListBox is enabled.
''' </summary>
Public Property ItemUnselected_BackColor As Color
    Get
        Return _ItemUnselected_BackColor.Color
    End Get
    Set(value As Color)
        _ItemUnselected_BackColor = New SolidBrush(value)
    End Set
End Property

问题是当我在设计时更改颜色时，我需要移动控件或最小化/最大化 VisualStudio IDE 以更新控件上的更改以查看新颜色。

这样做的正确方法是什么？

更新：

我认为这样做的方法是添加一个特殊标志或其他东西......

我已经尝试过了，但是该属性在编辑器中变得无法访问：

<EditorAttribute(GetType(Color), GetType(UITypeEditor))> _
Public Property ItemUnselected_BackColor As Color
...

Answer 1

当属性改变时使控件失效如何？

Public Property ItemUnselected_BackColor As Color
    Get
        Return _ItemUnselected_BackColor.Color
    End Get
    Set(value As Color)
        _ItemUnselected_BackColor = New SolidBrush(value)
        Me.Invalidate(True)
    End Set
End Property

编辑

由于强烈建议仅在需要时创建画笔，因此您应该这样做：

Public Property ItemUnselected_BackColor As Color
    Get
        Return Me._ItemUnselected_BackColor
    End Get
    Set(value As Color)
        If ((value = Color.Transparent) OrElse (value = Color.Empty)) Then
            Throw New ArgumentOutOfRangeException()
        End If
        If (value <> _ItemUnselected_BackColor) Then
            Me._ItemUnselected_BackColor = value
            Me.Invalidate()
        End If
    End Set
End Property

Private _ItemUnselected_BackColor As Color = Color.Black

在你的绘画方法中：

Protected Overrides Sub OnPaint(e As PaintEventArgs)
    Using b As New SolidBrush(Me._ItemUnselected_BackColor)
        'TODO: Paint
    End Using
    MyBase.OnPaint(e)
End Sub

Answer 2

部分问题是该属性被定义为一种颜色，但您正在尝试使用/保存画笔。正确的方法是

Public Property ItemUnselected_BackColor As Color
    Get
        Return _ItemUnselected_BackColor
    End Get
    Set(value As Color)
        _ItemUnselected_BackColor = value
        Me.Invalidate
    End Set
End Property

Invalidate 将是更新控件的正确方法，因为在新的颜色设置下，当前显示并非无效。画笔应该在paint 或OnDrawItem 过程中创建，而不是在属性get/setter 中。您的代码没有处理前一个。

这些属性不是必需的，也不会像您认为的那样做。他们会定义一种特殊的方式（如对话框）来获取颜色。

我开始使用的您的 ListView 现在具有 AlternativeBack 颜色。如果你想优化你可以这样做：

 Set(ByVal value As Color)
       If _AltBackColor <> value Then
           _AltBackColor = value
            Me.Invalidate()    ' only invalidate/repaint if it changed
       End If
 End Set