NSIS 在静默模式下安装后弹出对话框/消息答案

【问题标题】：Popping up a dialog/message after NSIS install in silent modeNSIS 在静默模式下安装后弹出对话框/消息
【发布时间】：2019-03-01 19:49:54
【问题描述】：

我有一个 NSIS 安装程序设置为在静默模式下运行。这很好用。

我有一个客户要求在安装完成后弹出信息...但仍然希望安装程序部分保持静音！

我意识到这是违反直觉的。

话虽如此，安装结束时是否可以覆盖静默？

我目前在 .nsi 脚本的开头设置了下面的安装程序属性

SilentInstall silent

【问题讨论】：

SilentInstall 设置安装程序属性，而不是变量。

标签： installation nsis

【解决方案1】：

您可以在.onInit 中使用SetSilent 打开或关闭静音模式，但一旦该函数返回，用户界面模式将无法更改。

简单的解决方案是在最后一个Section 末尾使用Banner 或Splash 插件之一来显示消息/图像。

或者您可以使用仅显示进度条的最小 UI 创建一个虚假的静音模式：

!include LogicLib.nsh
Var Silent

Function .onInit
${If} ${Silent}
    SetSilent Normal ; Turn off real silent mode
    SetAutoClose True
    StrCpy $Silent 1 ; Fake silent mode
${EndIf}
FunctionEnd

Page Components SkipPageIfSilent
Page Directory SkipPageIfSilent
Page InstFiles "" TweakInstfilesPage

Function SkipPageIfSilent
IntCmp $Silent 0 +2
    Abort
FunctionEnd

Function TweakInstfilesPage
${If} $Silent <> 0
    SetSilent Silent ; Make IfSilent return true
    FindWindow $0 "#32770" "" $HWNDPARENT
    GetDlgItem $0 $0 0x403 ; Show details button
    ShowWindow $0 0
    System::Call 'USER32::GetWindowRect(p$0,@r1)' ; NSIS v3+
    System::Call 'USER32::GetWindowRect(p$HWNDPARENT,@r2)' ; NSIS v3+
    System::Call '*$1(i,i.r3,i,i)'
    System::Call '*$2(i.r5,i.r6,i.r7,ir3r8)'
    IntOp $5 $7 - $5 ; Width
    IntOp $6 $8 - $6 ; Height
    System::Call 'USER32::SetWindowPos(p$HWNDPARENT,p,i,i,ir5,ir6,i0x12)'
    SetDetailsView Hide
${EndIf}
FunctionEnd

Section
Sleep 333
Sleep 333
Sleep 333
Sleep 333
SectionEnd

【讨论】：

谢谢安德斯，我会看看这个并报告！