如何通过使用批处理文件双击它来安装apk文件答案

【问题标题】：how can install apk files by double clicking on it using batch file如何通过使用批处理文件双击它来安装apk文件
【发布时间】：2015-10-23 16:11:01
【问题描述】：

我想编写一个批处理文件，当我双击任何 apk 文件时帮助我安装 apk 文件

例如当我点击 apk 文件 myBatchFile.bat 执行时

myBatchFile.bat 中应该有什么

adb install what?

谢谢

【问题讨论】：

你的apk文件的路径怎么样？
是的，我不知道如何在批处理文件中接收点击文件的地址
我认为您希望您的 bat 脚本具有液滴行为。这应该有助于stackoverflow.com/q/8547676/794088

标签： android windows batch-file installation apk

【解决方案1】：

首先，备份HKEY_CURRENT_USER\SOFTWARE\Classes 注册表配置单元。因此，如果在测试 .bat 文件期间出现问题，您可以恢复设置。

您需要安装.apk 文件的shell 处理程序。处理程序是一个.bat 文件，例如MyApkInstaller.bat。当您在 Windows 资源管理器中双击 .apk 文件时，将运行处理程序 MyApkInstaller.bat，并将 .apk 文件名传递给处理程序。

@echo off

echo Installing %1...
adb install %1 && echo Done || echo Failed
pause

将处理程序安装/卸载到 Windows 注册表的脚本

@echo off
setlocal

set _progId=MyApkInstaller
set _handler=MyApkInstaller.bat

if not "%1"=="" goto uninstall

:install
echo Installing...
reg add HKCU\Software\Classes\.apk\OpenWithProgIds /v %_progId% /t REG_SZ /f
reg add HKCU\Software\Classes\%_progId%\Shell\Open\Command /ve /t REG_SZ /d "%~dp0%_handler% ""%%1""" /f
goto finish

:uninstall
echo Uninstalling...
reg delete HKCU\Software\Classes\.apk
reg delete HKCU\Software\Classes\%_progId%

:finish
endlocal

【讨论】：

【解决方案2】：

您可以将这些写入您的 xxx.bat

@echo %1

adb install -r %1

pause

需要设置环境变量，选择xxx.bat

的方式打开xxxx.apk

【讨论】：

【解决方案3】：

adb可以在模拟器上安装*.apk如下：

adb install PATH

所以，您可以像这样简单地创建一个批处理文件：

@echo off

echo installing your application...
adb install %1

保存后，选择此批处理文件作为*.apk 文件的默认应用程序。（资源管理器中的 apk 文件 > 右键单击 > 属性 > 更改 > YOUR_BATCH_FILE）

【讨论】：